Макрос для сохранения локальной копии почты (и переименования локальной копии)

Это не прямой ответ на ваш вопрос. Это расследование, которое, я надеюсь, предоставит информацию, необходимую для ответа.

Вы говорите: «… письма автоматически генерируются системой…». Это может объяснить, почему я не совсем понимаю, почему ваш код работает. Я объясню свое замешательство после того, как предоставлю некоторую предысторию.

Существует четыре различных метода, с помощью которых можно выбрать MailItem для обработки:

1. Пользователь может выбрать одно или несколько писем, а затем вызвать макрос для обработки выбранного MailItem. (Обратите внимание, что это электронное письмо пользователю, а MailItem макросу.)
2. Макрос может читать вверх или вниз папку MailItems, просматривая свойства, чтобы определить, какие из них должны быть обработаны. Sort и Filter можно использовать для более быстрого нацеливания на интересующие MailItem.
3. Вы можете указать правило, которое будет проверять каждое электронное письмо по мере его поступления и просматривать такие свойства, как тема и отправитель. Если письмо имеет необходимые свойства, можно выполнить ряд действий. Если стандартных действий недостаточно, вы можете связать макрос для выполнения любого действия, доступного для макроса VBA.
4. Вы можете указать Outlook вызывать макрос всякий раз, когда происходит определенное событие. События включают в себя: MailItem добавлено в папку Xxxx, MailItem открыто, MailItem отправлено, MailItem сохранено, MailItem закрыто, MailItem ответило или MailItem переслано.

В вашем коде используется подход 4. В частности, вы используете событие MailItemsent. Вы говорите: «… мы получаем около сотни таких [электронных писем] в неделю…». Если «получить» — правильное слово, я ожидаю, что добавление MailItem в папку «Входящие» будет подходящим событием. Возможно, ваш код работает, потому что система генерирует электронные письма от пользователя X пользователю X.

Если эти электронные письма генерируются системой, мы не можем быть уверены, какие свойства установлены и какие значения для них установлены. Скопируйте приведенный ниже код в модуль Outlook. Выберите одно или несколько из этих писем и запустите макрос CallSubForSelectedEmails.

Option Explicit
Public Sub CallSubForSelectedEmails()

  Dim Exp As Explorer
  Dim ItemCrnt As MailItem

  Set Exp = Outlook.Application.ActiveExplorer

  If Exp.Selection.Count = 0 Then
    Call MsgBox("Please select one or more emails then try again", vbOKOnly)
    Exit Sub
  Else
    For Each ItemCrnt In Exp.Selection
      If ItemCrnt.Class = olMail Then
        Call DsplSimpleProperties(ItemCrnt)
      End If
    Next
  End If

End Sub
Sub DsplSimpleProperties(ItemCrnt As Outlook.MailItem)

  Dim InxR As Long

  Debug.Print "============================================= = "
  Debug.Print "  Profile: " & Session.CurrentProfileName
  Debug.Print "     User: " & Session.CurrentUser
  With ItemCrnt
    Debug.Print "  Created: " & .CreationTime
    Debug.Print " Receiver: " & .ReceivedByName
    Debug.Print " Received: " & .ReceivedTime
    For InxR = 1 To .Recipients.Count
      Debug.Print "Recipient: " & .Recipients(InxR)
    Next
    Debug.Print "   Sender: " & .Sender
    Debug.Print " SenderEA: " & .SenderEmailAddress
    Debug.Print " SenderNm: " & .SenderName
    Debug.Print "   SentOn: " & .SentOn
    Debug.Print "  Subject: " & .Subject
    Debug.Print "       To: " & .To
  End With

End Sub

Для одного из моих электронных писем эта процедура выводит:

==============================================
  Profile: Outlook
     User: Tony Dallimore
  Created: 08/04/2019 19:59:22
 Receiver: Tony Dallimore
 Received: 08/04/2019 18:45:39
Recipient: [email protected]
   Sender: Lifecake
 SenderEA: [email protected]
 SenderNm: Lifecake
   SentOn: 08/04/2019 18:45:37
  Subject: ?? Someone commented on Alex and Eric's video
       To: [email protected]

Примечание 1. Я одновременно являюсь пользователем системы и получателем этого электронного письма. Это дает два возможных способа получить мои имя и фамилию. Я использую инициалы в своем адресе электронной почты, но ваша компания может использовать имена.

Примечание 2: мой код использует подход 1 для выбора электронных писем для обработки. Макрос CallSubForSelectedEmails вызывает макрос DsplSimpleProperties для каждого выбранного письма. Я делаю все свои исследования и всю свою разработку макросов обработки электронной почты, используя такой код. Это дает мне полный контроль над тем, какие электронные письма обрабатываются. Профиль вызова для макроса DsplSimpleProperties такой же, как и для макроса правила или макроса события. После того, как я отладил свой макрос, используя подход 1, я переключился на его вызов из правила или события с минимальным дополнительным тестированием. Я не знаю более простого способа отладки макросов обработки электронной почты.

Опять же, это не полный ответ, потому что у меня нет информации для полного ответа.

Задача 1: Создать путь

Информация для имени пути берется из MailItemSubject. Для этого примера я предполагаю, что тип запроса — 1, 2 или 3, и это последний символ темы.

Dim PathName As String

' Generate end of subfolder name
Select Case Right$(ItemCrnt.Subject,1)
  Case "1"
    PathName = "xxxx"
  Case "2"
    PathName = "yyyy"
  Case "3"
    PathName = "zzzz"
  Case Else
    ' Subject does not conform to expected format.
    Exit Sub
