Elispprocess-send-string выдает неожиданную ошибку «процесс не запущен: прослушайте»

(process-send-string client "asdf")
;; => got asdf from surfer <127.0.0.1:1337>

Насколько я понимаю, «клиент» действует как сокет, который позволяет вам взаимодействовать с сервером.

handle-filter, кстати, не используется.

Обновлено:

Вот некоторые ключевые моменты о сетевой связи Emacs (согласно справочному руководству Elisp):

• Клиент — это не процесс, а скорее «соединение». Вы не можете убить его или послать ему сигналы. Функция delete-process закрывает соединение (по сути, это похоже на сокет).
• Сервер — это процесс, но вы не можете общаться с ним напрямую. Когда он получает запрос на соединение, он создает новое сетевое соединение, представляющее только что установленное соединение.
• Сам сервер не использует фильтры и датчики; они наследуются новым соединением, устанавливаемым при подключении клиента к серверу.
• В отличие от обычных сокетов, объект соединения можно использовать для отправки строки (через process-send-string), но не для ее получения. Вместо этого входная строка отправляется в фильтр; фильтр по умолчанию отправляет его в указанный буфер или отбрасывает, если такой буфер не был указан (или :buffer nil был передан в make-network-process).

Для простоты в прилагаемом коде предполагается только один клиент и один сервер.

(defconst net-port        35678)
(defconst max-connections 1)

(defvar my-surfer         nil) ;; the listening server process
(defvar my-client->server nil) ;; a connection
(defvar my-server->client nil) ;; another connection

;;;; Server-side functions

(defun handle-connection (proc _)
  (message (format " -> handle-connection"))
  (setq my-server->client proc)) ;; set this so 'test-main' can continue

;; Messages from the client are passed here
(defun surfer-filter (proc msg)
  (message "[surfer-filter] %S received %S" proc msg))

(defun surfer-sentinel (proc msg)
  ;; (message "[surfer sentinel] proc %S  msg %s" proc msg)
  (cond ((string-prefix-p "open" msg)
         (handle-connection proc msg))
        ((string-prefix-p "deleted" msg)
         (message "-> server connection deleted"))
        (t (message "something went wrong"))))

;;;; Client-side

;; Messages from the server are sent here
(defun client-filter (_ msg)
  (message "[client-filter] received %S" msg))

;;;;

(defmacro my-delete-process(var-name)
  `(when ,var-name
     (delete-process ,var-name)
     (setq ,var-name nil)))

(defun test-main()
  (interactive)

  (with-current-buffer "*Messages*"
    (let ((inhibit-read-only t))
      (erase-buffer)))

  ;; Clean-up after the previous run
  (my-delete-process my-client->server)
  (my-delete-process my-surfer)
  (my-delete-process my-server->client)

  ;; Messages from the client are passed to 'surfer-filter'.
  ;; Since we have a filter, we can manage without a buffer.
  (setq my-surfer (make-network-process
                   :name "surfer" :server max-connections
                   :host 'local
                   ;; :buffer "surfer"
                   :filter 'surfer-filter
                   :service net-port :sentinel 'surfer-sentinel))

  ;; Messages from the server are passed to 'client-filter'
  (setq my-client->server
        (make-network-process
         :name "client" ;; :buffer "client"
         :filter 'client-filter
         :remote (vector 127 0 0 1 net-port)))

  (message "waiting for server connection...")
  (let ((i 0))
    ;; Wait for 2 seconds max
    (while (and (< i 20)
                (not my-server->client))
      (cl-incf i)
      (sleep-for 0.1)))
  (cl-assert my-server->client)

  (process-send-string my-client->server
                       "a message from the client")
  (process-send-string my-server->client
                       "a message from the server"))

Возможный результат:

waiting for server connection...
 -> handle-connection
[client-filter] received "a message from the server"
[surfer-filter] #<process surfer <127.0.0.1:45054>> received "a message from the client"