Я написал небольшое консольное приложение, которое обновляет запись Type без использования какой-либо изменяемой переменной. Если для опытных функциональных программистов это выглядит просто, то для меня это была довольно тяжелая работа. Работает, но есть одна вещь, которая меня не устраивает. Но перед этим начнем с кода:
open System
//------------------------------------------------------------------------------------
// Type, no data validation to keep it simple
//------------------------------------------------------------------------------------
[<StructuredFormatDisplay("{FirstName} {LastName} is a {Age} year old {Sex}")>]
type Student = {
FirstName: string
LastName : string
Sex : char
Age: int
}
//------------------------------------------------------------------------------------
// I/O functions
//------------------------------------------------------------------------------------
let getConsoleChar message =
printf "\n%s" message
Console.ReadKey().KeyChar
let getConsoleString message =
printf "\n%s" message
Console.ReadLine()
let getConsoleInt = getConsoleString >> Int32.Parse //no tryparse to keep it simple, I'm sure you can type an integer
let isValidCommand command = [ 'f'; 'l'; 's'; 'a'; 'x'] |> List.contains command
let isStopCommand = (=) 'x'
let processCommand student command =
match command with
| 'f' -> { student with FirstName = (getConsoleString "First Name: ")}
| 'l' -> { student with LastName = (getConsoleString "Last Name: ")}
| 's' -> { student with Sex = (getConsoleChar "Sex: ")}
| 'a' -> { student with Age = (getConsoleInt "Age: ")}
| 'x' -> student
| _ -> failwith "You've just broken the Internet, theorically you cannot be here"
//------------------------------------------------------------------------------------
// Program
//------------------------------------------------------------------------------------
let initialStudent = {
FirstName = String.Empty
LastName = String.Empty
Sex = Char.MinValue
Age = 0
}
let commands = seq {
while true do
yield getConsoleChar "Update [f]irst name, [l]ast name, [s]ex, [a]ge or e[x]it: " }
let finalStudent =
commands
|> Seq.filter isValidCommand
|> Seq.takeWhile (not << isStopCommand)
|> Seq.map (fun cmd -> (initialStudent, cmd))
|> Seq.fold (fun student studentAndCommand -> processCommand student (snd studentAndCommand)) initialStudent
printfn "\n<<<< %A >>>>\n" finalStudent
Моя проблема с
|> Seq.map (fun cmd -> (initialStudent, cmd))
|> Seq.fold (fun student studentAndCommand -> processCommand student (snd studentAndCommand)) initialStudent
Кажется странным преобразовывать последовательность char
в Student*char
, чтобы иметь возможность подключить ее к Seq.fold
. Кроме того, если использование initialStudent
в качестве отправной точки для Seq.fold
логично, то использовать его в преобразовании сопоставления кажется странным (я не уверен, что кто-нибудь поймет логику, если этот код будет отправлен в prod).
Есть ли лучший способ обработки последовательности команд или этот код является стандартным и приемлемым в функциональном мире?
Вы можете избавиться от map
и значительно упростить fold
:
commands
|> Seq.filter isValidCommand
|> Seq.takeWhile (not << isStopCommand)
|> Seq.fold processCommand initialStudent
Я не уверен, почему вы думали, что вам нужно сопоставить seq<char>
с seq<Student * char>
для начала. Поскольку вы сразу же используете snd
для извлечения char
из кортежа, отменяя карту, первые элементы кортежей полностью игнорируются. Гораздо чище, чтобы просто избегать создания кортежей в первую очередь