Как я могу добавить к типу, который содержит целое число внутри результата размеченного объединения?

Я работаю над единичным размеченным союзом с модулем для создания экземпляров типа и возврата результата либо «ОК», если ввод был действительным, либо «Ошибка» в противном случае. Вот что у меня есть до сих пор.

type ErrorMessage = string
type NonNegativeInt = private NonNegativeInt of int

module NonNegativeInt =
    
    let create (inputInt:int) : Result<NonNegativeInt, ErrorMessage> =
        if inputInt >= 0 then
            Ok (NonNegativeInt inputInt)
        else
            Error ("inputInt must be >= 0")
      
    let value (NonNegativeInt intVal) = intVal

Я хотел бы добавить целое число к экземпляру этого типа, используя функцию создания, чтобы он блокировал отрицательные значения. У меня первый тест работает таким образом.

[<Fact>]
member this.``NonNegativeInt test`` () =
    
    let nonNegativeResult = NonNegativeInt.create 5
    
    let newNonNegativeResult = match nonNegativeResult with
                               | Ok result ->
                                   let intVal = NonNegativeInt.value result
                                   let newIntVal = intVal + 1
                                   NonNegativeInt.create newIntVal
                               | Error _ ->
                                   nonNegativeResult
            
    match newNonNegativeResult with
    | Ok result ->
        Assert.Equal(6, NonNegativeInt.value result)
    | Error _ ->
        Assert.Fail("Error creating new NonNegativeInt")

Это в значительной степени непригодно для использования таким образом. Есть ли более краткий способ выполнить эту задачу без всей этой распаковки, упаковки и сопоставления с образцом? Подходит ли Result.bind?

Обновление 1. Попытка Result.bind

Это лучше, но все еще кажется немного неуклюжим. Возможно, модулю NonNegativeInt нужна еще одна функция, кроме create и value, чтобы упростить эту задачу.

[<Fact>]   
member this.``NonNegativeInt test2`` () =

    let nni1 = NonNegativeInt.create 5

    let nni2 = nni1
               |> Result.bind (fun x -> NonNegativeInt.create ((NonNegativeInt.value x) + 1))
    
    let expectedResult = NonNegativeInt.create 6
    
    Assert.Equal(expectedResult, nni2)
Стоит ли изучать PHP в 2023-2024 годах?
Стоит ли изучать PHP в 2023-2024 годах?
Привет всем, сегодня я хочу высказать свои соображения по поводу вопроса, который я уже много раз получал в своем сообществе: "Стоит ли изучать PHP в...
Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией
Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией
В JavaScript одним из самых запутанных понятий является поведение ключевого слова "this" в стрелочной и обычной функциях.
Приемы CSS-макетирования - floats и Flexbox
Приемы CSS-макетирования - floats и Flexbox
Здравствуйте, друзья-студенты! Готовы совершенствовать свои навыки веб-дизайна? Сегодня в нашем путешествии мы рассмотрим приемы CSS-верстки - в...
Тестирование функциональных ngrx-эффектов в Angular 16 с помощью Jest
В системе управления состояниями ngrx, совместимой с Angular 16, появились функциональные эффекты. Это здорово и делает код определенно легче для...
Концепция локализации и ее применение в приложениях React ⚡️
Концепция локализации и ее применение в приложениях React ⚡️
Локализация - это процесс адаптации приложения к различным языкам и культурным требованиям. Это позволяет пользователям получить опыт, соответствующий...
Пользовательский скаляр GraphQL
Пользовательский скаляр GraphQL
Листовые узлы системы типов GraphQL называются скалярами. Достигнув скалярного типа, невозможно спуститься дальше по иерархии типов. Скалярный тип...
0
0
59
1
Перейти к ответу Данный вопрос помечен как решенный

Ответы 1

Ответ принят как подходящий

Предложение 1

Вы можете использовать построитель вычислений, чтобы сделать код чище:

type ResultBuilder() =
    member _.Return(x) = Ok x
    member _.ReturnFrom(res : Result<_, _>) = res
    member _.Bind(res, f) = Result.bind f res

let result = ResultBuilder()

Тогда ваш пример становится:

let test () =
    result {
        let! nni = NonNegativeInt.create 5
        return! NonNegativeInt.create (nni.Value + 1)
    }

test () |> printfn "%A"   // Ok NonNegativeInt 6

Я также добавил элемент, чтобы упростить доступ к значению NonNegativeInteger:

type NonNegativeInt =
    private NonNegativeInt of int
    with
    member this.Value =
        let (NonNegativeInt n) = this in n

Предложение 2

Иметь тип NNI, а затем оборачивать его в Result — это все равно, что носить одновременно ремень и подтяжки. Чтобы еще больше упростить ситуацию, вы можете полностью избавиться от типа NNI и просто сохранить логику проверки:

module NonNegativeInt =
    
    let create (inputInt:int) : Result<int, ErrorMessage> =
        if inputInt >= 0 then
            Ok inputInt
        else
            Error ("inputInt must be >= 0")

let test () =
    result {
        let! n = NonNegativeInt.create 5
        return! NonNegativeInt.create (n + 1)
    }

test () |> printfn "%A"   // Ok 6

Предложение 3

В качестве альтернативы вы можете сохранить тип NNI и доверить вызывающему объекту его использование с допустимыми значениями (без переноса в результат). Вот что делает FsCheck, например:

///Represents an int >= 0
type NonNegativeInt = NonNegativeInt of int with
    member x.Get = match x with NonNegativeInt r -> r
    override x.ToString() = x.Get.ToString()
    static member op_Explicit(NonNegativeInt i) = i

Отлично! Потребуется минута, чтобы понять это. Выражение вычисления удивительно. Мне нужно действительно пристегнуться и преодолеть мой ментальный блок на них. Они, вероятно, не так сложны, как я себе представляю. Можно ли использовать вычисляемое выражение результата внутри какого-либо другого вычислительного выражения, такого как task{}?

Matthew MacFarland 19.12.2022 14:12

Вычислительные выражения действительно великолепны. Вы можете использовать один внутри другого, но если вы собираетесь работать с Task<Result<_, _>>, вероятно, лучше использовать конструктор специально для этого типа. Есть один здесь, но я его не пробовала.

Brian Berns 19.12.2022 15:34

Другие вопросы по теме