Как правильно обрабатывать ошибки синтаксического анализа с помощью PetitParser или PetitParser2 в Pharo

Вы можете использовать синтаксический анализатор с отрицательным прогнозом. Я не помню API в Smalltalk, но в Dart (прямой порт исходной реализации Smalltalk) вы бы написали:

В Дарте для сравнения

final grammar = char('(') 
    & number 
    & char(',').not('please remove the extra comma from your input') 
    & char(')'); 

Оригинальный PetitParser в Smalltalk (как предложил Лукас Ренггли в разделе комментариев)

Чтобы реализовать это в оригинальном PetitParser (как предложено в комментариях):

Добавьте переменную экземпляра message в определение класса:

PPDelegateParser subclass:#PPNotParser
        instanceVariableNames:'message'
        classVariableNames:''
        poolDictionaries:''
        category:'PetitParser-Parsers'

В PPNotParser>>parseOn:

parseOn: aPPContext
        | element memento |
        memento := aPPContext remember.
        element := parser parseOn: aPPContext.
        aPPContext restore: memento.
        ^ element isPetitFailure
                ifFalse: [ PPFailure message: message context: aPPContext ]

Тестирование с помощью PetitParser2

Чтобы просто протестировать Pharo Smalltalk с помощью PetitParser2, вам нужно сделать следующее — реализовать это, как в PetitParser выше, вероятно, будет сложнее:

• Добавьте #message к #PP2NotNode:

    PP2DelegateNode subclass: #PP2NotNode
       instanceVariableNames: 'message'
       classVariableNames: ''
       package: 'PetitParser2-Nodes'

• Создайте сеттеры и геттеры в #PP2NotNode

   message: aString
       message := aString
   message
       ^ message

• Отредактируйте PP2NotNode>>#parseOn: и примите решение, исходя из того, пусто сообщение или нет:

parseOn: aPP2Context
    ^ self message isEmptyOrNil
        ifTrue: [ strategy parseOn: aPP2Context ]
        ifFalse: [ strategy parseOn: aPP2Context message: self message ]

• Затем создайте новый метод PP2Not>>parseOn:message:

parseOn: context message: aMessageString
    | memento retval |
    memento := self remember: context.
    retval := node child parseOn: context.
    self restore: context from: memento.
    ^ retval isPetit2Failure
        ifTrue: [ nil ]
        ifFalse: [ PP2Failure message: aMessageString context: context ]

• Вам нужно улучшить PP2CompositeNodeTest>>parse: production:to:end:checkResult:

parse: aString production: production to: expectedResult end: end checkResult: aBoolean
    | ctx |
    ctx := self context.
    resultContext := self
        parse: aString
        withParser: production
        withContext: ctx.
    result := resultContext value.
    resultContext isPetit2Failure
        ifTrue: [ self unableToParse: resultContext withString: aString ].
    self assert: resultContext position equals: end.
    aBoolean
        ifTrue: [ self assert: expectedResult equals: result ].
    ^ result

• И последнее, но не менее важное: создайте метод PP2CompositeNodeTest>>unableToParse:withString:

unableToParse: aResultContext withString: aString
    aResultContext message isEmptyOrNil
        ifTrue: [ self deny: aResultContext isPetit2Failure description: 'Unable to parse ' , aString printString ]
        ifFalse: [ self
                deny: aResultContext isPetit2Failure
                description:
                    aResultContext message , ' While parsing: ' , aString printString , '; ' , ' See postion: '
                        , aResultContext position asString ]

Это возвращает сообщение об ошибке, если за числом следует запятая, но в противном случае позволяет следующему синтаксическому анализатору обрабатывать остальную часть последовательности.