Как получить идентификатор максимального значения?

1. Прежде всего скопируйте столбцы A:D на лист и оставьте следующие 4 столбца пустыми.
2. Сортировка столбцов по A и B

Надеюсь, этот фрагмент кода поможет.

Sub FindMaxCostForGroups()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("YOUR_WORKSHEET") ' Change to your sheet name
    
    Dim lastRow As Long
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    
    Dim currentA As String, currentB As String
    Dim maxCost As Double
    Dim saleID As String
    Dim outputRow As Long
    outputRow = 1 ' Starting row for output, change as needed
    
    Dim i As Long
    For i = 2 To lastRow ' Assuming headers in row 1
        If ws.Cells(i, 1).Value <> currentA Or ws.Cells(i, 2).Value <> currentB Then
            ' New group detected, output the previous group's results
            If i > 2 Then
                ws.Cells(outputRow, 6).Value = currentA
                ws.Cells(outputRow, 7).Value = currentB
                ws.Cells(outputRow, 8).Value = saleID
                ws.Cells(outputRow, 9).Value = maxCost
                outputRow = outputRow + 1
            End If
            
            ' Initialize new group variables
            currentA = ws.Cells(i, 1).Value
            currentB = ws.Cells(i, 2).Value
            maxCost = ws.Cells(i, 4).Value
            saleID = ws.Cells(i, 3).Value
        Else
            ' Same group, update max cost and sale ID if necessary
            If ws.Cells(i, 4).Value > maxCost Then
                maxCost = ws.Cells(i, 4).Value
                saleID = ws.Cells(i, 3).Value
            End If
        End If
    Next i
    
    ' Output the last group's results
    ws.Cells(outputRow, 6).Value = currentA
    ws.Cells(outputRow, 7).Value = currentB
    ws.Cells(outputRow, 8).Value = saleID
    ws.Cells(outputRow, 9).Value = maxCost
End Sub

В этом коде предполагается, что ваши данные начинаются со строки 2, а столбцы от A до D содержат ваши данные, а выходные данные начинаются со столбца F. При необходимости измените имя листа, начальную строку и ссылки на столбцы.

Как альтернатива; этот код ADO/SQL создает простую таблицу на «Листе1» без использования каких-либо циклов.

Sub Test()
    Dim objConn As Object, RS As Object, strSQL As String, strArgs As String, j As Integer

    Sheets("Sheet1").Range("M2:P" & Rows.Count).ClearContents
    
    Set objConn = CreateObject("ADODB.Connection")

    strArgs = "Driver = {Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)}; Readonly=False; DBQ = " & ThisWorkbook.FullName
    
    objConn.Open strArgs

    strSQL = " Select T1.[Name], T1.[Product], T1.[Sale ID], T1.[Cost] From [Sheet1$] As T1 " & _
             " Left Join [Sheet1$] As T2 " & _
             " On (T1.[Name]= T2.[Name] And T1.[Product]= T2.[Product] And T2.[Cost] > T1.[Cost]) Where T2.[Name] Is Null " & _
             " Order By T1.[Name], T1.[Product]"
        
    Set RS = objConn.Execute(strSQL)
    
    Sheets("Sheet1").Range("M1:P1") = Array("Name", "Product", "Sale ID", "Cost")

    Sheets("Sheet1").Range("M2").CopyFromRecordset RS

    objConn.Close
    Set objConn = Nothing
End Sub