Как выполнить анализ пробелов и островов с помощью запроса мощности?

можем ли мы использовать DAX для получения этого результата?

Column =
VAR _last =
    MAXX (
        FILTER (
            'Table',
            'Table'[Item] = EARLIER ( 'Table'[Item] )
                && 'Table'[TransDate] < EARLIER ( 'Table'[TransDate] )
        ),
        'Table'[TransDate]
    )
VAR _lastinventory =
    MAXX (
        FILTER (
            'Table',
            'Table'[Item] = EARLIER ( 'Table'[Item] )
                && 'Table'[TransDate] = _last
        ),
        'Table'[InventoryCount]
    )
VAR _lastex =
    MAXX (
        FILTER (
            'Table',
            'Table'[Item] = EARLIER ( 'Table'[Item] )
                && 'Table'[TransDate] = _last
        ),
        'Table'[explanation]
    )
RETURN
    IF (
        _lastinventory = 0
            && CONTAINSSTRING ( _lastex, "depleted" ),
        DATEDIFF ( _last, 'Table'[TransDate], DAY )
    )

Вы можете использовать аналогичный подход в Power Query.

1. Сортировать по TransDate
2. ГруппаПо Item
3. Затем во вложенной сгруппированной таблице:
   1. Удалите верхние строки, которые InventoryCount = 0.
   2. Добавьте новый столбец для NextDate, если InventoryCount > 0.
   3. Заполните NextDate
   4. Удалить дубликаты InventoryCount и NextDate — это удалит последовательные 0.
   5. Вычислите дни, вычитая TransDate из NextDate.
   6. Фильтр по Days больше 0
   7. Расширить таблицу необходимыми столбцами

let
    Source = YourTable,
    #"Sorted Rows" = Table.Sort(Source,{{"TransDate", Order.Ascending}}),
    #"Grouped Rows" = Table.Group(#"Sorted Rows", {"Item"}, {{"Rows", each _, type table [Item=nullable text, TransDate=nullable date, InventoryCount=nullable number]}}),
    #"RemoveTop0Rows" = Table.TransformColumns(#"Grouped Rows", { "Rows", each Table.Skip(_, each [InventoryCount] = 0) }),
    #"Add NextDate" = Table.TransformColumns(#"RemoveTop0Rows", { "Rows", each Table.AddColumn(_, "NextDate", each if [InventoryCount] > 0 then [TransDate] else null) }),
    #"FillUp NextDate" = Table.TransformColumns(#"Add NextDate", { "Rows", each Table.FillUp(_ ,{"NextDate"}) }),
    #"Remove Consecutive zeros" = Table.TransformColumns(#"FillUp NextDate", { "Rows", each Table.Distinct(_, {"NextDate", "InventoryCount"}) }),
    #"Add days" = Table.TransformColumns(#"Remove Consecutive zeros", { "Rows", each Table.AddColumn(_, "Days", each Duration.Days([NextDate] - [TransDate]), Int64.Type) }),
    #"Filter Days" = Table.TransformColumns(#"Add days", { "Rows", each Table.SelectRows(_, each [Days] > 0) }),
    #"Expanded Rows" = Table.ExpandTableColumn(#"Filter Days", "Rows", {"Days"}, {"Days"})
in
    #"Expanded Rows"

Чтобы получить результирующую таблицу, похожую на: