Использование Excel для VLOOKUP и WildCard не работает

Вместо использования VLOOKUP() лучше использовать функцию XLOOKUP() в контексте поиска по соответствующим ключевым словам и возврата соответствующих поставщиков:

=XLOOKUP(1,1-ISERR(SEARCH($H$2:$H$3,E2)),I$2:I$3,"Not Found")

И если вы собираетесь использовать только VLOOKUP(), попробуйте использовать следующее:

=IFERROR(TOCOL(VLOOKUP(TEXTSPLIT(E2," "),$H$2:$I$3,2,0),2),"Not Found")

Или, используя функцию LOOKUP():

=IFERROR(LOOKUP(2,1/(SEARCH($H$2:$H$3,E2)),$I$2:$I$3),"Not Found")

Или можно использовать следующее, но оно будет пустым, если ничего не найдено:

=TEXTJOIN("",1,IF(ISNUMBER(SEARCH($H$2:$H$3,E2)),$I$2:$I$3,""))

Обратите внимание, что я использовал 1-ISERR(), что эквивалентно ISNUMBER(), вы также можете использовать ISNUMBER() вместо первого!

Еще одна вещь: лучше добавить границы до и после ключевого слова:

=XLOOKUP(TRUE,ISNUMBER(SEARCH(" "&$H$2:$H$3&" "," "&E2&" ")),I$2:I$3,"Not Found")

Функция XLOOKUP() не нуждается в других функциях, если нет совпадения, возвращающего Not Found !

Вместо VLOOKUP предлагаю использовать INDEX(...,MATCH(...

=INDEX($M$2:$M$3,MATCH(TRUE,ISNUMBER(SEARCH($L$2:$L$3,E2)),0))

Вы можете использовать инструмент оценки формул, чтобы следовать логике.

Рекурсивное развлечение

(Немного многословная альтернатива, похожая на версию Рона)

Предполагая, что у вас есть Microsoft 365, мы могли бы использовать функцию рекурсивного сопоставления.

Предостережение: из-за текущих ограничений этот метод будет работать, только если таблица поиска содержит 341 строку или меньше (=QUOTIENT(1024, 2 parameters + 1).

1. Для удобства определите значения поиска в виде таблицы . Здесь я назвал это как Vendor_Lookup

   Вы можете ввести ключевые слова с подстановочными знаками (? и *) — например, для электрической компании в примере.

2. Введите функцию сопоставления , здесь она называется find_first, так как она найдет первое совпадение.

   1. В Менеджере имен введите новый элемент с именем find_first.
   2. Введите следующее в качестве ссылки: =LAMBDA(lookup_table,text, IF(ISNUMBER(SEARCH(TAKE(lookup_table, 1, 1), text)), TAKE(lookup_table, 1, -1), IF(ROWS(lookup_table) = 1, "Not found", find_first(DROP(lookup_table, 1), text))))

3. В первой ячейке столбца «Поставщик» введите следующее, указав весь диапазон для описания:

   =find_first(Vendor_Lookup,E2:E5)

Вот функция в развернутом виде:

TAKE(lookup_table, 1, 1) — это искомое значение, а TAKE(lookup_table, 1, -1) — возвращаемое значение. Функция TAKE - Служба поддержки Microsoft

=LAMBDA(lookup_table, text,
    IF(
        ISNUMBER(SEARCH(TAKE(lookup_table, 1, 1), text)),
        TAKE(lookup_table, 1, -1),
        IF(
            ROWS(lookup_table) = 1,
            "Not found",
            find_first(DROP(lookup_table, 1), text)
        )
    )
)

Нерекурсивный

Добавьте функцию find_all_matches в Диспетчер имен аналогично описанному выше:

Неформатированная версия

=LAMBDA(lookup_table,text, LET(match_1, LAMBDA(row_, LET(pos, SEARCH(TAKE(row_, 1, 1), text), IF(ISNUMBER(pos), TAKE(row_, 1, -1), pos))), matches, BYROW(lookup_table, match_1), errors_removed, TOCOL(matches, 2), joined, TEXTJOIN(" OR ", , errors_removed), result, IFERROR(joined, "Not found"), result))

=LAMBDA(lookup_table, text,
    LET(
        match_1, LAMBDA(row_,
            LET(
                pos, SEARCH(TAKE(row_, 1, 1), text),
                IF(ISNUMBER(pos), TAKE(row_, 1, -1), pos)
            )
        ),
        matches, BYROW(lookup_table, match_1),
        errors_removed, TOCOL(matches, 2),
        joined, TEXTJOIN(" OR ", , errors_removed),
        result, IFERROR(joined, "Not found"),
        result
    )
)