Как обновить элемент в этом векторе?

Быстрый поиск в Интернете приведет вас к... A.18.2 Пакет-контейнеры. Векторы (или, если вы используете GNAT Studio: щелкните правой кнопкой мыши «Векторы» в «Ada.Containers.Vectors», затем выберите «Перейти к объявлению»). Тогда вы найдете это:

procedure Update_Element
     (Container : in out Vector;
      Index     : in     Index_Type;
      Process   : not null access procedure
                      (Element : in out Element_Type));

У вас тут много всего намешано. Во-первых, если вы посмотрите на ответ Zerte более внимательно, чем раньше, вы заметите, что ваша операция TestUpdate вообще не соответствует этому аргументу Process. Он ожидает процедуру (у вас есть функция), и параметр процедуры "in out", а вы используете "in" и у вас есть дополнительный параметр. Вы должны исправить это в первую очередь

Если вы хотите использовать Update_Element (я не рекомендую его для вашего конкретного случая), вам нужно изучить «Вложенные подпрограммы». Вот пример того, как изменить операцию TestUpdate для работы с Update_Element:

procedure TestUpdate(V : in out NodeVector.Vector; val : Integer) is
    procedure Actual_Update(N : in out Node) is
    begin
        n.Size := n.Size + val;
    end Actual_Update;
begin
    V.Update_Element(V.Last,Actual_Update'Access);
end TestUpdate;

Обратите внимание, как процедура Actual_Update на самом деле соответствует аргументу процесса контракта операции Update_Element. Кроме того, поскольку Actual_Update является вложенным, он имеет доступ к аргументу Val из TestUpdate.

Полный пример:

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Containers.Vectors;

procedure Test_Update is
    type Node is record
       Parent : Integer := -1;
       Size : Integer := -1;
    end record;

    package NodeVector is new
        Ada.Containers.Vectors
        (
            Index_Type   => Natural,
            Element_Type => Node
        );

    Nodes : NodeVector.vector;
    Current_Node : Node;
    
    procedure TestUpdate(V : in out NodeVector.Vector; val : Integer) is
        procedure Actual_Update(N : in out Node) is
        begin
            n.Size := n.Size + val;
        end Actual_Update;
    begin
        V.Update_Element(V.Last,Actual_Update'Access);
    end TestUpdate;
    
begin
    Current_Node.Size := 10;
    Nodes.Append(Current_Node);
    TestUpdate(Nodes, 5);
end Test_Update;

С векторами вы также можете просто индексировать вещи напрямую. После добавления элемента вы можете использовать <vector_name>.Last, чтобы получить курсор (индекс) для последнего элемента... того, который вы только что добавили. Пример:

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Containers.Vectors;

procedure Test_Update is
    type Node is record
       Parent : Integer := -1;
       Size : Integer := -1;
    end record;

    package NodeVector is new
        Ada.Containers.Vectors
        (
            Index_Type   => Natural,
            Element_Type => Node
        );

    Nodes : NodeVector.vector;
    Current_Node : Node;
    
    procedure Using_Cursors
        (V : in out NodeVector.Vector;
         N : Node;
         Value : Integer)
    is begin
        Nodes.Append(N);
        Nodes(Nodes.Last).Size := Nodes(Nodes.Last).Size + Value;
    end Using_Cursors;
    
begin
    Current_Node.Size := 10;
    Using_Cursors(Nodes,Current_Node,5);
end Test_Update;