Как извлечь символ (<<) и соответствующие ему алфавиты из строки с помощью sed, awk или grep

если я правильно понимаю, вы хотите напечатать все символы < плюс символы над символами <

Я попробовал это

$ awk '{
        if (match($0, /<+/)) {
                print $1, $2, substr(prevline, RSTART, RLENGTH)
                print $1, $2, substr($0, RSTART, RLENGTH)
                next
        }
}

{
        prevline = $0
}' file

NC_013791.2.2 : GAG
NC_013791.2.2 : <<<
NC_013791.2.3 : CTGG
NC_013791.2.3 : <<<<
NC_013791.2.4 : GGA
NC_013791.2.4 : <<<
NC_013791.2.5 : CTGA
NC_013791.2.5 : <<<<

Это может сработать для вас (GNU sed):

sed -E 'N;:a;s/^.(.*\n)[^<]|.(\n.*)[^<]$/\1\2/;ta;' file

Используйте расширенное регулярное выражение, установив опцию -E.

Добавьте следующую строку.

Ввести цикл.

Используя замену, откусывайте переднюю и заднюю часть обеих строк, пока не останется только результат маски и маски.

После дальнейших разъяснений(?), возможно:

cat <<\! > file
NC_013791.2.2 : GCTCAGCTGGCtAGAG
NC_013791.2.2 : >>>>.........<<<
!

cat <<\! > file1
NC_013791.2.3 : GCTCAGCTGGCtAGAG
NC_013791.2.3 : >>>>..<<<<......
!

cat <<\! > file2
NC_013791.2.2 : GCTCAGCTGGCtAGAG
NC_013791.2.2 : >>>>.........<<<
NC_013791.2.3 : GCTCAGCTGGCtAGAG
NC_013791.2.3 : >>>>..<<<<......
NC_013791.2.4 : GCTCAGCTGGCtAGAG
NC_013791.2.4 : >>>>.........<<<
NC_013791.2.5 : GCTCAGCTGGCtAGAG
NC_013791.2.5 : >>>>..<<<<......
!

sed -E 'N;:a;s/^(.*: ).(.*\n\1)[^<]|.(\n.*)[^<]$/\1\2\3/;ta' file file1
NC_013791.2.2 : GAG
NC_013791.2.2 : <<<
NC_013791.2.3 : CTGG
NC_013791.2.3 : <<<<

sed -E 'N;:a;s/^(.*: ).(.*\n\1)[^<]|.(\n.*)[^<]$/\1\2\3/;ta' file2
NC_013791.2.2 : GAG
NC_013791.2.2 : <<<
NC_013791.2.3 : CTGG
NC_013791.2.3 : <<<<
NC_013791.2.4 : GAG
NC_013791.2.4 : <<<
NC_013791.2.5 : CTGG
NC_013791.2.5 : <<<<

Если ваши данные всегда в этом формате, вы можете распечатать первые два поля, а затем вызвать substr, который напечатает интересующую часть.

Основываясь на ответе @stuffy, вы можете изменить код, чтобы он соответствовал 3 или более раз символу <:

awk 'match($0, /<<<+/) { 
  print $1, $2, substr(prev, RSTART, RLENGTH)
  print $1, $2, substr($0, RSTART, RLENGTH)
} { 
  prev = $0
}' file

Здесь $0 — текущая строка, а prev — предыдущая строка.

Функция match устанавливает предопределенные переменные RSTART и RLENGTH, которые вы можете использовать для вызова substr.

Выход

NC_013791.2.2 : GAG
NC_013791.2.2 : <<<
NC_013791.2.3 : CTGG
NC_013791.2.3 : <<<<
NC_013791.2.4 : GGA
NC_013791.2.4 : <<<
NC_013791.2.5 : CTGA
NC_013791.2.5 : <<<<

Если, например, разделителем полей является : , и вы хотите проверить, что обе части перед этим одинаковы в обеих строках:

awk -F" : " '
  match($2, /<<<+/) && key == $1 {
    print $1 FS substr(val, RSTART, RLENGTH)
    print $1 FS substr($2, RSTART, RLENGTH)
  }
  { val = $2; key = $1 }
' file

Используя любой awk плюс tac:

$ cat tst.awk
match($3,/<+/) {
    start = RSTART
    lgth = RLENGTH
}
{
    $3 = substr($3,start,lgth)
    print
}

$ tac file | awk -f tst.awk | tac
NC_013791.2.2 : GAG
NC_013791.2.2 : <<<
NC_013791.2.3 : CTGG
NC_013791.2.3 : <<<<
NC_013791.2.4 : GGA
NC_013791.2.4 : <<<
NC_013791.2.5 : CTGA
NC_013791.2.5 : <<<<