Извлечь одно число из строки с условием

Я думаю, что ответ уже содержится в предложенных вами требованиях Вам нужно добавить оператор if в качестве проверки, чтобы сделать это, или оператор case, я рекомендую определить дополнительную переменную для проверки, прежде чем добавлять к результатам. Определите это как символ вашей строки, которую вы перебираете. Пример:

Dim Check as string

Check = Mid(CellRef, i, 1)
If Check =  Chr(34) then GetNumeric = Result    

Работа с несколькими числами без дальнейшего определения приведет к неразрешимым ситуациям, например, в вашем предпоследнем примере нет указания, является ли 1 или 36 правильным.

Возможно, создайте свой собственный UDF, используя регулярное выражение. Возможно что-то вроде:

Public Function RegexExtract(str, pat, Optional gFlag As Boolean = False, Optional pos As Integer = 0, Optional cse as Boolean = True) As String

Static RE As Object: If RE Is Nothing Then Set RE = CreateObject("vbscript.regexp")

RE.Pattern = pat
RE.Global = gFlag
RE.IgnoreCase = cse

If RE.Test(str) Then
    RegexExtract = RE.Execute(str)(pos)
Else
    RegexExtract = vbNullString
End If

End Function

Обратите внимание, что я создал необязательный глобальный флаг, который по умолчанию является ложным, который должен просто вытащить самое первое попадание в ячейку. Необязательная переменная pos предназначена для возврата определенного совпадения, если вы хотите каким-то образом вернуть другие числа, когда вы устанавливаете глобальный флаг в значение true. Также обратите внимание на использование флага case, для которого установлено значение true, чтобы по умолчанию не учитывать регистр.

Вы можете вызвать вышеуказанное как:

=IFERROR(--RegexExtract(A1,"\b\d\d?(?!\d)(?=\s*(?:""|''|in(?:ch)?\b)?)"),"")

Используемый шаблон означает:

• \b\d\d? - граница слова с 1 цифрой и 2-й необязательной;
• (?!\d) - Отрицательный просмотр вперед, чтобы не утверждать больше цифр;
• (?=\s*(?:"|''|in(?:ch)?\b)?) - Положительный просмотр вперед для утверждения позиции сопровождается 0+ (жадными) символами пробела и:
  • " - Двойная кавычка или;
  • '' - Две одинарные кавычки или;
  • in(?:ch)?\b - Буквально «in», за которым следует необязательный «ch» и граница слова, чтобы подтвердить, что буквы не являются частью большей подстроки, чтобы предотвратить ложные срабатывания.

РЕДАКТИРОВАТЬ1:

Согласно комментариям OP ниже; есть случай, когда может быть число процентов, которое не находится на 1-й позиции. Поскольку OP позволяет также сопоставлять число без дюймов, добавление здесь состоит в том, чтобы включить отрицательный просмотр вперед, который будет утверждать, что нет второго вхождения действительного шаблона:

\b\d\d?(?!\d|.*\b\d+\s*(?:""|''|in(?:ch)?\b))(?=\s*(?:""|''|in(?:ch)?\b)?)

Я полагаю, что это неявно то же самое, что и:

\b\d\d?(?!\d|.*\b\d+\s*(?:""|''|in(?:ch)?\b))

РЕДАКТИРОВАТЬ2:

Чтобы разрешить десятичные дроби, вы можете включить необязательную группу без захвата:

=IFERROR(--RegexExtract(A2,"\b\d\d?(?:\.\d+)?(?!\d|.*\b\d+\s*(?:""|''|in(?:ch)?\b))"),"")

Вот два решения, которые не требуют Regex.

Первое решение применяет ряд преобразований к строке, чтобы мы могли использовать Split для получения последовательности строк, некоторые из которых будут числами. Проблема здесь заключается в выборе правильных преобразований, чтобы можно было применить разделение для изоляции чисел. Иногда это может быть невозможно.

Второе решение просто анализирует строку до тех пор, пока не будет извлечена последовательность числовых символов, а затем возвращает эту числовую строку для дальнейшей обработки. Это, вероятно, лучшее решение в вашем случае.

Обратите внимание, что ни одно из решений не тестировалось для крайних случаев.

Учитывая, что вы пытаетесь проанализировать то, что кажется текстом произвольной формы, может быть много пограничных случаев.

Sub Test()

    Dim myC As Collection
    Set myC = New Collection
    With myC
    
        .Add "INSPECT - 8" & Chr$(34) & " Water 12 Pipe    8"
        .Add "INSPECT- 18" & Chr$(34) & " Water 12   18"
        .Add "PM-6in Pipe From M37 st 6"
        .Add "PM- 6 inch Pipe From H44    6"
        .Add "PM-36 Pipe From M-1T    36"
        .Add "PM-123 Pipe From MT"
        
    End With
    

    Dim myItem As Variant
    Dim myNumber As Long
    For Each myItem In myC
    
    'Option 1
'        If TryGetFirstNumber(myItem, myNumber) Then
'            Debug.Print myNumber
'        End If
     ' option 2
'        Debug.Print ParseFirstNumber(VBA.CStr(myItem))
    Next
    
End Sub

' Pass ByVal so we don't alter the original string
Public Function ApplyTransforms(ByVal ipString As String) As String

    ipString = VBA.LCase(ipString)
    ipString = VBA.Replace(ipString, "-", " ")
    ipString = VBA.Replace(ipString, VBA.Chr(34), " ")
    ipString = VBA.Replace(ipString, "in ", " ")
    ipString = VBA.Replace(ipString, "inch ", " ")
    
    ApplyTransforms = ipString
    
End Function

'The try function indicates success by the returned boolean value, the result of the success is returned Byref in parameter opNumber
Public Function TryGetFirstNumber(ByRef ipString As Variant, ByRef opNumber As Long, Optional ipLength As Long = 2) As Boolean

    
    Dim myArray As Variant
    myArray = VBA.Split(ApplyTransforms(ipString))
    
    Dim myItem As Variant
    For Each myItem In myArray
    
        If VBA.IsNumeric(myItem) Then
        
            If VBA.Len(myItem) <= ipLength Then
            
                opNumber = VBA.CLng(myItem)
                TryGetFirstNumber = True
                Exit Function
                
            End If
            
        End If
            
    Next
    
    TryGetFirstNumber = False
    
End Function


Public Function ParseFirstNumber(ByRef ipString As String) As String

    Dim myIndex As Long
    myIndex = 1
    
    Dim myLen As Long
    myLen = VBA.Len(ipString)
    
    Dim myNumber As String
    myNumber = vbNullString

    Do While myIndex <= myLen
        If VBA.InStr("0123456789", VBA.Mid$(ipString, myIndex, 1)) > 0 Then
            Exit Do
        End If
        myIndex = myIndex + 1
    Loop

    If myIndex > myLen Then
        ParseFirstNumber = myNumber
        Exit Function
    End If

    Do While VBA.InStr("0123456789", VBA.Mid$(ipString, myIndex, 1)) > 0
        myNumber = myNumber & VBA.Mid$(ipString, myIndex, 1)
        myIndex = myIndex + 1
        If myIndex > myLen Then
            ParseFirstNumber = myNumber
            Exit Function
        End If
    Loop
    
    ParseFirstNumber = myNumber
    
End Function

Пожалуйста, (также) проверьте следующий способ. Он использует стандартный VBA и массив для обработки. Содержимое обработанного массива будет удалено в конце кода, поэтому он должен быть очень быстрым даже для больших диапазонов. Предполагается, что обрабатываемый диапазон начинается с "A1", заголовки, существующие в первой строке листа:

Sub extractInchesNoFromAllRange()
   Dim sh As Worksheet, lastR As Long, arr, i As Long
   Dim dblQ As Long, sQ As Long, strIn As Long, No As String
   
   Set sh = ActiveSheet
   lastR = sh.Range("A" & sh.rows.count).End(xlUp).row
   
   arr = sh.Range("A2:B" & lastR).Value2
   
   For i = 1 To UBound(arr)
        dblQ = InStr(arr(i, 1), """") 'check if a double quote caracters exists and return its postition if it does
        sQ = InStr(arr(i, 1), "''")      'check if two simple quote caracters exists and return its postition if it does
        strIn = InStr(arr(i, 1), "in") 'the same as above for "in" string
        
        No = "" 'reinitialize the variable to keep the extracted number (as string...)
        If dblQ > 0 Or sQ > 0 Then 'if doble quote exists:
            If IsNumeric(Mid(arr(i, 1), IIf(dblQ > 0, dblQ, sQ) - 1, 1)) Then 'if a number exists before the quote ch
                No = Mid(arr(i, 1), IIf(dblQ > 0, dblQ, sQ) - 1, 1)                      'extract first digit
                arr(i, 2) = extractNo(IIf(dblQ > 0, dblQ, sQ) - 2, CStr(arr(i, 1)), No, True) 'call the function which make extraction by (backward) iteration
            End If
        ElseIf strIn > 0 Then 'if "in" exists:
            If Mid(arr(i, 1), strIn + 2, 1) = " " Or Mid(arr(i, 1), strIn + 2, 2) = "ch" Or strIn + 1 = Len(arr(i, 1)) Then
                If Mid(arr(i, 1), strIn - 1, 1) = " " Then
                    arr(i, 2) = extractNo(strIn - 2, CStr(arr(i, 1)), No, True)
                Else
                    arr(i, 2) = extractNo(strIn - 1, CStr(arr(i, 1)), No, True)
                End If
            End If
        Else
            arr(i, 2) = extractNo(0, CStr(arr(i, 1)), "")
        End If
   Next i
   
   'drop the processed arran content back in its range:
   sh.Range("A2").Resize(UBound(arr), UBound(arr, 2)).Value2 = arr
End Sub

Function extractNo(pos As Long, str As String, No As String, Optional boolChar = False) As Variant
   Dim i As Long, boolNo As Boolean
   
   On Error GoTo WrongPatt
   If boolChar Then 'if one of the searched characters has been found:
        For i = pos To 1 Step -1
            If IsNumeric(Mid(str, i, 1)) Or Mid(str, i, 1) = "." Then
                No = CStr(Mid(str, i, 1)) & No
            Else
                extractNo = CDbl(No): Exit For
            End If
        Next i
  Else 'if no searched string has been found:
        For i = 1 To Len(str)
            If IsNumeric(Mid(str, i, 1)) Then
                boolNo = True
                No = No & Mid(str, i, 1)
            Else
                If boolNo Then Exit For
            End If
        Next i
        If Len(No) <= 2 And No <> "" Then
                extractNo = CLng(No)
        Else
                extractNo = ""
        End If
  End If
  Exit Function
  
WrongPatt:
   extractNo = "Wrong pttern"
End Function

Но приведенный выше код будет обрабатывать только строку шаблона, которую вы указали в своем вопросе. Если, например, будет больше символов двойных кавычек с другим назначением ** перед тем, у которого есть число перед ним), код обработает только первый найденный. У него могут возникнуть проблемы, если искомые строки являются первыми в строке и т. д. Его можно адаптировать для работы с большим количеством условий, но мы здесь не умеем читать мысли, чтобы охватывать такие не показанные случаи...