Использование массивов с циклами

Я не уверен, что понимаю, о чем вы спрашиваете, но, судя по вашему коду, похоже, вы могли бы использовать помощь в преобразовании того, что вы написали, используя 12 переменных, в код, использующий один массив. Вот простейшее преобразование вашего существующего кода для использования одного массива вместо множества переменных:

Option Explicit
Dim d(12) As Variant

Sub example1()
    d(1) = Sheet1.Range("A4:AX34")
    d(2) = Sheet2.Range("A4:AX34")
    d(3) = Sheet3.Range("A4:AX34")
    d(4) = Sheet4.Range("A4:AX34")
    d(5) = Sheet5.Range("A4:AX34")
    d(6) = Sheet6.Range("A4:AX34")
    d(7) = Sheet7.Range("A4:AX34")
    d(8) = Sheet8.Range("A4:AX34")
    d(9) = Sheet9.Range("A4:AX34")
    d(10) = Sheet10.Range("A4:AX34")
    d(11) = Sheet11.Range("A4:AX34")
    d(12) = Sheet12.Range("A4:AX34")
End Sub

Однако неясно, чего вы пытаетесь достичь. Я не уверен, что значит просто присвоить вариант диапазону. Если вы пытаетесь, чтобы каждая переменная (или элемент массива) ссылалась на диапазон на каждом листе, вам нужно будет использовать ключевое слово set для привязки переменной (или элемента массива) к объекту. В этом случае несколько эффективнее объявить массив типа range вместо variant следующим образом. Я добавил цикл для печати значения из первой строки, третьего столбца в диапазоне на каждом листе (это ячейка C4 на листе) в демонстрационных целях.

Option Explicit
Dim d(12) As Range

Sub example1()
    Dim i As Integer
    Set d(1) = Sheet1.Range("A4:AX34")
    Set d(2) = Sheet2.Range("A4:AX34")
    Set d(3) = Sheet3.Range("A4:AX34")
    Set d(4) = Sheet4.Range("A4:AX34")
    Set d(5) = Sheet5.Range("A4:AX34")
    Set d(6) = Sheet6.Range("A4:AX34")
    Set d(7) = Sheet7.Range("A4:AX34")
    Set d(8) = Sheet8.Range("A4:AX34")
    Set d(9) = Sheet9.Range("A4:AX34")
    Set d(10) = Sheet10.Range("A4:AX34")
    Set d(11) = Sheet11.Range("A4:AX34")
    Set d(12) = Sheet12.Range("A4:AX34")

    For i = 1 To 12
        Debug.Print d(i).Cells(1, 3).Address, d(i).Cells(1, 3).Value
    Next
End Sub

Этот код немного длиннее, чем мне хотелось бы, но мы должны обращаться к каждому листу по имени его объекта. Если имена листов имеют шаблон, похожий на кодовые имена, мы можем значительно сократить код:

Option Explicit
Dim d(12) As Range

Sub example1()
    Dim i As Integer
    
    For i = 1 To 12
       Set d(i) = ThisWorkbook.Worksheets("Sheet" & i).Range("A4:AX34")
       Debug.Print d(i).Cells(1, 3).Address, d(i).Cells(1, 3).Value
    Next
    
End Sub

Важной особенностью массивов в VBA является то, что они начинают считать с 0, а не с 1. Таким образом, во всех приведенных выше примерах у нас есть неиспользуемый элемент массива в самом начале. Мы можем ввести директиву компилятора (Option Base 1) поверх кода, чтобы указать интерпретатору VBA начинать подсчет массивов с 1 следующим образом:

Option Base 1
Option Explicit
Dim d(12) As Range

Sub example1()
    Dim i As Integer
    
    For i = 1 To 12
       Set d(i) = ThisWorkbook.Worksheets("Sheet" & i).Range("A4:AX34")
       Debug.Print d(i).Cells(1, 3).Address, d(i).Cells(1, 3).Value
    Next
    
End Sub

Однако я думаю, что чаще всего это делается для того, чтобы массивы считались с нуля и просто смещали индекс массива по мере необходимости следующим образом:

Option Explicit
Dim d(11) As Range

Sub example1()
    Dim i As Integer
    
    For i = 0 To 11
       Set d(i) = ThisWorkbook.Worksheets("Sheet" & i + 1).Range("A4:AX34")
       Debug.Print d(i).Cells(1, 3).Address, d(i).Cells(1, 3).Value
    Next
    
End Sub

Это все хорошо, но мы часто не знаем, сколько элементов нам нужно в массиве до запуска кода. Чтобы сделать размер массива динамическим, мы объявляем массив без указания размера и используем оператор ReDim для установки его размера во время выполнения (обратите внимание на пустые круглые скобки при объявлении массива и использование оператора «Ubound» в операторе «Ubound»). Для цикла, чтобы найти верхнюю границу массива):

Option Explicit
Dim d() As Range

Sub example1()
    Dim i As Integer
    ReDim d(ThisWorkbook.Worksheets.Count - 1)
    For i = 0 To UBound(d)
       Set d(i) = ThisWorkbook.Worksheets("Sheet" & i + 1).Range("A4:AX34")
       Debug.Print d(i).Cells(1, 3).Address, d(i).Cells(1, 3).Value
    Next
    
End Sub

Наконец, из исходной публикации кода я вижу, что вы знакомы с коллекциями. Поскольку коллекция — это объект со свойствами и методами, может быть проще использовать коллекцию вместо массива, который является просто схемой распределения памяти.

Option Explicit
Dim d As New Collection

Sub example1()
    Dim i As Integer
    
    For i = 1 To ThisWorkbook.Worksheets.Count
       d.Add ThisWorkbook.Worksheets("Sheet" & i).Range("A4:AX34")
       Debug.Print d(i).Cells(1, 3).Address, d(i).Cells(1, 3).Value
    Next
    
End Sub

Обратите внимание, что коллекции начинают считаться с 1.