Как передавать и получать сигнал основной полосы частот в unetstack?

Базовый код, который у вас есть для передачи (TxBasebandSignalReq) и приема (RecordBasebandSignalReq) сигналов, кажется правильным.

Это должно хорошо работать на модемах, за исключением того факта, что ваше генерирование сигнала, вероятно, ошибочно по двум причинам:

1. Вы пытаетесь сгенерировать сигнал с частотой 5 кГц в представлении основной полосы частот, используя несущую частоту 24 кГц и полосу пропускания 24 кГц. Этот сигнал будет сглажен, так как это представление основной полосы частот может представлять только сигналы 24 ± 12 кГц, т. е. 12–36 кГц. Если вам нужно передать сигнал 5 кГц, вам нужно, чтобы ваш модем работал на гораздо более низкой несущей частоте (легко в симуляторе, но на практике вам нужно проверить характеристики модема).

2. Вы преобразуете вывод sin и cos в int. Вероятно, это не то, что вы намеревались сделать, так как signal представляет собой массив float, масштабированный между -1 и 1. Поэтому было бы целесообразно просто отбросить (int).

На симуляторе вам необходимо убедиться, что параметры модема настроены правильно, чтобы отразить ваши предположения о несущей частоте основной полосы частот, полосе пропускания и длине записи:

modem.carrierFrequency = 24000
modem.basebandRate = 24000
modem.maxSignalLength = 24000

Параметры по умолчанию HalfDuplexModem отличаются, и ваш текущий код не выполнит RecordBasebandSignalReq с ответом REFUSE (который ваш код не проверяет).

Остальная часть вашего кода выглядит нормально, но я бы немного упростил ее:

import org.arl.fjage.*
import org.arl.unet.bb.*
import org.arl.unet.Services

platform = RealTimePlatform

modem.carrierFrequency = 24000
modem.basebandRate = 24000
modem.maxSignalLength = 48000

simulate 3.minutes, {

  def n1 = node('1', address: 1, location: [0,0,0])
  def n2 = node('2', address: 2, location: [0,0,0])

  n1.startup = {
    def bb = agentForService Services.BASEBAND
    add new TickerBehavior(50000, {
      float freq = 25000  // pick a frequency in the 12-36 kHz range
      float duration = 1000e-3
      int fd = 24000
      int fc = 24000
      int num = duration*fd
      def sig = []
      (0..num-1).each { t ->
        double a = 2*Math.PI*(freq-fc)*t/fd
        sig << Math.cos(a)
        sig << Math.sin(a)
      }
      bb << new TxBasebandSignalReq(signal: sig)
      println "sent"
    })
  }

  n2.startup = {
    def bb = agentForService Services.BASEBAND
    add new TickerBehavior(50000, {
      bb << new RecordBasebandSignalReq(recLen: 24000)
      def rxNtf = receive(RxBasebandSignalNtf, 25000)
      if (rxNtf) {
        println "Received"
      }
      println "Tried"
    })
  }

}

Это должно работать так, как ожидалось!

Тем не менее, есть еще несколько ошибок, о которых следует помнить:

1. Вы отправляете и записываете по таймеру. В симуляторе это должно быть нормально, так как оба узла имеют одинаковое время начала и нет задержки распространения (вы установили узлы в одном и том же месте). Однако на реальном модеме запись может не происходить во время передачи.

2. Передача и прием сигналов с настоящим модемом работает хорошо. Симулятор Unet в первую очередь является симулятором сети и фокусируется на моделировании поведения модемов в системе связи, но не обязательно на акустическом распространении. Хотя он поддерживает сервис BASEBAND, физика канала передачи сигналов не точно моделируется моделью HalfDuplexModem по умолчанию. Таким образом, ваш пробег по обработке сигнала записи может варьироваться. Это можно исправить, определив собственную модель канала, которая использует подходящую модель акустического распространения, но это нетривиальная задача.