Как ссылаться на выходные заголовки bazel С++ protobuf в другом рабочем пространстве/пакете

cc_library.includes принимает строки, представляющие пути, а не метки. Вы хотите установить includes = ["."] в my-protobuf-common.

Точно так же cc_library.hdrs предназначен для исходных файлов заголовков, цели которых зависят от этого, будут #include. Перечислять что-то и в deps, и в hdrs не имеет смысла, для этого варианта использования вам вообще не нужен hdrs.

Кроме того, используйте cc_binary для создания файла с main. cc_library не делает полную ссылку.

Кроме того, copts = ["--std=c++17"] редко бывает хорошей идеей. Это только устанавливает флаг для файлов в этом cc_library, который может изменить свой ABI, чтобы ссылка на другие части сборки не работала. В этом случае cc_library-эквивалентные части cc_proto_library не получат флаг. Используйте флаг командной строки bazel --copt=--std=c++17 instead, чтобы применить его ко всей сборке.

В общем, вы должны иметь возможность напрямую зависеть от cc_proto_library, поэтому промежуточное звено cc_librarymy-protobuf-common обычно не требуется. Цепочка инструментов cc использует -iquote для добавления прототипов, поэтому я считаю, что #include "proto/point.pb.h" нужно использовать.

proto-repo/WORKSPACE:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rules_proto",
    sha256 = "66bfdf8782796239d3875d37e7de19b1d94301e8972b3cbd2446b332429b4df1",
    strip_prefix = "rules_proto-4.0.0",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/rules_proto/archive/refs/tags/4.0.0.tar.gz",
        "https://github.com/bazelbuild/rules_proto/archive/refs/tags/4.0.0.tar.gz",
    ],
)
load("@rules_proto//proto:repositories.bzl", "rules_proto_dependencies", "rules_proto_toolchains")
rules_proto_dependencies()
rules_proto_toolchains()

proto-repo/BUILD:

cc_proto_library(
  name = "point_cc_proto",
  deps = [":point"],
  visibility = ["//visibility:public"],
)

proto_library(
  name = "point",
  srcs = ["proto/point.proto"],
)

proto-repo/proto/point.proto:

syntax = "proto3";

package my_protos.point;

message Point {
  optional int32 x = 1;
  optional int32 y = 2;
}

main-repo/WORKSPACE:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

local_repository(
  name = "my_protos",
  path = "../proto-repo",
)

http_archive(
    name = "rules_proto",
    sha256 = "66bfdf8782796239d3875d37e7de19b1d94301e8972b3cbd2446b332429b4df1",
    strip_prefix = "rules_proto-4.0.0",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/rules_proto/archive/refs/tags/4.0.0.tar.gz",
        "https://github.com/bazelbuild/rules_proto/archive/refs/tags/4.0.0.tar.gz",
    ],
)
load("@rules_proto//proto:repositories.bzl", "rules_proto_dependencies", "rules_proto_toolchains")
rules_proto_dependencies()
rules_proto_toolchains()

main-repo/BUILD:

cc_binary(
  name = "main",
  srcs = ["main.cc"],
  deps = ["@my_protos//:point_cc_proto"],
)

main-repo/main.cc:

#include <iostream>
#include "proto/point.pb.h"

int main() {

  my_protos::point::Point p;
  p.set_x(123);
  p.set_y(456);
  std::cout << p.DebugString();

  return 0;
}

Использование:

main-repo$ bazel run main
INFO: Analyzed target //:main (43 packages loaded, 570 targets configured).
INFO: Found 1 target...
Target //:main up-to-date:
  bazel-bin/main
INFO: Elapsed time: 6.166s, Critical Path: 5.33s
INFO: 106 processes: 4 internal, 102 linux-sandbox.
INFO: Build completed successfully, 106 total actions
INFO: Build completed successfully, 106 total actions
x: 123
y: 456