Как мне «назначить» значение в `CArray`, содержащее адрес памяти, `Pointer`?

Это вопрос NativeCall.

У меня есть 8 байтов (с прямым порядком байтов) в CArray, представляющем адрес памяти. Как мне создать Pointer из него?

(CArray и Pointer — это два типа NativeCall, совместимые с C. Pointers имеют длину 8 байтов. Все должно выстроиться в линию, но как поместить адрес указателя в CArray в Pointer способом, приемлемым для NativeCall?)

Можете ли вы показать пример кода, который иллюстрирует, как вы собираетесь это использовать?

Håkon Hægland 04.12.2022 00:32

В приведенном ниже коде vpaste: $pCount возвращается правильно (обычно 2), $ppSession — нет. Он указывает на мусор. Что я должен получить в ответ и что важно learn.microsoft.com/en-us/answers/questions/1113072/… Как правильно объявить указатель на указатель: [out] PWTS_SESSION_INFOA *ppSessionInfo Эти возвращают мусор: Pointer[ Pointer] $ppSessionInf is rw Pointer $ppSessionInf is rw Пример кода: vpaste.net/rVyxB Все вызовы API задокументированы в комментариях

Todd 04.12.2022 03:32
Стоит ли изучать PHP в 2023-2024 годах?
Стоит ли изучать PHP в 2023-2024 годах?
Привет всем, сегодня я хочу высказать свои соображения по поводу вопроса, который я уже много раз получал в своем сообществе: "Стоит ли изучать PHP в...
Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией
Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией
В JavaScript одним из самых запутанных понятий является поведение ключевого слова "this" в стрелочной и обычной функциях.
Приемы CSS-макетирования - floats и Flexbox
Приемы CSS-макетирования - floats и Flexbox
Здравствуйте, друзья-студенты! Готовы совершенствовать свои навыки веб-дизайна? Сегодня в нашем путешествии мы рассмотрим приемы CSS-верстки - в...
Тестирование функциональных ngrx-эффектов в Angular 16 с помощью Jest
В системе управления состояниями ngrx, совместимой с Angular 16, появились функциональные эффекты. Это здорово и делает код определенно легче для...
Концепция локализации и ее применение в приложениях React ⚡️
Концепция локализации и ее применение в приложениях React ⚡️
Локализация - это процесс адаптации приложения к различным языкам и культурным требованиям. Это позволяет пользователям получить опыт, соответствующий...
Пользовательский скаляр GraphQL
Пользовательский скаляр GraphQL
Листовые узлы системы типов GraphQL называются скалярами. Достигнув скалярного типа, невозможно спуститься дальше по иерархии типов. Скалярный тип...
4
2
146
3
Перейти к ответу Данный вопрос помечен как решенный

Ответы 3

Как мне создать указатель из него?

Я думаю, вы могли бы использовать nativecast вот так:

my $ptr = nativecast(CArray[Pointer], $array);
my Pointer $ptr2 = $ptr[$idx];

Не уверен, как использовать выше. Не могли бы вы использовать мою vpaste, чтобы показать мне, как? vpaste.net/rVyxB

Todd 04.12.2022 03:34
docs.raku.org/language/nativecall#sub_nativecast ясно как грязь
Todd 04.12.2022 03:36

«Не могли бы вы использовать мою vpaste, чтобы показать мне, как это сделать?» Смотрите мой второй ответ ниже. Это правильная интерпретация вашей проблемы?

Håkon Hægland 04.12.2022 10:32

Из комментариев кажется, что нативная подпрограмма должна возвращать указатель на массив структур. В Linux я создал следующий пример:

тест.с

#include <stdio.h>
#include <stdint.h>
#include <stdlib.h>

typedef struct myStruct
{
    int32_t A;
    double B;
} mstruct;

void set_pointer(mstruct **arrayOfStruct)
{
    mstruct *ptr = (mstruct *) malloc(sizeof(mstruct)*2);
    printf("allocated memory at address: %p\n", ptr);
    ptr[0].A = 10;
    ptr[0].B = 1.1;
    ptr[1].A = 20;
    ptr[1].B = 2.1;
    *arrayOfStruct = ptr;
}

п.раку:

use v6;
use NativeCall;

class myStruct is repr('CStruct') {
    has int32 $.A is rw;
    has num64 $.B is rw;
}

