Как заполнить таблицу Powerpoint из данных Excel

В коде ниже есть синтаксическая ошибка.

' this code is to count the number of rows, but it doesn't work
 for i = 40 to Set Name_Attendees_lastVal = sht.Columns(5).Find("*", sht.Cells(1, 2), xlValues, xlPart, xlByColumns, xlPrevious).count  

• Set нельзя использовать в предложении For
• Метод Find возвращает либо Nothing, либо объект Range; если он возвращает объект Range, свойство Row используется для получения номера строки.
• Второй аргумент (After) Find должен находиться в пределах искомого диапазона (Columns(5)); в противном случае произойдет ошибка выполнения 13.

Документация Майкрософт:

Метод Range.Find (Excel)

Option Explicit
Sub Excel2PPTTable()
    Dim Name_Attendees_lastVal As Range
    Dim oSht As Worksheet
    Dim pptApp As PowerPoint.Application
    Dim pptPres As PowerPoint.presentation
    Dim pptSlide As PowerPoint.Slide
    Dim pptTab As PowerPoint.Table
    Dim pptfile As String
    Dim iR As Long, i As Long
    Const START_ROW = 2 ' change to 1 if there isn't a header row in Table1
    Set oSht = Sheets("Reports")
    pptfile = "C:\Users\habinalshaikh\Desktop\Training\presentation maker\Course Report.pptx"
    Set pptApp = CreateObject("PowerPoint.Application")
    pptApp.Visible = True
    Set pptPres = pptApp.Presentations.Open(pptfile)
    Set pptTab = pptPres.Slides(3).Shapes("Table 1").Table
    If pptTab Is Nothing Then
        MsgBox "Can't find table on the third slide."
    Else
        With oSht.Columns(4)
            Set Name_Attendees_lastVal = .Find("*", .Cells(1), xlValues, xlPart, xlByRows, xlPrevious)
        End With
        iR = START_ROW - 1
        For i = 40 To Name_Attendees_lastVal.Row
            iR = iR + 1
            pptTab.Cell(iR, 1).Shape.TextFrame2.TextRange.Text = oSht.Range("D" & i) ' the names in the excel sheet
            pptTab.Cell(iR, 2).Shape.TextFrame2.TextRange.Text = oSht.Range("E" & i) ' the Attending status in the excel sheet
        Next
    End If
    '    pptPres.Save ' save file
    '    pptPres.Close ' close file
    '    pptApp.Quit    ' close ppt app.
End Sub