Каков оптимальный способ фильтрации строк из DataTable?

Если вы предпочитаете цикл для каждого цикла, как видно из кода, который вы разместили, используйте эту функцию:

Public Sub ForEachLoop()

    Dim maxValue As Integer

    ' Loop through rows to find max value
    For Each row As DataRow In mDataTable.Rows
        Dim currentRowValue As Integer = row.Field(Of Integer)(numbersColumn)
        If currentRowValue > maxValue Then
            maxValue = currentRowValue
        End If
    Next

    ' Create a List of DataRow
    Dim res As New List(Of DataRow)

    ' Loop through rows again to add to list each row in which numbersColumn field = maxValue
    For Each row As DataRow In mDataTable.Rows
        If row.Field(Of Integer)(numbersColumn) = maxValue Then
            res.Add(row)
        End If
    Next

    ' Create results DataTable copying the List to a new DataTable
    Dim result As DataTable = res.CopyToDataTable()

End Sub

Если вам нужно что-то более лаконичное, вы можете попробовать LINQ, но это более продвинутое решение, конечно, не удобное для новичков.

Что-то вроде:

Public Sub LINQ()

    ' Find the row with highest value in numbersColumn, then get the value from the field
    Dim maxValue As Integer = mDataTable.AsEnumerable().MaxBy(Function(x) x.Field(Of Integer)(numbersColumn)).Field(Of Integer)(numbersColumn)

    ' Select all the rows with numbersColumn value = maxValue (this returns an IEnumerable of DataRow)
    Dim resultsRows As IEnumerable(Of DataRow) = mDataTable.AsEnumerable().Where(Function(x) x.Field(Of Integer)(numbersColumn) = maxValue)

    ' Create results DataTable copying the IEnumerable to a new DataTable
    Dim result As DataTable = resultsRows.CopyToDataTable()

End Sub

Вы также можете использовать метод DataTable.Select()...

Public Sub DataTableSelect()

    Dim result As DataTable = mDataTable.Select("numbersColumn = max(numbersColumn)").CopyToDataTable()

End Sub

... но это значительно медленнее, чем для каждого цикла:

Как видите, для каждой версии примерно в 3500 раз быстрее, чем для версии Select() — это большая разница! Этот тест был выполнен на относительно небольшой таблице данных с примерно 10 000 строк — представьте, насколько большой может быть разница в таблице данных с миллионом строк.