Excel VBA: End(xlUp) и End(xlDown) заканчиваются строкой 244, которая пуста?

Я не могу подтвердить ваши выводы. Имея пустой ActiveSheet и пустой Sheet9, приведенный ниже код заполнил ActiveSheet нулями B2:GQ244. Затем он считывает последнюю строку xlUp как 244 и xlDown как 2. Оба этих значения соответствуют ожидаемым. Возможно, у вас есть настройка, подавляющая отображение нулей. Однако, как объяснялось в моем комментарии выше, ячейка, которая выглядит пустой, не обязательно является пустой, и это также применимо к ячейке, содержащей NullString, вставленную вашей формулой, даже если формула была впоследствии удалена, оставив нулевую строку на своем месте.

Sub Examine()
    
    Dim last_row As Long
    Dim i As Long

    With ActiveSheet
        .Range("B2:GQ244").Formula = "=IF(ISERROR(FIND( B$1,Sheet9!$H34)),"""",Sheet9!$I34)"
        
        'paste by value to get rid of formulae
        
        .Range("B2:GQ244").Copy
        .Range("B2").PasteSpecial Paste:=xlPasteValues
        
        'sort by column
        
        For i = 2 To 200 Step 1
            Range(.Cells(2, i), .Cells(245, i)).Sort Key1:=.Cells(2, i), Order1:=xlAscending
            last_row = .Cells(.Rows.Count, i).End(xlUp).Row
            Debug.Print last_row            ' returns 244
            last_row = .Cells(1, i).End(xlDown).Row
            Debug.Print last_row            ' returns 2
        Next i
    End With
End Sub

Таким образом, остается единственная загадка, почему .Cells(1, i).End(xlDown).Row дает вам значение 244. Это не так. Поэтому решение должно быть в проведении вашего теста, а не в его результате. Сравните свой метод тестирования с тем, который я использовал выше.

Приведенный ниже код удалит все нулевые строки в нижней части столбцов, а также те, которые содержат нули.

Sub ClearBlankCells()
    ' 146
    
    Dim Rng         As Range            ' working range
    Dim R           As Long             ' intermediate: row
    Dim C           As Long             ' loop counter: columns

    Application.ScreenUpdating = False
    With ActiveSheet
        With .Range("B2:GQ244")
            .Formula = "=IF(ISERROR(FIND( B$1,Sheet9!$H34)),"""",Sheet9!$I34)"
            ' replace formulas with their values
            .Copy
            .PasteSpecial Paste:=xlPasteValues
        End With
        Application.CutCopyMode = False

        For C = 2 To 200 Step 1
            Set Rng = .Columns(C)
            R = Application.Evaluate("SUMPRODUCT((" & Rng.Address & "<>"""")*(" & _
                                                      Rng.Address & "<>0)*1)")
            If R > 0 Then
                Set Rng = Range(.Cells(R + 1, C), .Cells(Rows.Count, C))
                Rng.ClearContents
            End If
            ' sort by column
'            Range(.Cells(2, C), .Cells(245, C)).Sort Key1:=.Cells(2, C), Order1:=xlAscending
        Next C
    End With
    Application.ScreenUpdating = True
End Sub

Обратите внимание, что в блок данных над нижней частью каждого столбца, включая заголовок, нельзя включать пробелы или нули.

Сортировка должна быть выполнена после того, как такие ячейки будут удалены, но я оставил инструкции сортировки затемненными, потому что это неправильно либо синтаксически, либо по идее. Если вам нужно отсортировать каждый столбец, синтаксис неверен, потому что синтаксис сортирует весь лист. С другой стороны, если вы хотите отсортировать весь лист, вам не нужно делать это в цикле 200 раз.

Код работает очень медленно, что приводит к двум наблюдениям.

1. Он тратит 99% своего времени на устранение ущерба, нанесенного в первой линии.
2. Он рассматривает диапазон данных, который значительно больше, чем на самом деле требуется. Никто не хочет смотреть на лист из 200 столбцов и 244 строк.

Поэтому должны быть гораздо лучшие способы добиться того, чего вы хотите.