End Select  

' Prefix root folder name and year of subfolder name
PathName = "P:\EMEA Requests\" & Year(ItemCrnt.SentOn) & "\" & PathName

Right$ — это функция, которая извлекает указанное количество завершающих символов из строки. Также доступны функции Left$ и Mid$. Если тема достаточно сложная, мы можем рассмотреть Regex. Year — это функция, извлекающая год из даты. Значение будет целым числом, но VBA автоматически преобразует его в строку, если оно используется как строка.

Если подпрограмма не может определить тип запроса, она отбрасывает MailItem. Я обсужу этот вопрос позже.

Задание 1; Предложение 2: сгенерировать имя пути

Вы говорите, что темы не имеют фиксированного формата и просто включают слова из исходного запроса. Вы подразумеваете, что эти слова достаточно хороши, чтобы человек мог определить тип запроса. Таким образом, слова для запроса могут включать «аппаратное обеспечение», «h'ware», «компьютер» или «ноутбук». Другой запрос может включать «программное обеспечение», «приложение» или «приложение». Это простой метод обработки ситуации такого типа. Существует лучший метод, который я представлю, если он покажется возможным.

If Instr(1, LCase(ItemCrnt.Subject), "hardware") <> 0 Then 
  PathName = "xxxx"
ElseIf Instr(1, LCase(ItemCrnt.Subject), "h'ware") <> 0 Then 
  PathName = "xxxx"
ElseIf Instr(1, LCase(ItemCrnt.Subject), "computer") <> 0 Then 
  PathName = "xxxx"
ElseIf Instr(1, LCase(ItemCrnt.Subject), "laptop") <> 0 Then 
  PathName = "xxxx"
ElseIf Instr(1, LCase(ItemCrnt.Subject), "software") <> 0 Then 
  PathName = "yyyy"
ElseIf Instr(1, LCase(ItemCrnt.Subject), "application") <> 0 Then 
  PathName = "yyyy"
ElseIf Instr(1, LCase(ItemCrnt.Subject), "app") <> 0 Then 
  PathName = "yyyy"
Else
  PathName = ""
End If

Вы можете продолжать добавлять возможные ключевые слова, пока у ваших заказчиков не закончатся альтернативы. В противном случае вы можете использовать свою пользовательскую форму с подходом кнопок после того, как макрос обработает простые сообщения.

Задача 2: Создать имя файла

Dim FileName As String

FileName = Format(ItemCrnt.SentOn, "yymmdd") & " " & Replace(ItemCrnt.SenderName," ", "_")

Задача 0: Дизайн

Прежде чем начать кодирование, вам необходимо спроектировать весь процесс. Вы можете начать с чего-то простого, а затем развивать его по мере того, как лучше понимаете свои требования. Вы можете кодировать маленькие кусочки, как я сделал с PathName и FileName, чтобы вы могли понять биты, которые вам нужны, чтобы соответствовать друг другу. Но решение чего-то сложного без плана редко заканчивается удовлетворительно.

Мое понимание вашего требования неполное, но я попробую дизайн.

У меня было бы правило, согласно которому входящие электронные письма этого типа скопировано помещаются в папку Outlook, например «Несохраненные запросы EMEA». Примечание: это копии; оригинал остается в папке «Входящие» для обработки по мере необходимости. Я предполагаю, что есть способ идентифицировать эти электронные письма, который находится в пределах функциональности, доступной для правила.

У меня был бы весь код в макросе, который я вызывал бы один или два раза в день по мере необходимости. Этот макрос будет читать папку «Несохраненные запросы EMEA». Если он может сгенерировать путь и имя файла для сообщения, он сохранит сообщение в требуемой папке на диске и удалит сообщение из папки Outlook. Если он не мог обработать сообщение, он оставлял его в папке Outlook «Несохраненные запросы EMEA». Если сообщение осталось в папке Outlook «Несохраненные запросы EMEA», вы будете знать, что (1) макрос нуждается в доработке для обработки ранее неизвестного типа сообщения или (2) необходимо изменить правило, потому что оно скопировало сообщение неправильного типа.

Я сказал «прочитать папку», а не «прочитать папку». Вы получаете доступ к MailItem в папке по его положению: 1, 2, 3, … Folder.Count. Если вы удалите MailItem 2, то MailItem 3 станет MailItem 2, MailItem 4 станет MailItem 3 и так далее. Значение Folder.Count уменьшается на единицу. Иногда вы видите вопросы, спрашивающие, почему их макрос обрабатывает только все остальные MailItem. Причина в том, что у них есть кодировка вроде:

For InxI = 1 to Folder.Count
  ' Process and delete Folder.Item(InxI)
Next

С помощью приведенного выше кода вы по очереди обрабатываете элементы 1, 2, 3. Если вы удалите элемент 2, вы пропустите исходный элемент 3, потому что теперь он является элементом 2.

Правильный код:

For InxI = Folder.Count To 1 Step -1
  ' Process and delete Folder.Item(InxI)
Next

С помощью этого кода вы по очереди обрабатываете пункты 10, 9, 8, 7. Если вы удалите элемент 9, вам все равно, что элемент 10 стал элементом 9, потому что теперь вы обрабатываете элемент 8.

Если вы только читаете элементы, вам не нужно беспокоиться об этой проблеме. Но если вы добавляете или удаляете элементы, вам нужно об этом беспокоиться.