sub set_pointer(Pointer[CArray[myStruct]] is rw) is native("./libtest.so") { * };

my $array-ptr = Pointer[CArray[myStruct]].new();
set_pointer($array-ptr);
my $array = nativecast(Pointer[myStruct], $array-ptr.deref);
say $array[0].A;
say $array[0].B;
say $array[1].A;
say $array[1].B;

Вывод:

allocated memory at address: 0x5579f0d95ef0
10
1.1
20
2.1

Я не уверен, что вы написали мне. Если я смогу найти начало данных, на которые дважды указывает *ppSessionInfo, я знаю, где все должно быть, и я найду то, что мне нужно. C++ BOOL WTSEnumerateSessionsA([in] HANDLE hServer, [in] DWORD Reserved, [in] DWORD Version, [out] PWTS_SESSION_INFOA *ppSessionInfo, [out] DWORD *pCount); Все, что мне нужно, это правильный адрес, чтобы я мог прочитать данные

Todd 04.12.2022 11:36

@Todd Смотрите мой третий ответ. Я пытался использовать вызов Windows API, о котором вы упомянули. Это помогает?

Håkon Hægland 04.12.2022 16:05
Ответ принят как подходящий

Вот пример использования вызова Windows API WTSEnumerateSessionsA(), который вы упомянули в комментариях:

use NativeCall;

constant BYTE     := uint8;
constant DWORD    := uint32;
constant WTS_CURRENT_SERVER_HANDLE = 0;  # Current (local) server
constant LPSTR    := Str;

enum WTS_CONNECTSTATE_CLASS (
  WTSActive => 0,
  WTSConnected =>1,
  WTSConnectQuery => 2,
  WTSShadow => 3,
  WTSDisconnected => 4,
  WTSIdle => 5,
  WTSListen => 6,
  WTSReset => 7,
  WTSDown => 8,
  WTSInit => 9
);

constant WTS_CONNECTSTATE_CLASS_int := int32;

class WTS_SESSION_INFOA is repr('CStruct') {
    has DWORD $.SessionId is rw;
    has LPSTR $.pWinStationName is rw;
    has WTS_CONNECTSTATE_CLASS_int $.State;
}

sub GetWTSEnumerateSession(
   #`{
       C++
       BOOL WTSEnumerateSessionsA(
         [in]  HANDLE             hServer,
         [in]  DWORD              Reserved,
         [in]  DWORD              Version,
         [out] PWTS_SESSION_INFOA *ppSessionInfo,
         [out] DWORD              *pCount
       );
       Returns zero if this function fails.
   }
   DWORD $hServer,                        # [in]  HANDLE
   DWORD $Reserved,                       # [in] always 0
   DWORD $Version,                        # [in] always 1
   Pointer[Pointer] $ppSessionInf is rw,  # [out] see _WTS_SESSION_INFOA and _WTS_CONNECTSTATE_CLASS;
   DWORD $pCount         is rw            # [out] DWORD
   )
   is native("Wtsapi32.dll")
   is symbol("WTSEnumerateSessionsA")
   returns DWORD  # If the function fails, the return value is zero.
   { * };


my $hServer = Pointer[void].new();
$hServer = WTS_CURRENT_SERVER_HANDLE;   # let windows figure out what current handle is
my $ppSession  = Pointer[Pointer].new();  # A pointer to another pointer to an array of WTS_SESSION_INFO
my DWORD $pCount;

my $ret-code = GetWTSEnumerateSession $hServer, 0, 1, $ppSession, $pCount;
say "Return code: " ~ $ret-code;
my $array = nativecast(Pointer[WTS_SESSION_INFOA], $ppSession.deref);
say "Number of session info structs: " ~ $pCount;
for 0..^ $pCount -> $i {
    say "{$i} : Session id: " ~ $array[$i].SessionId;
    say "{$i} : Station name: " ~ $array[$i].pWinStationName;
    say "{$i} : Connection state: " ~ $array[$i].State;
}

Выход (окна 11)

Return code: 1
Number of session info structs: 2
0 : Session id: 0
0 : Station name: Services
0 : Connection state: 4
1 : Session id: 1
1 : Station name: Console
1 : Connection state: 0

Другие вопросы по теме