Как сравнить значения строк нескольких столбцов с одинаковым заголовком на разных листах, даже если эти столбцы находятся только на одном листе?

Попробуйте это. Комментарии в коде.

Const HEADER_ROW As Long = 2 'header row# on all sheets

Sub CompareColumns()
    Dim cols As Collection, headerList, header, n As Long, i As Long, j As Long
    Dim rng As Range, v, wb As Workbook, wsCheck As Worksheet
    Dim cPos As Long, ok As Boolean, colOK As Boolean
    
    headerList = Array("abc", "def", "ghi") 'column headers to compare
    Set wb = ThisWorkbook
    
    Set wsCheck = ThisWorkbook.Worksheets("ws_checks")
    wsCheck.Cells.Clear
    
    For Each header In headerList             'check each header
        Debug.Print "---Checking:" & header & "---"
        Set cols = CompareRanges(wb, header)  'check all sheets for the header
        If cols.Count > 1 Then                'any sheets to compare?
            colOK = True
            cPos = HeaderPos(wsCheck, header)     'header position on "check "sheet
            ResetFill cols                    'clear previous flags
            For i = 1 To cols(1).Cells.Count  'column length
                ok = True
                v = cols(1)(i)                'read value from first column
                For j = 2 To cols.Count       'check other columns
                    If cols(j).Cells(i).Value <> v Then   'mismatch?
                        For Each rng In cols  'flag all columns at this position
                            rng.Cells(i).Interior.Color = vbRed
                        Next rng
                        ok = False            'row mismatch
                        colOK = False         'column not matched
                        Exit For              'done checking
                    End If
                Next j
                wsCheck.Cells(cols(1)(i).Row, cPos).Value = IIf(ok, "O", "X")
            Next i
            wsCheck.Cells(HEADER_ROW, cPos).Interior.Color = IIf(colOK, vbGreen, vbRed)
        End If
    Next header
End Sub

'Check all sheets in workbook `wb` for the header `hdr` on the configured row
'  Return a collection of all data columns below found headers, sized to the max length
'   of all of the returned ranges
Function CompareRanges(wb As Workbook, hdr) As Collection
    Dim ws As Worksheet, col As New Collection, maxRow As Long, lr As Long
    Dim rng As Range, m, i As Long, c As Range, lc As Long
    For Each ws In wb.Worksheets
        lc = ws.Cells(HEADER_ROW, ws.Columns.count).End(xlToLeft).Column
        For Each c In ws.Cells(HEADER_ROW, 1).Resize(1, lc).Cells
            If c.Value = hdr Then
                col.Add ws.Cells(HEADER_ROW + 1, c.Column)
                lr = ws.Cells(Rows.count, c.Column).End(xlUp).Row
                If lr > maxRow Then maxRow = lr
            End If
        Next c
    Next ws
    Set CompareRanges = New Collection
    If col.count = 0 Then Exit Function
    For Each rng In col  'make all columns same size as the longest one
        CompareRanges.Add rng.Resize(maxRow - HEADER_ROW)
    Next rng
End Function

'Clear any fill from a collection of ranges
Sub ResetFill(col As Collection)
    Dim rng As Range
    For Each rng In col
        Debug.Print rng.Parent.name, rng.Address
        rng.Interior.ColorIndex = xlNone
    Next rng
End Sub

'Return the column number for header `hdr` on sheet `ws`
'  Add the header if not found
Function HeaderPos(ws As Worksheet, hdr) As Long
    Dim m
    m = Application.Match(hdr, ws.Rows(HEADER_ROW), 0)
    If IsError(m) Then
        m = ws.Cells(HEADER_ROW, Columns.Count).End(xlToLeft).Column
        If Len(ws.Cells(HEADER_ROW, m)) > 0 Then m = m + 1
        ws.Cells(HEADER_ROW, m).Value = hdr
    End If
    HeaderPos = CLng(m)
End Function