Как избежать закрытия поверхности pm3d другими объектами, находящимися перед ней?

gnuplot> help layer

 A gnuplot plot is built up by drawing its various components in a fixed order.
 This order can be modified by assigning some components to a specific layer
 using the keywords `behind`, `back`, or `front`. For example, to replace the
 background color of the plot area you could define a colored rectangle with the
 attribute `behind`.
      set object 1 rectangle from graph 0,0 to graph 1,1 fc rgb "gray" behind
 The order of drawing is
      behind
      back
      the plot itself
      the plot legend (`key`)
      front
 Within each layer elements are drawn in the order
      grid, axis, and border elements
      pixmaps in numerical order

Таким образом, в основном вам нужно добавить атрибут «передний» к объектам, которые вы хотите отобразить перед графиком.

Я предполагаю, что ваша первоначальная идея, т. е. «прокалывание» 3D-поверхности стрелкой или линией, не работает сразу в gnuplot, потому что gnuplot не будет автоматически вычислять точки прокалывания. Пожалуйста, поправьте меня, если я ошибаюсь, и дайте мне знать, если это может быть простое решение.

Как и в вашем простом случае, вы можете просто разделить стрелку в начале координат, потому что вы уже знаете точку прокола. Однако что делать, если поверхность неровная или имеет несколько точек прокола?

Решение: приложите усилия, чтобы создать сегментированную трехмерную стрелку и позволить gnuplot автоматически отображать и скрывать поверхности по мере необходимости. Это, вероятно, приближается к тому, что вы имели в виду. Однако это решение покажет сюрпризы, когда вы захотите изменить цвет стрелок. Так что есть еще куда расти.

Код: (простая версия со стрелками вдоль осей x, y, z)

### arrows "piercing" a 3D surface
reset session 

set view equal xyz
set xyplane relative 0.0

set xrange [-4:4]
set yrange [-4:4]
set zrange [-4:4]

# create 3D arrow
r = 0.01     # radius of arrow
rHead = 0.1  # radius of arrrowhead
n = 6        # corners of arrow
set print $myArrow
    do for [h=-100:90] {
        do for [a=360/n:360:360/n] {
            print sprintf("%g %g %g",r*cos(a),r*sin(a), h/100.)
        }
    print ""
    }
    do for [h=90:100] {
        do for [a=360/n:360:360/n] {
            print sprintf("%g %g %g",rHead*(100-h)/10.*cos(a), \
            rHead*(100-h)/10.*sin(a), h/100.)
        }
    print ""
    }
set print

unset key
unset colorbox
set pm3d depthorder

set samples 100
set isosamples 100
set view 65,46,1.3

# function to demonstrate "piercing"
f(x,y) = (sin(x*3)/x + sin(y*3)/y - 3)/2

splot \
  f(x,y) w pm3d, \
  $myArrow u 1:2:($3*4):(0) w pm3d lc rgb var, \
  $myArrow u 2:($3*4):1:(0) w pm3d lc rgb var, \
  $myArrow u ($3*4):1:2:(0) w pm3d lc rgb var  
### end of code

Результат: