Автоматически изменять диапазон функции при добавлении строк

Событие изменения рабочего листа: отслеживание изменений в данных столбца

• Лично я бы согласился с предложением JvdV в комментариях.
• При каждом ручном изменении ячейки, например. в столбце A он проверит формулу =SUM(A2:ALastRow) в ячейке A1, и если он неправильный, он перезапишет его правильным.
• Вы можете использовать это для нескольких несмежных столбцов, например. "A,C:D,E".
• Ничего не нужно запускать. Просто скопируйте код в соответствующий модуль листа, например. Sheet1 и выйдите из редактора Visual Basic.

Модуль листа, например. Sheet1 (не стандартный модуль, например Module1)

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    UpdateFirstRowFormula Target, "A"
End Sub

Private Sub UpdateFirstRowFormula( _
        ByVal Target As Range, _
        ByVal ColumnList As String)
    
    On Error GoTo ClearError
    
    Dim ws As Worksheet: Set ws = Target.Worksheet
    Dim Cols() As String: Cols = Split(ColumnList, ",")
    
    Application.EnableEvents = False
    
    Dim irg As Range, arg As Range, crg As Range, lCell As Range
    Dim n As Long
    Dim Formula As String
    
    For n = 0 To UBound(Cols)
        With ws.Columns(Cols(n))
            With .Resize(.Rows.Count - 1).Offset(1)
                Set irg = Intersect(.Cells, Target.EntireColumn)
            End With
        End With
        If Not irg Is Nothing Then
            For Each arg In irg.Areas
                For Each crg In arg.Columns
                    Set lCell = crg.Find("*", , xlFormulas, , , xlPrevious)
                    If Not lCell Is Nothing Then
                        Formula = "=SUM(" & crg.Cells(1).Address(0, 0) & ":" _
                            & lCell.Address(0, 0) & ")"
                        With crg.Cells(1).Offset(-1)
                            If .Formula <> Formula Then .Formula = Formula
                        End With
                    End If
                Next crg
            Next arg
            Set irg = Nothing
        End If
    Next n

SafeExit:
    If Not Application.EnableEvents Then Application.EnableEvents = True
    Exit Sub
ClearError:
    Debug.Print "Run-time error '" & Err.Number & "': " & Err.Description
    Resume SafeExit
End Sub

Используйте вложенную функцию, как показано ниже: =СУММ(СМЕЩ(A2,,,СЧЁТ(A2:A26)))