Дублирование записей в текстовом файле для пустых записей до тех пор, пока не будет найдена непустая запись, а затем продолжите работу с новой записью

Это действительно хакерство, но и форматы ввода и вывода тоже... Используйте с One True Awk или GNU awk 5.3+:

awk --csv -v OFS='","' \
  'NR>1 {for (i=1;i<NF;i++) {a[i]=$i=$i?$i:a[i]; gsub(/"/,"\"\"",$i)} print "\"" $0}'

"Alpha","OldTheme","Some more text"]
"Alpha","OldTheme","Another rest text"]
"Alpha","OldTheme","Yet another text"]
"Yadda","NewTheme","Crazy Text"]
"Yadda","NewTheme","More crazy text"]

Это может сработать для вас (GNU sed):

sed -E '1d;N;s/^|\n/&\n/g
        :a;s/\n("[^"]*",?)(.*\n.*)\n"",?/\1\n\2\1\n/;ta
        /""/s/\n("[^"]*",?)(.*\n.*)\n("[^"]*",?)/\1\n\2\3\n/;ta
        s/\n(.*)\n/\1/;P;D' file

Удалите первую строку.

Добавьте следующую строку и сформируйте двухстрочное окно по всему файлу.

Добавьте несколько новых строк, чтобы отслеживать, какое поле было сопоставлено.

Сформируйте цикл, сопоставляя поля первой строки с полями второй, заменяя пустые поля во второй соответствующими полями в первой строке, а также переходя к следующему полю.

Если была произведена замена, повторите цикл.

Если во второй строке все еще существуют несовпадающие поля, переместите следующее поле и повторите.

После того, как все поля будут заменены/не заменены, удалите каркас, распечатайте и удалите первую строку и повторите попытку.

Чтобы изменить только первые два пустых поля, используйте:

sed -E '1d;N;s/^((("[^"]*",){2}).*\n)"","",/\1\2/;P;D' file

Я создал решение в bash с помощью sed, но процесс это очень, очень медленно и занимает несколько часов. Я думаю, причина в задержка связана с тем, что я читаю построчно, обрабатываю их в bash и запишите их в новый файл. Я предполагаю, что сценарий sed с переменные и сам файл (-f) могут ускорить процесс резко.

Многие способы чтения данных в оболочку являются дорогостоящими, особенно при чтении со стандартного ввода. Оболочка должна избегать чтения большего количества данных, чем предполагалось, что часто означает чтение по одному байту за раз. Ваш сценарий, вероятно, сильно пострадает от этого.

Сценарий также запускает множество дополнительных процессов для выполнения своей работы, по несколько в строке — много grep, sed и echo. Запускать процессы дорого. Уже приняв удар по чтению данных, было бы лучше полностью выполнить обработку строки в оболочке. Оно на это способно.

Но еще лучше было бы выполнить всю работу за один запуск программы обработки текста, например sed или awk. Последнее гораздо читабельнее, но вы специально сказали sed, а на awk у вас уже есть ответ. Один из способов сделать это с помощью sed:

sed -n -E '1n; s/^"","",//; t1; b2; :1; H; g; s/\n//; :2; p; s/^(([^"]*"){4},).*/\1/; h' \
  < input \
  > output

Вы, конечно, можете это написать.

Объяснение:
Выражение sed представляет собой последовательность команд, разделенных точкой с запятой (;). Я добавил пробел после каждой точки с запятой, чтобы было легче читать; это пространство не имеет значения для sed. Команды:

• 1n — для строки номер 1 просто прочитайте следующую строку. Если действует параметр командной строки -n, первая строка полностью пропускается.

• s/^"","",// - удалить текст "","", с начала строки (заменить его пустой строкой), если он присутствует

• t1 - если замена действительно была выполнена, перейдите к метке 1, пропуская команды между здесь и там. Это то, что происходит со строками с «отсутствующими» записями.

• b2 - безоговорочный переход к метке 2, пропуская команды между здесь и там. Вот что происходит с новыми «начальными» строками.

• :1 - ярлык 1

• H — добавьте новую строку и содержимое пространства шаблона в пространство Hold (см. также ниже). Первые пустые поля пространства шаблонов были просто удалены, поэтому копируется только хвост.

• g — получить содержимое пространства удержания, заменив им содержимое пространства шаблона

• s/\n// — удалить новую строку из пространства шаблонов. Это было введено предыдущей командой H.

• :2 - этикетка 2. Когда управление достигает этой точки, содержимое пространства шаблонов выглядит как начальная строка, независимо от того, началось оно таким образом или нет.

• p — распечатать содержимое пространства шаблона.

• s/^(([^"]*"){4},).*/\1/ — обрезать строку после второй строки в кавычках и ее завершающей запятой. Осталась та часть, которую мы хотим сохранить для использования в последующих неначальных строках.

  Каждый ([^"]*") соответствует и группирует ноль или более символов, отличных от ", за которыми следует ровно один ". {4} требует, чтобы эта группа была сопоставлена ​​ровно четыре раза. , соответствует буквальной запятой. Включаем все это в группы () и фиксируем это (это группа 1), а следующий .* соответствует всему остальному до конца строки. Замена \1 — это обратная ссылка, представляющая содержимое группы 1. Поскольку шаблон соответствует всей строке, группа 1 — это все, что осталось после замены.

• h — скопировать содержимое пространства шаблона в пространство удержания

При действующей опции командной строки -n автоматическая печать пространства шаблона в конце цикла не производится.

Обратите внимание: если вы хотите сохранить первую строку, а не удалять ее, вы можете очень легко изменить приведенное выше, чтобы сделать это. Просто добавьте команду d в конце и запустите без опции -n.

Использование GNU awk для FPAT и многосимвольных RS и при условии, что у вас нет строк ]\n внутри каких-либо полей:

$ cat ./tst.sh
#!/usr/bin/env bash

awk '
    NR == 1 {
        RS = ORS = "]" RS
        OFS = ","
        FPAT = "([^" OFS "]*)|(\"([^\"]|\"\")*\")"
        next
    }
    {
        for ( i=1; i<=NF; i++ ) {
            $i = ( $i ~ /^("")?$/ ? prev[i] : $i )
            prev[i] = $i
        }
        print
    }
' "${@:--}"

$ ./tst.sh file
"Alpha","OldTheme","Some more text"]
"Alpha","OldTheme","Another rest text"]
"Alpha","OldTheme","Yet another text"]
"Yadda","NewTheme","Crazy Text"]
"Yadda","NewTheme","More crazy text"]

Если вы хотите, чтобы манипулировали только первыми двумя полями, просто измените i<=NF на i<=2 или i<NF, в зависимости от того, что вы предпочитаете.

См. Какой самый надежный способ эффективного анализа CSV с помощью awk? для получения дополнительной информации о анализе CSV-файлов с помощью awk.