Как создать массив для последовательности месяцев между двумя датами?

Попробуйте использовать следующую формулу:

=BYROW(MONTH(A2:B4),LAMBDA(α, LET(δ, INDEX(α,1), TEXTJOIN(",",,SEQUENCE(INDEX(α,2)-δ+1,,δ)))))

Обновлено: использование CHOOSECOLS() также возможно, только если это функция массива, вам нужно будет использовать неявный оператор пересечения, чтобы Excel осознал, что пользовательский LAMBDA() должен применяться к каждой строке, а при использовании INDEX() это не требуется, поскольку он принимает строку ссылка на столбцы. Кроме того, при использовании @ требуется один дополнительный ключ, а при использовании INDEX() — нет!

=BYROW(MONTH(A2:B4),LAMBDA(α,
 LET(δ,@CHOOSECOLS(α,1),TEXTJOIN(",",,
 SEQUENCE(@CHOOSECOLS(α,2)-δ+1,,δ)))))

Приложение: если у вас есть более старые даты, которые не относятся к одному и тому же году, то приведенное выше значение обязательно вернет ошибку, поэтому используйте следующее:

• Использование INDEX():

=BYROW(A6:B12,LAMBDA(α, LET(δ, INDEX(α,1), 
 TEXTJOIN(",",,MONTH(UNIQUE(TEXT(SEQUENCE(INDEX(α,2)-δ+1,,δ),"mmm e")))))))

• Использование CHOOSECOLS():

=BYROW(A6:B12,LAMBDA(α, LET(δ, @CHOOSECOLS(α,1), 
TEXTJOIN(",",,MONTH(UNIQUE(TEXT(SEQUENCE(@CHOOSECOLS(α,2)-δ+1,,δ),"mmm e")))))))

Обходной путь путем принуждения к одиночному (значению)

Я еще не до конца это понял, но при использовании CHOOSECOLS, TAKE и т. д. с некоторыми функциями, такими как SEQUENCE, TEXTJOIN и т. д., обрабатывайте входные данные как столбцы и возвращайте только первый столбец. Самый простой обходной путь — преобразовать параметр в одно значение. Например, в вашем случае мы могли бы использовать SUM(....

Вот несколько вариантов, для интереса :)

С вашим оригиналом:

=BYROW(
    A2:B4,
    LAMBDA(a,
        TEXTJOIN(
            ",",
            TRUE,
            SEQUENCE(
                1,
                SUM(
                    MONTH(CHOOSECOLS(a, 2)) -
                        MONTH(CHOOSECOLS(a, 1)) + 1
                ),
                SUM(MONTH(CHOOSECOLS(a, 1))),
                1
            )
        )
    )
)

Или

=BYROW(
    MONTH(A2:B4),
    LAMBDA(a,
        LET(
            start, SUM(TAKE(a, , 1)),
            end, SUM(TAKE(a, , -1)),
            ARRAYTOTEXT(SEQUENCE(end - start + 1, , start))
        )
    )
)

Функция MAP обычно больше подходит для подобных ситуаций, поскольку она может перебирать несколько столбцов одновременно, устраняя необходимость в дополнительных функциях, таких как CHOOSECOLS или INDEX.

=MAP(MONTH(A2:A4), MONTH(B2:B4), LAMBDA(ms,me, TEXTJOIN(",",, SEQUENCE(, me-ms+1, ms))))

Кроме того, если ваши даты начала и окончания охватывают несколько лет, вы можете изменить формулу следующим образом:

=MAP(MONTH(A2:A4), YEAR(A2:A4), MONTH(B2:B4), YEAR(B2:B4),
   LAMBDA(ms,ys,me,ye, TEXTJOIN(",",, MONTH(DATE(ys, SEQUENCE(, me-ms+(ye-ys)*12+1, ms), 1)))))

Для получения дополнительной информации о различиях между BYROW или BYCOL и MAP см.:

• Любопытное поведение конструкции BYROW_SEQUENCE

Вот версия, в которой не используются LAMBDA или SEQUENCE (но используется TEXTJOIN), что может сделать ее совместимой с другими версиями Excel.

Это также будет работать в разные годы, но для января месяц будет установлен на 1:

=LET(dStart, A1, dEnd, B1, yDiff,YEAR(dEnd)-YEAR(dStart),mStart,MONTH(dStart),mEnd,MONTH(dEnd)+(yDiff*12),TEXTJOIN(",",TRUE,1+MOD(ROW(INDEX($A:$A,mStart):INDEX($A:$A,mEnd))-1,12)))

Однако, удалив все MOD части кода, вы можете сохранить месяц как 13 для января при переносе месяца:

=LET(dStart, A1, dEnd, B1, yDiff,YEAR(dEnd)-YEAR(dStart),mStart,MONTH(dStart),mEnd,MONTH(dEnd)+(yDiff*12),TEXTJOIN(",",TRUE,ROW(INDEX($A:$A,mStart):INDEX($A:$A,mEnd))))