Найдите последнюю версию и верните гиперссылку, используя столбец для поиска

Разливаю за HYPERLINK

Возможный обходной путь использования HYPERLINK с распределенными массивами: предварительно заполните диапазон ссылок, учитывая самый большой набор результатов, при этом первая ячейка указывает на ячейку с формулой разлива.

Как в примере ниже:

• В D2 введите HYPERLINK(E2), заполните
• В E2 введите формулу разлива, результат будет в виде
  CONCAT("[", INDEX(filtered, COUNTA(filtered)), "]") вместо HYPERLINK(CONCAT…

Таким образом, нам не придется заполнять то, что уже пролилось :)

Если вы еще этого не сделали, не могли бы вы попробовать это:

=BYROW(A2:A3, LAMBDA(row,
LET(partnum, IF(ISNUMBER(SEARCH(row, B2:B4)), C2:C4 & B2:B4, ""),
filtered, FILTER(partnum, partnum <> ""),
HYPERLINK(CONCAT("[", INDEX(filtered, COUNTA(filtered)), "]")))))

• Обертывание ссылки в [] необходимо, если в пути есть пробелы.
• В моем тестировании ссылки не отформатированы (с синим подчеркиванием) последовательно (но при наведении курсора курсор превращается в указатель), но функционируют правильно как ссылки.

Пожалуйста, протестируйте и дайте знать.

Начало новой строки текста внутри ячейки в Excel - Служба поддержки Microsoft

Необязательно — извлеките номера ревизий, чтобы найти максимум

Поскольку вам, кажется, нравятся LAMBDA, определение вспомогательной функции first_number в диспетчере имен для извлечения номера версии может оказаться полезным. Это быстрособранная функция, более короткие вы можете найти где-нибудь еще. Я предпочитаю использовать REGEX, но он может быть пока недоступен в вашей версии Excel.

first_number определено в диспетчере имен:

=LAMBDA(text,
    LET(
        len_, LEN(text),
        num_start, MIN(MAP(SEQUENCE(len_), LAMBDA(i, IF(ISNUMBER(--MID(text, i, 1)), i, len_ + 1)))),
        num_end, MIN(
            MAP(
                SEQUENCE(len_ - num_start + 1, , num_start),
                LAMBDA(i, IF(ISNUMBER(--MID(text, i, 1)), len_ + 1, i))
            )
        ),
        --MID(text, num_start, num_end - num_start)
    )
)

• Тогда вместо использования столбца Part Number можно использовать TEXTSPLIT для извлечения Part Number и Revision.
• После извлечения используйте пользовательскую функцию, чтобы получить максимальное число.

=LET(
    file_names, TOCOL(B2:B10, 1),
    paths, TOCOL(C2:C10, 1),
    revisions, TOCOL(TRIM(BYROW(file_names, LAMBDA(row, TEXTBEFORE(row, ",")))), 2),
    part_nums, TOCOL(TRIM(BYROW(file_names, LAMBDA(row, TEXTAFTER(row, ",")))), 2),
    rev_numbers, MAP(revisions, first_number),
    make_hyperlink, LAMBDA(path_and_file, HYPERLINK(CONCAT("[", path_and_file, "]"))),
    make_links, MAP(
        UNIQUE(part_nums),
        LAMBDA(part_num,
            LET(
                max_rev_num, MAX(FILTER(rev_numbers, part_nums = part_num)),
                path_and_file_for_latest, FILTER(
                    HSTACK(paths, file_names),
                    (part_nums = part_num) * (rev_numbers = max_rev_num)
                ),
                make_hyperlink(path_and_file_for_latest)
            )
        )
    ),
    make_links
)