Как переслать объявление роли, которая будет использоваться для перечисления?

Перечисления являются конструкциями времени компиляции, поэтому вся логика для создания перечисления должна существовать при его объявлении.

Самое близкое решение - сделать вот так

use v6.d;

enum Surface <Fire>;

role DrawSurface {
    method draw ($surface) {
        given $surface {
            when Surface::Fire { "f" }
        }
    }
}

say DrawSurface.draw(Fire);

или вот так

use v6.d;

enum Surface <Fire>;

class SurfaceC {
    has Surface $.surface;

    method draw {
        given $!surface {
            when Surface::Fire { "f" }
        }
    }
}

say SurfaceC.new(surface => Fire).draw;

Прямое решение с использованием мультидиспетчеризации.

module DrawSurface {
    enum Surface is export <Fire>;

    proto draw (Surface $ ) is export {*}
    multi draw (Fire) {'f'}
}

import DrawSurface;

say draw Fire;

f

Сочетание с role.

role DrawSurface {
    method draw () {drawp self}
}

enum Surface does DrawSurface <Fire>;

multi drawp(Fire) { 'f' }

say Fire.draw;

f