Как ускорить парсинг цен на монеты Binance?

Пример использования ожидаемого PeriodicTimer и System.Text.Json .NET 6+ для анализа результирующего потока, возвращаемого функцией GetStreamAsync() HttpClient.

PeriodicTimer может быть весьма эффективным в таких контекстах, поскольку он пытается не отставать от заданного вами интервала. Поскольку для выполнения внутренней процедуры требуется время - HttpClient.GetStreamAsync() требуется неопределенное количество времени для выполнения и возврата результата - Таймер отслеживает фактическое прошедшее время и пытается постоянно тикать (если только процедура не занимает больше указанного интервала, тогда ты промахиваешься, конечно)

• Примечание: как обычно, при работе с задачами, которые принимают CancellationToken, вы должны запускать этот код без отладчика (CTRL+F5) или настроить отладчик так, чтобы он не останавливался на TaskCanceledException или OperationCanceledException, в противном случае он обрабатывает (игнорируемое) исключение до того, как вы это сделаете.

Imports System.Globalization
Imports System.Net.Http
Imports System.Text.Json
Imports System.Threading

Private Shared ReadOnly m_Client As New HttpClient()
Private timerCts As CancellationTokenSource = Nothing
Private m_PeriodicTimer As PeriodicTimer = Nothing
Private m_PeriodicTimerInterval As Integer = 500
Private currentPrice As Decimal = 0.0D

Private Async Function StartPriceLookupTimer(token As CancellationToken, timerInterval As Integer) As Task
    If token.IsCancellationRequested Then Return
    Dim lookupAddress = "https://api.binance.com/api/v1/ticker/price?symbol=DOGEBUSD"
    m_PeriodicTimer = New PeriodicTimer(TimeSpan.FromMilliseconds(timerInterval))
    Try
        While Await m_PeriodicTimer.WaitForNextTickAsync(token)
            Dim jsonStream = Await m_Client.GetStreamAsync(lookupAddress, token)
            Try
                Dim prop = (Await JsonDocument.ParseAsync(jsonStream, Nothing, token)).RootElement.GetProperty("price")
                Dim strPrice = prop.GetString()
                If Decimal.TryParse(strPrice, CultureInfo.InvariantCulture, currentPrice) Then
                ' Do whatever you need to do with the parsed value
                ' E.g., assign it to a TextBox for presentation, 
                ' using the current Culture format, since strPrice contains the original format
                    [Some TextBox].Text = currentPrice.ToString() ' <= UI Thread here
                End If
            Catch knfex As KeyNotFoundException
                Debug.WriteLine("The JSON property was not found")
            Catch tcex As TaskCanceledException
                Debug.WriteLine("The lookup procedure was canceled")
            End Try
        End While
    Catch tcex As TaskCanceledException
        Debug.WriteLine("The lookup procedure was canceled")
    End Try
End Function

Private Sub StopPriceLookupTimer()
    timerCts?.Cancel()
    m_PeriodicTimer?.Dispose()
    timerCts?.Dispose()
    timerCts = Nothing
End Sub

Как запустить эту процедуру поиска, вызвав метод StartPriceLookupTimer()?
Вы можете использовать кнопку, сделав ее обработчик кликов асинхронным:

Private Async Sub SomeButton_Click(sender As Object, e As EventArgs) Handles SomeButton.Click
    If timerCts Is Nothing Then
        timerCts = New CancellationTokenSource()
        Await StartPriceLookupTimer(timerCts.Token, m_PeriodicTimerInterval)
    Else
        Debug.WriteLine("Lookup Timer already started")
    End If
End Sub

Или сделайте так, чтобы метод Shown Handler / OnShown() формы переопределял асинхронность и запускал процедуру при первом представлении формы:

Protected Overrides Async Sub OnShown(e As EventArgs)
    MyBase.OnShown(e)
    timerCts = New CancellationTokenSource()
    Await StartPriceLookupTimer(timerCts.Token, m_PeriodicTimerInterval)
End Sub

Чтобы остановить процедуру поиска, при необходимости вызовите метод StopPriceLookupTimer(), например, с помощью другой кнопки или в обработчике Form.Closed/переопределении OnFormClosed()