Может ли за одной строкой VBA If Then следовать одна строка ElseIf Then?

Нет. Встроенный синтаксис предназначен для коротких условий и быстрых Then и (возможно) быстрых маленьких Else операторов. Если условия нетривиальны, вам нужно использовать блочный синтаксис.

Встроенный синтаксис — это самостоятельный оператор; в VBA терминатор оператора является новой строкой, поэтому токен ElseIf не может начинать строку допустимого кода, если предыдущая строка не была зарегистрирована как условное выражение блочного синтаксиса.

Не уверен, что вы имеете в виду под "нет ошибки" в первом фрагменте... это ошибка компиляции... которая вообще предотвращает запуск кода:

Тем не менее, есть и другие способы выразить эти условия:

State = "Z"
If WD = "Sat" Or WD = "Sun" Then Exit Sub
Select Case HH
    Case Is >= 16
        State = "A"
    Case Is >= 13
        State = "B"
    Case Is >= 5
        State = "C"
    Case Is >= 4
        State = "D"
    Case Is >= 0
        State = "E"
End Select

Синтаксис оператора VBA If

Хотя ответ Матье технически правильный - это невозможно с операторами if - позвольте мне попытаться объяснить, почему.

Причина, по которой ваш первый пример не работает, заключается в том, что VBA допускает такой синтаксис:

Sub Demo()
    Dim var As Long
    If True Then var = 5
    Debug.Print var
End Sub

Обратите внимание, что в приведенном выше примере End If не требуется, на самом деле это даже не разрешено и представляет собой синтаксическую ошибку.

If True Then var = 5 End If 'Syntax error!

Это означает, что после однострочного оператора If VBA считает блок If завершенным. Вот почему следующий пример приводит к ошибке компиляции ("ElseIf без If"):

If Wd = "Sat" Or Wd = "Sun" Then State = "Z" 'VBA considers If block complete here
ElseIf HH >= 16 Then State = "A" '"ElseIf without If"

Причина, по которой вы не увидели ошибку в своем примере, заключалась в том, что ваш фрагмент был заключен в другое выражение If.

В этом случае это действительно работает, просто не так, как вы ожидали. Возможно, следующий пример с правильным отступом может продемонстрировать это:

Sub Demo()
    Dim State As String, Wd As String, HH As Long
    HH = 10
    Wd = "Do" '"Sat"
    If True Then '<-- Will always get entered -> ElseIfs will never do anything
        If Wd = "Sat" Or Wd = "Sun" Then State = "Z"
    ElseIf HH >= 16 Then State = "A" '<-- all of the following ElseIfs will not
    ElseIf HH >= 13 Then State = "B" '    get executed, because they belong to
    ElseIf HH >= 5 Then State = "C"  '    the same block as the "If True Then",
    ElseIf HH >= 4 Then State = "D"  '    which was already entered. In this
    ElseIf HH >= 0 Then State = "E"  '    case they are dead code and will never
    End If                           '    do anything!
    Debug.Print State
End Sub

VBA допускает однострочные ElseIf внутри уже запущенного If-блока, например:

If WD = "Sat" Or WD = "Sun" Then
    State = "Z"
ElseIf HH >= 16 Then State = "A"
End If

Причина этого в том, что здесь EndIf является обязательным, поэтому синтаксис однозначен. Используя это, вы можете создать то, что, возможно, наиболее близко к фактическому ответу на ваш вопрос:

Sub Demo()
    Dim State As String, Wd As String, HH As Long
    HH = 10
    Wd = "Do" '"Sat"
    If False Then
    ElseIf Wd = "Sat" Or Wd = "Sun" Then State = "Z"
    ElseIf HH >= 16 Then State = "A" 
    ElseIf HH >= 13 Then State = "B" 
    ElseIf HH >= 5 Then State = "C"  
    ElseIf HH >= 4 Then State = "D"  
    ElseIf HH >= 0 Then State = "E"  
    End If                           
    Debug.Print State
End Sub

Это If утверждение выглядит немного странно, но оно работает! Возможно, это обходной путь, который вы ищете. Если нет, есть дополнительные варианты с использованием синтаксиса продолжения строки с Select Case.

Альтернатива: Select Case

Select Case также может оценивать любое условие, как и операторы if, используя Select Case True, как показано в следующем фрагменте кода:

Sub Demo()
    Dim State As String, Wd As String, HH As Long
    HH = 10
    Wd = "Do" '"Sat"
    Select Case True:
        Case Wd = "Sat" Or Wd = "Sun": State = "Z"
        Case HH >= 16: State = "A"
        Case HH >= 13: State = "B"
        Case HH >= 5: State = "C"
        Case HH >= 4: State = "D"
        Case HH >= 0: State = "E"
    End Select
    Debug.Print State
End Sub

Кроме того, используя Select Case, вы можете пойти еще дальше и поместить все выражение в одну строку (до 1024 символов):

Sub Demo()
    Dim State As String, Wd As String, HH As Long
    HH = 10
    Wd = "Do" '"Sat"
    Select Case True: Case Wd = "Sat" Or Wd = "Sun": State = "Z": Case HH >= 16: State = "A": Case HH >= 13: State = "B": Case HH >= 5: State = "C": Case HH >= 4: State = "D": Case HH >= 0: State = "E": End Select
    Debug.Print State
End Sub