Как правильно хранить SKProduct* (Objective-C) в C++ std::map?

Для вопроса в заголовке я бы инкапсулировал эту часть в пользовательский класс-контейнер, чтобы обернуть внутри управление памятью. Вот пример минималистичной реализации:

template<typename Key> // Key type must not be a retain-release object
class id_unordered_map {
    std::unordered_map<Key, id> m_underlying_map;

    void clear() {
        for (const auto& element: m_underlying_map) {
            [element.second release];
        }
        m_underlying_map.clear();
    }


public:
    id_unordered_map() = default;

    id_unordered_map(const id_unordered_map& rhs) {
        for (const auto& element: rhs.m_underlying_map) {
            // makes a shallow copy
            m_underlying_map[element.first] = [element.second retain];
        }
    };

    id_unordered_map(id_unordered_map&& rhs) {
        for (const auto& element: rhs.m_underlying_map) {
            m_underlying_map[element.first] = [element.second retain];
        }
        rhs.clear();
    }

    id_unordered_map& operator=(const id_unordered_map& rhs) {
        clear();
        for (const auto& element: rhs.m_underlying_map) {
            // makes a shallow copy
            m_underlying_map[element.first] = [element.second retain];
        }
        return *this;
    }

    id_unordered_map& operator=(id_unordered_map&& rhs) {
        clear();
        for (const auto& element: rhs.m_underlying_map) {
            m_underlying_map[element.first] = [element.second retain];
        }
        rhs.clear();
        return *this;
    }

    void setObject(const Key& key, id object) {
        removeObject(key);

        if (object) {
            m_underlying_map[key] = [object retain];
        }
    }

    id getObject(const Key& key) {
        if (auto it = m_underlying_map.find(key); it != m_underlying_map.end()) {
            return it->second;
        } else {
            return nil;
        }
    }

    void removeObject(const Key& key) {
        if (auto it = m_underlying_map.find(key); it != m_underlying_map.end()) {
            [it->second release];
            m_underlying_map.erase(it);
        }
    }

    ~id_unordered_map() {
        clear();
    }
};

Я предлагаю здесь поверхностный подход к копированию, так как он согласуется с тем, как работают собственные коллекции Cocoa. Создание глубокой копии считается исключительным случаем и требует отдельного метода (например, initWithDictionary:copyItems: конструктор NSDictionary)

Однако лично я не чувствую, что в предоставленном коде есть очевидная ошибка, которая приводит к сбою приложения. Ошибка, которую вы наблюдаете, обычно возникает, когда сообщение отправляется объекту, для которого не установлено значение nil, но который уже выпущен. И при условии, что никакие release сообщения не отправляются объектам на карте между функциями, ваш SKProduct объект должен выжить.

Вот несколько вещей, которые следует учитывать:

• productsRequest:didReceiveResponse: поток вызова не указан, и он на 99% отличается от потока пользовательского интерфейса, из которого, как я предполагаю, вызывается ваша make_purchase функция. Это означает, что объекты, порожденные в потоке делегатов, могут выйти из пула автоматического освобождения, в котором они были созданы (это, однако, не должно быть проблемой, если вы retain добавили объекты и при чтении/записи на карту не возникает состояние гонки) .
• [SKPayment paymentWithProduct: product]; возвращает автоматически выпущенный объект, срок действия которого не истечет (по крайней мере) до конца текущей области, поэтому вам не требуется retain его.
• Если вы делаете запросы продукта несколько раз в течение жизненного цикла вашего приложения, убедитесь, что вы освобождаете объекты, содержащиеся на карте, и clear() ее, прежде чем записывать новые данные на карту.

Подводя итог, ваш SKProductsRequestDelegate должен выглядеть примерно так (продукт здесь искусственный, поэтому я делаю это на лету в ответе):

NS_ASSUME_NONNULL_BEGIN

@interface TDWObject ()<SKProductsRequestDelegate>

@property (strong, readonly, nonatomic) dispatch_queue_t productsSyncQueue;
@property (assign, nonatomic) id_unordered_map<std::string> products;
@property (strong, readonly, nonatomic) NSMutableSet<SKProductsRequest *> *pendingRequests;

@end

NS_ASSUME_NONNULL_END

@implementation TDWObject

@synthesize products = _products;

#pragma mark Lifecycle

- (instancetype)init {
    if (self = [super init]) {
        _productsSyncQueue = dispatch_queue_create("the.dreams.wind.property_access.products",
                                                    DISPATCH_QUEUE_CONCURRENT);
        _pendingRequests = [[NSMutableSet set] retain];
    }
    return self;
}

- (void)dealloc {
    [_pendingRequests release];
    [_productsSyncQueue release];
    [super dealloc];
}

#pragma mark Properties

- (id_unordered_map<std::string>)products {
    __block id_unordered_map<std::string> *data;
    dispatch_sync(_productsSyncQueue, ^{
        // Take by pointer here, to avoid redundant copy
        data = &_products;
    });
    return *data; // makes a copy for observers
}

- (void)setProducts:(id_unordered_map<std::string>)products {
    dispatch_barrier_async(_productsSyncQueue, ^{
        _products = std::move(products);
    });
}

#pragma mark Actions

- (void)requestProducts {
    SKProductsRequest *productRequest = [[SKProductsRequest alloc] initWithProductIdentifiers:[NSSet setWithArray:@[
        @"the.dreams.wind.sampleSKU1"
    ]]];
    productRequest.delegate = self;
    [productRequest start];
    [_pendingRequests addObject:productRequest];
}

- (void)makePurchase {
    SKProduct *product = [_products.getObject("the.dreams.wind.sampleSKU1") retain];
    // Just checking that the object exists
    NSLog(@"%@", product);
    [product release];
}

#pragma mark SKProductsRequestDelegate

- (void)productsRequest:(SKProductsRequest *)request didReceiveResponse:(SKProductsResponse *)response {
    [_pendingRequests removeObject:request];

    decltype(_products) newProducts;
    // Artificial Products
    for (NSString *identifier in response.invalidProductIdentifiers) {
        newProducts.setObject(identifier.UTF8String, [[SKProduct new] autorelease]);
    }
    self.products = newProducts;

}

Здесь вы можете видеть, что доступ/чтение карты синхронизировано с использованием свойств GCD и Objective-C, что, я признаю, ужасно неэффективно, когда речь идет об объектах C++, доступ к которым осуществляется по значению. Вы захотите оптимизировать его, НО я считаю, что он должен работать без сбоев.

P.S. обычно вы также хотите синхронизировать чтение из/запись в набор pendingRequests, но это не имеет отношения к контексту вопроса, поэтому я пропустил эту часть.

Вы также можете подумать о том, чтобы просто взять массивы продуктов по ссылке, не используя объекты C++, что должно работать нормально и намного проще:

- (void)productsRequest:(SKProductsRequest *)request didReceiveResponse:(SKProductsResponse *)response {
    [_pendingRequests removeObject:request];
    NSArray<SKProduct *> *products = [response.products retain];
    ...
}