Как динамически создать массив фиксированного размера в Аде?

Размер объекта массива не может быть изменен после объявления объекта. Хотя это может показаться проблемой, Ада предоставляет решение путем объявления объекта во внутреннем блоке.

В приведенном ниже примере тип вашего массива определяется как неограниченный массив element_type. Замените любой тип, который вы хотите, чтобы ваш массив содержал в вашем фактическом коде. Этот неограниченный тип позволяет создавать экземпляры типа с любыми необходимыми размерами.

type Grid_Type is array(Natural range <>, Natural range <>) of element_type;

В вашей функции прочитайте информацию о границах массива, а затем объявите экземпляр, используя эти границы массива.

function Make_Grid return Grid_Type is
   Dim1_Min, Dim1_Max : Natural;
   Dim2_Min, Dim2_Max : Natural;
begin
   get(Dim1_Min);
   get(Dim1_Max);
   get(Dim2_Min);
   get(Dim2_Max);

   declare
      New_Grid : Grid_Type(Dim1_Min..Dim1_Max, Dim2_Min..Dim2_Max);
   begin
      return New_Grid;
   end;
end Make_Grid;

Внутренний блок создает новый экземпляр Grid_Type, используя значения, считанные из ввода. Функция просто возвращает объект из внутреннего блока. Раздел 5.6 Справочного руководства по Ада описывает операторы блока Ада.

В следующем примере показано, как это работает для массива целых чисел:

package Grids is
   type Grid_type is array(Natural range <>, Natural range <>) of Integer;
   function make_grid return Grid_Type;
end Grids;


with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

package body Grids is

   ---------------
   -- make_grid --
   ---------------

   function make_grid return Grid_Type is
      Dim1_Min, Dim1_Max : Natural;
      Dim2_Min, Dim2_Max : Natural;
   begin
      Get(Dim1_Min);
      Get(Dim1_Max);
      Get(Dim2_Min);
      Get(Dim2_Max);

      declare
         New_Grid : Grid_Type(Dim1_Min..Dim1_Max, Dim2_Min..Dim2_Max) :=
           (Others =>(Others => 0));
      begin
         return New_Grid;
      end;

   end make_grid;

end Grids;

Основная тестовая программа для этой программы:

with Ada.Text_IO; use Ada.Text_IO;
with Grids; use Grids;

procedure Grids_Test is
   The_Grid : Grid_type := Make_Grid;
begin
   Put_Line("Grid Dimensions");
   Put_Line(Natural'Image(The_Grid'First(1)) & ".." &
              Natural'Image(The_Grid'Last(1)) & " , " &
              Natural'Image(The_Grid'First(2)) & "..." &
                Natural'Image(The_Grid'Last(2)));
end Grids_Test;

Ввод и вывод выполнения примера:

0
10
20
30
Grid Dimensions
 0.. 10 ,  20... 30

В дополнение к использованию блоков объявления для временного хранения результата вашей функции вы также можете использовать Ада.Контейнеры.Индефините_Холдерс для более постоянного хранения результата.

Вам нужно будет создать экземпляр общего

use type Grid.Grid_Type;  -- necessary to get the " = " operation
package Grid_Holders is new Ada.Containers.Indefinite_Holders(Grid.Grid_Type);

Вы бы объявили это как

New_Grid : Grid_Holders.Holder;

и во время выполнения вы можете инициализировать его, используя

New_Grid := Grid_Holders.To_Holder(Grid.Get_Grid(Boundary));

как только вы это сделаете, вы можете получить доступ к сетке, используя операцию Reference:

Grid.Print(New_Grid.Reference);

Если вы хотите получить доступ к элементам напрямую, вам может потребоваться сделать что-то вроде:

Grid.Reference.Element(1,2) := 23;

Обратите внимание, что в некоторых версиях GNAT есть ошибка, из-за которой может генерироваться исключение Finalization. Если это так, вы обычно можете обойти это, используя объявляющий блок или функцию. Объявить пример блока:

declare
   The_Grid : Grid.Grid_Type renames New_Grid.Reference;
begin
   The_Grid(1,2) := 23;
end;

Это отличается от примера объявления блока другого ответа, потому что этот блок объявления не создает никаких новых сеток, он просто обращается к существующей памяти. Это чисто для обхода ошибки компилятора. В этом примере New_Grid существует вне блока объявления, поэтому он остается доступным.