Как получить уникальные столбцы в строке, сделать формулу «РАЗЛИВ» и работать и для других строк?

Возможно, вы имеете в виду что-то в этом роде:

Формула в H3:

=IFNA(DROP(LET(α,B3:F7,REDUCE(0,SEQUENCE(ROWS(α)),LAMBDA(β,γ,VSTACK(β,IFERROR(UNIQUE(TOROW(INDEX(α,γ,0),1),1,1),""))))),1),"")

Примечание. Теперь вы удалили значения, которые появлялись в исходных строках более одного раза в соответствии с вашей собственной попыткой с помощью UNIQUE(arr,1,1).

То же самое можно было бы сделать, используя MAKEARRAY:

=LET(range,A2:E6,MAKEARRAY(ROWS(range),COLUMNS(range),LAMBDA(r,c,LET(i,INDEX(range,r,), IFERROR(INDEX(UNIQUE(FILTER(i,i<>""),1,1),c),"")))))

Где мы сначала объявляем range и создаем массив того же размера.

Затем с помощью i мы перебираем диапазон по строкам. Мы фильтруем значения строк, удаляя пробелы, и применяем УНИКАЛЬНУЮ формулу, которую вы задумали. Мы индексируем результат, чтобы вернуть одно значение из вычисленных уникальных значений (позиция c).

Если позиция выходит за пределы ссылки на вычисляемый массив, будет возвращена #REF-ошибка. Мы превращаем их в пробелы, используя ЕСЛИОШИБКА.

Вот еще одна альтернатива с использованием функций REDUCE():

• Формула, используемая в ячейке H2

=LET(
     α, B3:F7,
     δ, IFNA(REDUCE(B2:F2,SEQUENCE(COLUMNS(α)),LAMBDA(r,c,
     VSTACK(r,UNIQUE(CHOOSEROWS(α,c),1,1)))),""),
     IF(δ=0,"",δ))

Вместо INDEX() можно также использовать CHOOSEROWS().

=LET(
     α, B3:F7,
     δ, IFNA(REDUCE(B2:F2,SEQUENCE(COLUMNS(α)),LAMBDA(r,c,
        VSTACK(r,UNIQUE(INDEX(α,c,),1,1)))),""),
     IF(δ=0,"",δ))

Та же основная логика, что и у JvdV и Маюха, немного многословная:

=LAMBDA(data,
    LET(
        num_cols, COLUMNS(data),
        once_only, LAMBDA(values,
            LET(
                values_wo_blanks, TOROW(values, 1),
                IFERROR(UNIQUE(values_wo_blanks, TRUE, TRUE), "")
            )
        ),
        REDUCE(
            CHOOSEROWS(data, 1),
            SEQUENCE(ROWS(data)),
            LAMBDA(acc_rows, cur_row,
                IF(
                    cur_row = 1,
                    acc_rows,
                    VSTACK(
                        acc_rows,
                        EXPAND(
                            once_only(CHOOSEROWS(data, cur_row)),
                            ,
                            num_cols,
                            ""
                        )
                    )
                )
            )
        )
    )
)(B2:F7)