Excel/Vba/ADODB: как подключиться к таблице (ListObject) только по ее имени, чтобы выполнить запрос?

Я написал ответ об этом несколько часов назад, но мне пришлось его удалить после того, как GSerg заметил мою ошибку из-за недосыпа, наверное. Спасибо за предупреждения GSerg...

Теперь я подготовил еще один вариант;

• Закрытая книга с именем «Employee.xlsx» имеет «ListObject» с именем «Table1» на листе «Sheet1». (Обратите внимание, что «Table1» не является определенным именем.)

• Книга с именем «Book1.xlsm» содержит приведенный ниже макрос, который: преобразует закрытую книгу ("Employee.xlsx") в zip-файл, извлекает содержимое zip-файла во временную папку (с именем "zipFolder") и получает адрес диапазона данных ListObject ("Table1") из связанный XML-файл ".....\xl\tables\Table1.xml"

• Используя этот адрес диапазона, данные закрытой книги выгружаются на активный лист, начиная с ячейки A2, с помощью ADO.

Этот подход может быть не совсем аккуратным, но если кто-то хочет работать с именем «ListObject», а не с определенным именем, это может быть альтернативой.

Обе книги должны находиться в одной папке...

Итак, код;

Option Explicit
'
Sub Test()
    Dim ListObjectName As String, objShell As Object, zipFile As Variant, myFile As String, zipFolder As Variant
    Dim xDoc As Object, myNode As Object, DataRange As String, adoCN As Object, RS As Object, strSQL As String
    
    ListObjectName = "Table1"
    
    zipFolder = ThisWorkbook.Path & Application.PathSeparator & "zipFolder"
    
    If Dir(zipFolder, vbDirectory) = "" Then
        MkDir ThisWorkbook.Path & "\zipFolder"
    End If
    
    myFile = ThisWorkbook.Path & "\Employee.xlsx"

    zipFile = ThisWorkbook.Path & "\zipFolder\Employee.zip"
    
    Name myFile As zipFile
    
    Set objShell = CreateObject("Shell.Application")
    objShell.Namespace(zipFolder).CopyHere objShell.Namespace(zipFile).items
    
    Name zipFile As myFile
    
    Set xDoc = CreateObject("MSXML2.DOMDocument")
    xDoc.async = False
    xDoc.validateOnParse = False
    
    xDoc.Load zipFolder & "\xl\tables\" & ListObjectName & ".xml"
    
    Set myNode = xDoc.SelectSingleNode("//table")
    DataRange = myNode.Attributes.getNamedItem("ref").Text
    
    Range("A2:C" & Rows.Count) = Empty
    
    Set adoCN = CreateObject("ADODB.Connection")
    Set RS = CreateObject("ADODB.Recordset")
    
    adoCN.Provider = "Microsoft.ACE.OLEDB.12.0"
    adoCN.Properties("Data Source") = myFile
    adoCN.Properties("Extended Properties") = "Excel 12.0 Macro; HDR=Yes; IMEX=1"
    adoCN.Open
        
    strSQL = "Select * From [Sheet1$" & DataRange & "]"
    
    RS.Open strSQL, adoCN
    
    Range("A2").CopyFromRecordset RS
    
    CreateObject("Scripting.FileSystemObject").DeleteFolder zipFolder
        
    RS.Close
    adoCN.Close
    
    Set RS = Nothing
    Set adoCN = Nothing
    Set adoCN = Nothing
    Set xDoc = Nothing
    Set objShell = Nothing
End Sub