Как я могу использовать функцию фильтра в Excel для фильтрации на основе выбора, в том числе «ВСЕ»?

Попробуйте использовать следующую формулу:

=LET(
     α, A7:B10,
     λ, LAMBDA(δ,ε,ABS(OR((δ  = "ALL"),ISBLANK(δ))-(ε=δ))),
     FILTER(α,λ(B2,TAKE(α,,1))*λ(B3,TAKE(α,,-1))))

Показать все данные, если критерии фильтра «Все» или пустые

=LET(data,A7:B10,crit,B2:B3,
    OneOrFilter,LAMBDA(array,crit,IF(OR(crit = "All",crit = ""),1,array=crit)),
    nf,OneOrFilter(CHOOSECOLS(data,1),INDEX(crit,1)),
    lf,OneOrFilter(CHOOSECOLS(data,2),INDEX(crit,2)),
    IF(AND(nf=1,lf=1),data,FILTER(data,nf*lf,"")))

то есть

=LET(
    OneOrFilter,LAMBDA(array,crit,IF(OR(crit = "All",crit = ""),1,array=crit)),
    nf,OneOrFilter(A7:A10,B2),
    lf,OneOrFilter(B7:B10,B3),
    IF(AND(nf=1,lf=1),A7:B10,FILTER(A7:B10,nf*lf,"")))

• Функция OneOrFilter возвращает либо 1, если критерием является «Все» или пустое значение, либо массив TRUE/FALSE, как результат сравнения столбца с критерием.
• В последнем операторе проверьте, соответствуют ли результаты для всех столбцов (их может быть больше двух) 1 когда требуется показать все данные. В противном случае покажите отфильтрованные данные.

include_all, SEQUENCE(ROWS(data), , 1, 0) = 1 (TRUE) для всех строк.

=LAMBDA(data, crit_1, crit_2,
    LET(
        include_all, SEQUENCE(ROWS(data), , 1, 0),
        all_or_crit, LAMBDA(col_num, crit,
            IF(
                OR(LEN(TRIM(crit)) = 0, TRIM(crit) = "ALL"),
                include_all,
                INDEX(data, , col_num) = crit
            )
        ),
        FILTER(
            data,
            all_or_crit(1, crit_1) *
                all_or_crit(2, crit_2)
        )
    )
)(A7:B10, B2, B3)

Частичное совпадение

Возможность частичного совпадения (без учета регистра с помощью SEARCH) путем ввода текста критерия с помощью *:

=LAMBDA(data, crit_1, crit_2,
    LET(
        include_all, SEQUENCE(ROWS(data), , 1, 0),
        all_or_crit, LAMBDA(col_num, crit,
            IFS(
                OR(
                    LEN(TRIM(crit)) = 0,
                    TRIM(crit) = "ALL"
                ),
                include_all,
                ISNUMBER(SEARCH("~*", crit)),
                ISNUMBER(
                    SEARCH(crit, INDEX(data, , col_num))
                ),
                TRUE,
                INDEX(data, , col_num) = crit
            )
        ),
        FILTER(
            data,
            all_or_crit(1, crit_1) *
                all_or_crit(2, crit_2)
        )
    )
)(A7:B10, B2, B3)