Использование типа объекта SQL в процедуре и использование их в функции конвейера

В вашей процедуре есть пара простых ошибок; имя курсора c1, но позже вы ссылаетесь на него как c1j, и вы пытаетесь назначить весь экземпляр объекта таблицы как элемент таблицы, а не просто запись:

l_tab(l_tab.last) := tst_rec(i.icri, i.datesitu, i.curr, i.ctmstm);

Более серьезная проблема заключается в том, что вы смешиваете объектные и собственные типы. Когда вы удаляете коллекцию с помощью предложения table(), вы возвращаете несколько столбцов, а не один тип объекта; поэтому вам придется реконструировать свой объект:

  select tst_plus_rec(deal_id, datesitu, acc_code, acca_cust_grp, curr, ctmstm)
  bulk collect into l_tab_plus
  from table(get_plus_sdb_w(l_tab));

и тогда вставка forall должна будет вернуться к каждому атрибуту объекта:

  forall idx IN INDICES OF l_tab_plus
  insert into tst_cri_plus_sdb (deal_id, datesitu, acc_code, acca_cust_grp, curr, ctmstm)
  values (l_tab_plus(idx).deal_id, l_tab_plus(idx).datesitu, l_tab_plus(idx).acc_code,
    l_tab_plus(idx).acca_cust_grp, l_tab_plus(idx).curr, l_tab_plus(idx).ctmstm);

Итак, складываем их вместе:

create or replace procedure tst_insert
is
  cursor c1 is select * from tst_cri_sdb;
  l_tab tst_table_rec := tst_table_rec();
-- no need to initialise this one as bulk collect will replace it
--  l_tab_plus tst_plus_table_rec := tst_plus_table_rec();
  l_tab_plus tst_plus_table_rec;
begin
  for i in c1
  loop
    l_tab.extend;
    l_tab(l_tab.last) := tst_rec(i.icri, i.datesitu, i.curr, i.ctmstm);
  end loop;

  select tst_plus_rec(deal_id, datesitu, acc_code, acca_cust_grp, curr, ctmstm)
  bulk collect into l_tab_plus
  from table(get_plus_sdb_w(l_tab));

  forall idx IN INDICES OF l_tab_plus
  insert into tst_cri_plus_sdb (deal_id, datesitu, acc_code, acca_cust_grp, curr, ctmstm)
  values (l_tab_plus(idx).deal_id, l_tab_plus(idx).datesitu, l_tab_plus(idx).acc_code,
    l_tab_plus(idx).acca_cust_grp, l_tab_plus(idx).curr, l_tab_plus(idx).ctmstm);
end;
/

exec tst_insert;

select * from tst_cri_plus_sdb;

   DEAL_ID DATESITU     ACC_CODE ACCA_CUST_ CUR CTMST
---------- ---------- ---------- ---------- --- -----
       100 2019-03-13     100345 A1105      EUR STM  
       100 2019-03-13     200345 A4405      EUR STM  
       100 2019-03-13     300345 A3305      EUR STM  
       100 2019-03-13     500345 A5505      EUR STM  
       100 2019-03-13     600345 A6605      EUR STM  
       100 2019-03-13     700345 A7705      EUR STM  
       101 2019-03-14     100345 A1105      GBP CTM  
       101 2019-03-14     200345 A4405      GBP CTM  
...
       104 2019-03-17     600345 A6605      EUR STM  
       104 2019-03-17     700345 A7705      EUR STM  

30 rows selected. 

Вам не нужна промежуточная коллекция с bulk collect и forall, вы можете вставить ее напрямую:

create or replace procedure tst_insert
is
  cursor c1 is select * from tst_cri_sdb;
  l_tab tst_table_rec := tst_table_rec();
-- you don't need this variable at all now
--  l_tab_plus tst_plus_table_rec;
begin
  for i in c1
  loop
    l_tab.extend;
    l_tab(l_tab.last) := tst_rec(i.icri, i.datesitu, i.curr, i.ctmstm);
  end loop;

  insert into tst_cri_plus_sdb
  select *
  from table(get_plus_sdb_w(l_tab));
end;
/

который получает тот же результат. И вы можете избежать цикла заполнения, изменив его на массовый сбор:

create or replace procedure tst_insert
is
  l_tab tst_table_rec;
begin
  select tst_rec(icri, datesitu, curr, ctmstm)
  bulk collect into l_tab
  from tst_cri_sdb;

  insert into tst_cri_plus_sdb
  select *
  from table(get_plus_sdb_w(l_tab));
end;
/

дб <> рабочий пример

В более поздних версиях Oracle вы могли использовать сделать это все в пакете без каких-либо типов объектов уровня схемы; но поскольку вы используете 11g, это не сработает (предложение table() выдаст PLS-00642).