Использование replace() для определенного столбца в таблице для изменения дат

Вы не можете использовать «Заменить» или «Заменить» в назначении диапазона ячеек, и вы не можете применить формулу ко всему столбцу, который ссылается на себя (как в вашей попытке).

Если это всего лишь небольшая таблица, вы можете использовать свое решение для одной ячейки в ленивом цикле через ListColumn:

Dim raCell as Range

For each raCell in wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold").DataBodyRange
    raCell = WorksheetFunction.Substitute(raCell, ".", "/")
Next

В качестве альтернативы, как указал Скотт, использование встроенной функции VBA Replace более эффективно:

Dim raCell as Range

For each raCell in wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold").DataBodyRange
    raCell = Replace(raCell, ".", "/")
Next

Тем не менее, оба решения по-прежнему неэффективны, если вы работаете с большим списком.

Более эффективным решением является создание временного рабочего столбца с помощью функции ПОДСТАВИТЬ:

With wsDormant.ListObjects("Table_Dormant_Stock").ListColumns.Add
    .DataBodyRange.Formula = "=SUBSTITUTE([@[Days Last Sold]], ""."", ""/"")"
    wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold").DataBodyRange.Value = .DataBodyRange.Value
    .Delete
End With

Другим эффективным решением является копирование всех значений в массив, цикл по этому массиву, а затем копирование обновленных значений обратно в электронную таблицу:

Dim varArray As Variant, i As Integer

With wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold")
    varArray = .DataBodyRange
    For i = 1 To UBound(varArray, 1)
        varArray(i, 1) = Replace(varArray(i, 1), ".", "/")
    Next i
    .DataBodyRange = varArray
End With