Как расшифровать массив хэшей?

%newhash{$newkey} должно быть $newhash{$newkey}.

При работе со ссылкой используйте тот же синтаксис, что и в противном случае, но замените имя переменной блоком, который возвращает ссылку.

%NAME      -> %{ $ref }           Or just %$ref
$NAME{...} -> ${ $ref }{...}      Although $ref->{...} easier to read.

@NAME      -> @{ $ref }           Or just @$ref
$NAME[...] -> ${ $ref }[...]      Although $ref->[...] easier to read.

Давайте дадим $VAR лучшее имя,

my $response = $VAR1;

Это означает, что вы хотите

my $results = $response->{movie_results};
for my $result (@$results) {
   for my $key (keys(%$result)) {
      say "$key: $result->{$key}";
   }
}

Видеть

• перлрефтут
• Синтаксис разыменования Perl

Вы упомянули, что думали, что получите вывод JSON, но получили что-то другое. Модуль сделал для вас веб-запрос, получил ответ JSON и преобразовал его в структуру данных Perl. Эта Perl-версия JSON — это то, что вы видите в дампе.

Объект JSON превращается в хеш Perl, вот что вы видите на верхнем уровне структуры данных. Это единственное, что возвращает find (подробнее об этом чуть позже):

Вот что у вас получилось, удалив внешнюю петлю foreach:

my @newarray = $narray->{"movie_results"};

foreach my $otherarray (@newarray){
    my %innerhash = $otherarray;
    print %innerhash;
    print "\n";
}

Значение в $narray->{"movie_results"} является ссылкой на массив. Все ссылки являются скалярами, и эти скаляры указывают на некоторую структуру данных. Когда вы присваиваете этот скаляр массиву, вы просто получаете массив из одного элемента, который является той же ссылкой. Вместо этого вы можете

my $movie_results = $narray->{"movie_results"};

Затем вы разыменовываете эту ссылку, чтобы рассматривать ее как массив:

foreach my $result ( @$movie_results ){ ... }

Или способ v5.24 постфиксного разыменования, который мне кажется немного более приятным, поскольку он лучше читается, особенно когда вы пропускаете промежуточную переменную:

foreach my $result ( $movie_results->@* ){ ... }

foreach my $result ( $narray->{"movie_results"}->@* ){ ... }

Эта штука в $result — еще одна ссылка на хэш.

Ссылки и структуры данных составляют примерно половину содержания Intermediate Perl , но есть также поваренная книга структур данных Perl (perldsc).

Немного улучшить ваш вопрос

Вы можете нам очень помочь, показав нам полную рабочую демонстрацию вашей проблемы. Вот что я собрал:

use v5.10;

use TMDB;
use Data::Dumper;

my $tmdb = TMDB->new( apikey => $ENV{TMDB_API_KEY} );
my @results = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

say Dumper( \@results );

Был вопрос по результатам find. Пример документации показывает, что он возвращает список (ну, результат присваивается именованному массиву, что подразумевает это), но фактической документации для find нет. Он возвращает декодированный JSON из ответа. Присвоение его скаляру (который будет ссылкой) тоже отлично работает:

my $result = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

say Dumper( $results );

Возвращаемое значение исходит из TMDB::Sesssion::talk(), что является просто этим (или пустым списком):

return $self->json->decode(
    Encode::decode( 'utf-8-strict', $response->{content} ) ); 

Это не имеет большого значения. Это просто означает, что вам не нужен внешний foreach. Это не на вас, потому что пример в документации говорит вам делать именно то, что вы сделали.

Теперь лучшая программа

Собрав все это вместе, вот простая программа, урезанная до того, что вам нужно:

use v5.10; 
use TMDB;

my $tmdb = TMDB->new( apikey => $ENV{TMDB_API_KEY} );
my $result = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

foreach my $item ( $result->{movie_results}->@* ) {
    say "Title: $item->{title}";
    }

Псевдоним ссылки

Существует экспериментальная функция под названием ref aliasing, которая позволяет вам назначать ссылку на ссылку именованной переменной. Это псевдоним, так что вы можете получить доступ к одним и тем же данным и изменить их, просто используя именованную переменную. Что-то это удобно, когда вам не нравится

use v5.10;

use TMDB;
use experimental qw(refaliasing);

my $tmdb = TMDB->new( apikey => $ENV{TMDB_API_KEY} );

# response is a hash ref, so ref alias to a named hash
\my %result = $tmdb->search->find(
    id     => 'tt0114694',
    source => 'imdb_id'
    );

# the part you want is an array ref, so alias that
\my @movie_results = $result{movie_results};

# each item in the array is a hash ref, so alias those too
foreach \my %item ( @movie_results ) {
    say "Title: $item{title}";
    }