У меня есть файл поиска, который я использую для поиска доступных записей в файле_2, и если такие записи присутствуют, замените эти записи на #. В настоящее время мой код заменяет всю запись на #, но мне нужно частично заменить ее. Я хочу заменить каждые два символа строки на #. Как я могу это сделать? Ваша помощь будет высоко оценена. Спасибо
код
awk ' NR==FNR {
s = $0;
gsub("[A-Za-z0-9]","#");
a[s] = $0;
next
}
{
if match($0, ">[^<]+"))
{
str = substr($0, RSTART+1, RLENGTH-1)
if (str in a )
{
$0 = substr($0, 1, RSTART) a[str] substr($0, RSTART+RLENGTH)
}
}
lines[FNR]=$0
}
END {for (i=1;i<=FNR;i++)
{
for (str in a )
{
regex = "\\<" str "\\>"
gsub(regex,a[str],lines[I])
}
}' lookup file_1 > file_2
кошачий поиск
CDX98XSD
@vanti Finserv Co.
11:11 - Capital
MS&CO(NY)
MS&CO(NY)
MS&CO(NY)
кошачий файл_1
<html>
<body>
<hr><br><>span class = "table">Records</span><table>
<tr class = "data">
<td>@vanti Finserv Co.</td>
<td>11:11 - Capital</td>
<td>MS&CO(NY)</td>
<td>New York</td>
<td>CDX98XSD</td>
<td></td>
<td></td>
<td></td>
<td></td>
</tr>
<tr class = "data">
<td>@vanti Finserv Co.</td>
<td></td>
<td>MS&CO(NY)</td>
<td>2</td>
<td>2</td>
<td>MS&CO(NY)</td>
<td>MS&CO(NY)</td>
<td></td>
</table>
</body>
</html>
ожидаемый результат
<html>
<body>
<hr><br><>span class = "table">Records</span><table>
<tr class = "data">
<td>@##n## F##s##v C##</td>
<td>1##11 - C##I##l</td>
<td>M##C##N##</td>
<td>New York</td>
<td>C##9##S#</td>
<td></td>
<td></td>
<td></td>
<td></td>
</tr>
<tr class = "data">
<td>@##n## F##s##v C##</td>
<td></td>
<td>M##C##N##</td>
<td>2</td>
<td>2</td>
<td>M##C##N##</td>
<td>M##C##N##</td>
<td></td>
</table>
</body>
</html>
Предположения/Понимание:
lookup
можно игнорировать (т. е. мы не обрабатываем повторяющиеся вхождения по-разному)lookup
мы хотим заменить n-й/(n+1)-й символ на #
(где n
= 2,5,8,11,14,17,20,....)lookup
11:11 - Capital
правильная строка замены — 1##1# - C##i##l
(в отличие от OP 1##11 - C##i##l
)Одна awk
идея:
awk '
FNR==NR { if ($0 in lookups) # if duplicate then ...
next # ignore
lookups[$0]=$0
for (i=1;i<=NF;i++) { # loop through list of white space delimited fields
oldstr=$i
newstr = ""
while (oldstr) { # while oldstr != ""
len=length(oldstr)
# keep 1st char; replace 2nd/3rd chars if length > 1/2, respectively
newstr=newstr substr(oldstr,1,1) substr("##",1,len-1)
oldstr=substr(oldstr,4) # strip off first 3 characters
}
ndx=index(lookups[$0],$i) # locate position of $i in current line
# replace $i with newstr
lookups[$0]=substr(lookups[$0],1,ndx-1) newstr substr(lookups[$0],ndx+length($i))
}
next
}
{ for (i in lookups) { # loop through our list of replacement strings ...
ndx=index($0,i) # look for a match in the current input line
while (ndx > 0) { # and if we find a match then replace it
$0=substr($0,1,ndx-1) lookups[i] substr($0,ndx+length(lookups[i]))
ndx=index($0,i) # look for another match in the current line
}
}
print
}
# uncomment following block to display contents of lookups[]
#END { print "############ lookups[]"
# for (i in lookups)
# print i " => " lookups[i]
# print "############"
# }
' lookup file_1 > file_2
Это генерирует:
$ cat file_2
<html>
<body>
<hr><br><>span class = "table">Records</span><table>
<tr class = "data">
<td>@##n## F##s##v C##</td>
<td>1##1# - C##i##l</td>
<td>M##C##N##</td>
<td>New York</td>
<td>C##9##S#</td>
<td></td>
<td></td>
<td></td>
<td></td>
</tr>
<tr class = "data">
<td>@##n## F##s##v C##</td>
<td></td>
<td>M##C##N##</td>
<td>2</td>
<td>2</td>
<td>M##C##N##</td>
<td>M##C##N##</td>
<td></td>
</table>
</body>
</html>
Сосредоточившись только на различиях:
$ diff file_1 file_2
5,7c5,7
< <td>@vanti Finserv Co.</td>
< <td>11:11 - Capital</td>
< <td>MS&CO(NY)</td>
---
> <td>@##n## F##s##v C##</td>
> <td>1##1# - C##i##l</td>
> <td>M##C##N##</td>
9c9
< <td>CDX98XSD</td>
---
> <td>C##9##S#</td>
16c16
< <td>@vanti Finserv Co.</td>
---
> <td>@##n## F##s##v C##</td>
18c18
< <td>MS&CO(NY)</td>
---
> <td>M##C##N##</td>
21,22c21,22
< <td>MS&CO(NY)</td>
< <td>MS&CO(NY)</td>
---
> <td>M##C##N##</td>
> <td>M##C##N##</td>
Раскомментирование блока END{...}
генерирует:
############ lookups[]
MS&CO(NY) => M##C##N##
CDX98XSD => C##9##S#
@vanti Finserv Co. => @##n## F##s##v C##
11:11 - Capital => 1##1# - C##i##l
############