Как вызывать функции в С++ и Objective-C друг к другу

В то время как Objective-C является строгим надмножеством C, существует другой язык, называемый Objective-C++, который является строгим надмножеством C++. Вы можете использовать Objective-C++ для записи C++ и Objective-C в одни и те же исходные файлы.

Другой вариант — избегать раскрытия каких-либо конкретных операторов C++ и Objective-C и поддерживать их совместимость с подмножеством, доступным для обоих языков (то есть преимущественно для языка C).

Подход Objective-C++

Вызов кода C++ из Objective-C++

Это довольно просто, если вы скомпилируете свой проект с помощью Xcode и Apple Clang, просто переименуйте расширение исходного файла с m на mm (например, с objc.m на objc.mm). Это заставит компилятор принять код C++ в данном исходном файле. Например. если у вас есть заголовок C++, определенный следующим образом:

// MyCpp.hpp file

#include <string>

struct MyCpp {
    std::string var;
    int sum(int a, int b);
};

Вы можете импортировать его в любой файл mm, как и любой другой заголовок, и легко написать встроенный код C++:

// objc.mm

#import "MyCpp.hpp"

@implementation Objc

- (int)objcSum:(int)num1 secondInt(int)num2{
    return MyCpp{}.sum(num1, num2);
}

Вызов формы кода Objective-C++ C++

Здесь все немного сложнее. C++ как язык программирования не определяет никакого интерфейса взаимодействия с Objective-C, поэтому лучшее, что вы можете сделать, это переключиться с единицы компиляции языка C++ на единицу компиляции языка Objective-C++, где оба синтаксиса приемлемы (обычно это просто означает переключение с расширения cpp на расширение mm). Опять же, если у вас есть интерфейс Objective-C, определенный следующим образом:

// MyObjc.h

#import <Foundation/Foundation.h>

@interface TDWObject: NSObject

- (NSInteger)addNum:(NSInteger)lhs toNum:(NSInteger)rhs;
@end

В некоторых классах C++ это можно вызвать без каких-либо проблем, при условии, что класс существует в модуле компиляции Objective-C++:

// MyCpp.mm

#import "MyCpp.hpp"
#import "MyObjc.h"

int MyCpp::sum(int a, int b) {
    return [[TDWObject new] addNum:a toNum: b];
}

С подход

Вызов кода C++ из Objective-C

И Objective-C, и C++ поддерживают определенный синтаксис C, поэтому альтернативный подход к тому, чтобы оба языка вызывались друг из друга, состоит в том, чтобы ограничить заголовки только C-совместимыми операторами. Например. вы можете объявить заголовок таким образом для реализации C++:

// CppSum.h

#pragma once

#ifdef __cplusplus
extern "C" {
#endif

int TDWCppSum(int a, int b);

#ifdef __cplusplus
}
#endif

(Примечание: защита extern "C" требуется, чтобы избежать искажения имен C++ при связывании этого заголовка с исходным кодом C++. В противном случае код C не сможет найти символы в скомпилированном объектном файле C++)

Однако файл реализации никак не ограничен, поэтому вы можете использовать любой код C++, поддерживаемый вашим компилятором:

// CppSum.cpp

#include "CppSum.h"

template<typename T>
class MySum {
public:
    T sum(T lhs, T rhs) {
        return lhs + rhs;
    }
};

int TDWCppSum(int a, int b) {
    return MySum<int>{}.sum(a, b);
}

В Objective-C это можно использовать так:

// objc.m

#import "CppSum.h"

@implementation Objc

- (int)objcSum:(int)num1 secondInt(int)num2{
    return TDWCppSum(num1, num2);
}

Вызов кода Objective-C из C++

Подход почти такой же: используйте только операторы C в заголовке и не раскрывайте там какую-либо реализацию Objective-C (например, операторы @interface или @protocol):

// ObjcSum.h

#pragma once

#ifdef __cplusplus
extern "C" {
#endif

int TDWObjcSum(int a, int b);

#ifdef __cplusplus
}
#endif

И опять же, вы можете использовать в реализации любые функции Objective-C:

// ObjcSum.m

#import "ObjcSum.h"
#import <Foundation/Foundation.h>

@interface TDWObject: NSObject

- (NSInteger)addNum:(NSInteger)lhs toNum:(NSInteger)rhs;
@end

@implementation TDWObject

- (NSInteger)addNum:(NSInteger)lhs toNum:(NSInteger)rhs {
    return lhs + rhs;
}

@end

int TDWObjcSum(int a, int b) {
    return [[TDWObject new] addNum:a toNum:b];
}

Для кода C++ это будет просто еще одна бесплатная функция:

// mycpp.cpp

#include "ObjcSum.h"


struct S {
    void foo() {
        auto result = TDWObjcSum(10, 15);
    }
};