Как получить доступ к тегу в xml, который заканчивается определенным текстом, используя конец с

Используйте это выражение XPath1, которое имитирует функцию fn:ends-with()¹:

//branch/node()[substring(local-name(),
    string-length(local-name()) - string-length("stock") + 1)  = "stock"]

Так:

my $stock_value = $branch
->findnodes('node()[substring(local-name(),
    string-length(
        local-name()) - string-length("stock") + 1)  = "stock"]'
)->[0]->textContent;

Из википедии (к сожалению...)

Существует несколько версий XPath. XPath 1.0 был опубликован в 1999 г., XPath 2.0 — в 2007 г. (второе издание — в 2010 г.), XPath 3.0 — в 2014 г., а XPath 3.1 — в 2017 г. Однако XPath 1.0 по-прежнему остается наиболее широко доступной версией.

Связанный: https://stackoverflow.com/a/40935676/465183

¹ https://www.w3.org/TR/xpath-functions-31/#func-ends-with

Этот приятный ends-with(), наряду со многими другими функциями, есть в XPath2 (и позже ). В XML::LibXML мы ограничены XPath 1.0, так как это лежит в основе libxml2.

Одной из работающих функций для запроса по частичному тексту является contains

use warnings;
use strict;
use feature 'say';

use Data::Dumper;
use XML::LibXML;

my $file = shift // die "Usage: $0 file\n";

my $parser = XML::LibXML->load_xml(location => $file);

my %branch_stock;
for my $sec ($parser->findnodes('/Details/Info')) { 
    for my $branch ($sec->findnodes('./branch')) {
        my $branch_name = $branch->getAttribute('name');

        for my $stock ($branch->findnodes('*[contains(name(),"stock")]')) {
            say "$branch_name --> $stock";
            $branch_stock{$branch_name} = $stock->textContent;

            # No "ends-with" in XPath1, what we have here
            # $branch->findnodes('*[ends-with(name(),"stock")]')
        }
    }   
}
print Dumper \%branch_stock;

Это печатает

city_1 --> <prevstock>10000</prevstock>
city_2 --> <presstock>2000</presstock>
city_3 --> <futstock>3000</futstock>
$VAR1 = {
          'city_3' => '3000',
          'city_1' => '10000',
          'city_2' => '2000'
        };

Несколько слов об исходниках и документации, которые, как мне кажется, не так уж и просты для XPath.

Обзор в perl-libxml-by-example . Хотя в XPath 1.0 отсутствуют мощные функции более поздних версий, в нем есть несколько функций . Для этого также можно создавать собственные функции, используя Perl API . Библиотека XML::LibXML использует XML::LibXML::XPathContext.

Если действительно есть один stock под каждым branch, что здесь явно ожидается, нам не нужен цикл, но мы можем выбрать «первый» (единственный) элемент

for my $sec ($parser->findnodes('/Details/Info')) { 
    for my $branch ($sec->findnodes('./branch')) {
        my $branch_name = $branch->getAttribute('name');

        my $stock = $branch->findnodes('*[contains(name(),"stock")]')->[0];
        say "$branch_name --> $stock";
        $branch_stock{$branch_name} = $stock->textContent;
     }
}

И для этого есть ярлык, findvalue

for my $sec ($parser->findnodes('/Details/Info')) { 
    for my $branch ($sec->findnodes('./branch')) {
        my $branch_name = $branch->getAttribute('name');

        my $stock_value = $branch->findvalue('*[contains(name(),"stock")]');
        $branch_stock{$branch_name} = $stock_value;
     }
}