Как получить css-стиль переполнения текста в фреймворке робота

Как получить CSS-стиль переполнение текста во фреймворке робота. Для проверки текста с многоточием.

<td _ngcontent-c5="" class="fontStyle" data-placement="top" title="123456789123456789qwertyuiasdfghjklzxcvbnmasdfghjkqwertyuiasdfghjkzxcvbnmertyui"> 123456789123456789qwertyuiasdfghjklzxcvbnmasdfghjkqwertyuiasdfghjkzxcvbnmertyui </td>
1
0
2 040
2
Перейти к ответу Данный вопрос помечен как решенный

Ответы 2

в фреймворке робота, чтобы получить текст, который вы можете использовать, это сохранит текст в переменной data

${data}    Get Text    xpath=*//td[@class='fontStyle' and @data-placement='top']

это даст вам переменную data как 123456789123456789qwertyuiasdfghjklzxcvbnmasdfghjkqwertyuiasdfghjkzxcvbnmertyui

для проверки вы можете использовать

для частичного совпадения:

Element Should Contain    locator    text_should_check_with

для точного совпадения используйте:

Element Text Should Be    locator    text_should_check_with

Мне нужно проверить, что отображаемый текст - многоточие. Получив стиль переполнения текста css: многоточие

Venkatesh 26.10.2018 08:02
Ответ принят как подходящий

Обновление: в текущей SeleniumLibrary (3.2+) есть выделенное ключевое слово: Получить атрибут элемента


Получение значения свойства CSS не поддерживается в SeleniumLibrary для Robot Framework. Однако в модуле Selenium Python есть метод value_of_css_property, который делает именно это.

Чтобы вызвать метод для элемента, можно использовать стандартное ключевое слово Call Method для любой переменной или объекта Robot. В приведенном ниже примере я создал собственное ключевое слово и несколько примеров, используя главную страницу Google. Они должны быть легко изменены для ваших целей.

*** Settings ***
Library    SeleniumLibrary

Suite Teardown    Close All Browsers

*** Test Cases ***
TC
    Open Browser    http://www.google.com    Chrome

    # a CSS property from the element.
    ${element_prop}=    Get CSS Property Value    id=SIvCob    line-height
    Should Be Equal As Strings    ${element_prop}    28px

    # a CSS property inherited from the <body> tag.
    ${body_prop}=    Get CSS Property Value    id=SIvCob    font-family
    Should Be Equal As Strings    ${body_prop}    arial, sans-serif

*** Keywords ***
Get CSS Property Value
    [Documentation]
    ...    Get the CSS property value of an Element.
    ...    
    ...    This keyword retrieves the CSS property value of an element. The element
    ...    is retrieved using the locator.
    ...    
    ...    Arguments:
    ...    - locator           (string)    any Selenium Library supported locator xpath/css/id etc.
    ...    - property_name     (string)    the name of the css property for which the value is returned.
    ...    
    ...    Returns             (string)    returns the string value of the given css attribute or fails.
    ...        
    [Arguments]    ${locator}    ${attribute name}
    ${css}=         Get WebElement    ${locator}
    ${prop_val}=    Call Method       ${css}    value_of_css_property    ${attribute name}
    [Return]     ${prop_val}

Привет @A. kootstra Чтобы проверить стиль текста, такой как размер шрифта / полужирный / курсив / цвет текста, какие ключевые слова / библиотеки следует искать в структуре робота?

Dev 29.10.2018 15:18

Это могут быть атрибуты вашего элемента или, что более вероятно, свойства CSS. Если это последнее, то это ключевое слово можно использовать для проверки их конкретного значения. Взгляните на инструменты разработчика браузеров, чтобы проверить их. Если вы хотите узнать больше, создайте новый вопрос, так как его здесь не следует обсуждать.

A. Kootstra 29.10.2018 19:15

Создайте для этого новый вопрос. Это выходит за рамки исходного вопроса.

A. Kootstra 30.10.2018 13:12

Другие вопросы по теме