Как задать вопрос, но умеет писать только цифры?

Вы не можете использовать пробелы вокруг == сравнений. Ваш код говорит if %NewPenaltyLimit%<space>==<space>Numbers??, который никогда не будет совпадать.

@echo off
setlocal

:NewPass
echo Create a password
set/p "newpass=>" || goto :NewPass
:NewPenaltyLimit
cls

echo Create a penalty limit, Numbers only
set /p "NewPenaltyLimit=>" || goto :NewPenaltyLimit
set "NewPenaltyLimit=%NewPenaltyLimit:"=%"
if not defined NewPenaltyLimit goto NewPenaltyLimit
for /f "delims=1234567890" %%A in ("%NewPenaltyLimit%") do goto NewPenaltyLimit

cls
ping localhost -n 2 > nul
echo You chose %NewPenaltyLimit% goto lock

Если вы разделите значение %NewPenaltyLimit% целыми числами из 1234567890, do goto :newPass должно происходить только если существуют символы, отличные от целых чисел.

Из-за возможности ввода двойных кавычек в подсказку set /p что может вызвать синтаксическую ошибку при расширении в виде текста, когда код анализируется. Двойные кавычки будут заменены (удаленный) из входного значения сразу после ввода. Это означает, что "86" станет 86 и будет принят как действительный номер.

Примеры значений:

• a1 с разделителями создает токен со значением a, который вызывает goto :NewPenaltyLimit произойти.
• 12 delimited не создает токена, так как 1 и 2 являются разделителями.

Если Отложенное расширение разрешено включать. Эта версия может обрабатывать ввод без удаления двойных кавычек:

@echo off
setlocal

:NewPass
echo Create a password
set/p "newpass=>" || goto :NewPass
:NewPenaltyLimit
cls

echo Create a penalty limit, Numbers only
set /p "NewPenaltyLimit=>" || goto :NewPenaltyLimit
setlocal enabledelayedexpansion
for /f "delims=1234567890" %%A in ("!NewPenaltyLimit!") do (
    endlocal
    goto NewPenaltyLimit
)
endlocal

cls
ping localhost -n 2 > nul
echo You chose %NewPenaltyLimit% goto lock

Отложенное расширение нужен только для цикла for, так что это может быть лучшая версия.

!NewPenaltyLimit! не раскрывается в коде при разборе кода, что означает, что ввод, такой как "86", не вызовет ошибки и не будет принимается как действительный номер, так как он имеет двойные кавычки.

Использованная литература:

• Просмотрите for /? для получения дополнительной полезной информации.

• Просмотрите set /? информацию о замене, используемой в этом ответе.

• Посмотреть setlocal /? и if /? об отложенном расширении.

Вы можете попробовать внедрить код powershell:

<# : batch portion
@echo off & setlocal

    for /f "tokens=*" %%a in ('powershell -noprofile "iex (${%~f0} | out-string)"') do set "number=%%a"
    echo you've entered %number%

endlocal
goto :EOF

: end batch / begin powershell #>

do {
  [Console]::Error.Write("Enter a number:")
  $inputString = read-host
  $value = $inputString -as [Double]
  $ok = $value -ne $NULL
  if ( -not $ok ) {[Console]::Error.WriteLine("You must enter a numeric value") }
}
until ( $ok )

write-host "$value"

Одним из преимуществ является то, что он может поддерживать несколько типов, таких как Integer, Double, Unsigned integer и т. д. (в данном случае это Double).

Вы также можете попробовать встроенный код jscript (можно использовать на старых машинах XP):

@if (@X) == (@Y) @end /* JScript comment 
    @echo off 

        for /f "tokens=*" %%a in ('cscript //E:JScript //nologo "%~f0" "%~nx0" %* ') do set "number=%%a"
        echo you've entered %number%

    exit /b %errorlevel%       
@if (@X)==(@Y) @end JScript comment */


WScript.StdErr.Write("Enter a number:");
WScript.StdIn.Read(0);
var strMyName = WScript.StdIn.ReadLine();
var num=parseInt(strMyName);

while(isNaN(num)){
    WScript.StdErr.Write("Enter a number:");
    WScript.StdIn.Read(0);
    var strMyName = WScript.StdIn.ReadLine();
    var num=parseInt(strMyName);
}

WScript.StdOut.WriteLine(num);