Новичок в использовании массивов SAS и не может заставить элементы массива заполняться значениями на основе инструкции IF-THEN-ELSE

Массив на основе переменных SAS позволяет указать, к каким переменным следует обращаться с помощью синтаксиса массива. Указание имен переменных после имени массива приведет к созданию новых переменных, если они еще не существуют.

Не забывайте, что переменные сбрасываются до отсутствующих в верхней части неявного цикла DATA Step. Если вы пытаетесь «заполнить» элементы массива по группе, то переменные массива также необходимо будет сохранить и сбросить в начале группы по. Если переменные массива являются частью набора данных, считываемого SET, вам может понадобиться «смежный» массив, в котором определенные элементы не будут перезаписывать значение.

Пример:

Поскольку вам нужно 0/1 в каждом слоте, вам нужно будет пройти по всему массиву и установить для элемента результат логической оценки (0-ложь, 1-истина).

Показанное здесь логическое выражение a <= b <= c характерно для SAS и означает a <= b and b <= c

data want ;
  set have ;
  array slot time_block_0-time_block_47 ;  * 48 variables ;
  do index = 1 to dim(slot) ;
    slot[index] = start_block <= index <= end_block ;
  end ;
run ;

Будет меньше путаницы, если вы скажете SAS использовать индексы от 0 до 47 вместо обычных от 1 до 48.

Давайте сначала создадим несколько примеров данных, чтобы у нас было что протестировать.

data have;
  input start_block end_block;
cards;
0 47
2 4
-1 56
56 -1
;

Поскольку SAS оценивает логические выражения как 0 (FALSE) или 1 (TRUE), вы можете пропустить логику IF/THEN и просто использовать оператор присваивания. (Также не беспокойтесь об использовании параметров набора данных для DROP переменной. Все, что вам нужно, — это простой оператор DROP. Оставьте усложнение параметров набора данных на случай, если вам придется их использовать.)

data WANT ;
  set HAVE;
  array time_blocks[0:47] time_block_0 - time_block_47;
  do index = 0 to 47;
    time_blocks[index] = start_block <= index <= end_block;
  end;
  drop index;
run;

В комментариях вы, кажется, говорите, что фактические данные — это значения времени суток для операций. В этом случае используйте фактические значения даты и времени и циклически переключайтесь между ними.

Инициализируйте массив нулями, затем выполните цикл между началом и концом с шагом в полчаса, а затем увеличьте соответствующую переменную.

data have;
  input start :datetime. end :datetime.;
  format start end datetime19.;
cards;
01JAN2024:00:15 01JAN2024:04:35 
01JAN2024:22:15 02JAN2024:03:00 
;

data WANT ;
  set HAVE;
  array time_blocks[0:47] time_block_0 - time_block_47;
  do index = 0 to 47; time_blocks[index] = 0; end;
  do datetime=start to end by '00:30:00't ;
    time_blocks[int(timepart(datetime)/'00:30:00't)]+1;
  end;
  drop index datetime;
run;

Если у вас есть только время суток, но нет фактических значений даты и времени, просто преобразуйте их. Поэтому используйте DAY=0 при преобразовании START_TIME в значение даты и времени, а когда END_TIME меньше START_TIME, используйте DAY=1 при преобразовании его в значение даты и времени. Пример:

start = dhms(0,0,0,start_time);
end = dhms(end_time<start_time,0,0,end_time);
format start_time end_time tod5. start end datetime19.;