Обработка текста: смещение значения даты в столбце на основе другого значения столбца

Используя GNU awk, любые преобразования даты должны выполняться с помощью предоставленных функций даты. Две полезные функции времени для этой задачи — mktime и strftime:

• mktime(datespec): This converts a date specification string, datespec, of the form YYYY MM DD hh mm ss into a Unix epoch time, i.e. the total seconds since 1970 01 01 UTC. Since gawk-4.2.1 you can use the utc-flag to indicate datespec is in UTC or not.

• strftime(format,timestamp): This converts an epoch-time timestamp into a formatted string (same formatting as the date command). You can use the utc-flag the indicate that the returned time should be in UTC or in the local time-zone.

More info in the GNU awk manual

Теперь код становится: convert.awk

BEGIN {FS=OFS="|"}
{ d=$4
  time=mktime(substr(d,1,4)" "substr(d,5,2)+1-$5" "substr(d,7,2)" 00 00 00")
  $5=strftime("%Y%m%d",time)
  print
}' file

и вы запускаете это с помощью:

$ awk -f convert.awk file.txt

mktime удивительно добавка. Таким образом, строка, которую вы передаете в форме YYYY MM DD hh mm ss, не обязательно должна быть правильной датой, у вас могут быть неправильные значения. Например, строка 2019 01 32 00 00 00 эквивалентна 2019 02 01 00 00 00, а 2019 5 -10 00 00 00 эквивалентна 2019 04 20 00 00 00 и, более того, 2019 -19 -10 00 00 эквивалентна 2017 04 20 00 00.

Примечание:, поскольку мы изменяем время непосредственно в mktime, нам не нужно беспокоиться о переходе на летнее время (см. комментарий).

В дополнение к ответу kvantour (который, вероятно, чище моего, потому что я бы предпочел использовать встроенные функции awk, а не вызывать команды bash внутри awk), вот ваш исправленный код:

BEGIN{
    FS="|"
    OFS = FS
}
{
#   Date field is in column 4, offset is in column 5
#   Replace column 5 with the offset date

    cmd = "date -d '"$4" -"$5-1" months'  +'%Y%m%d'" # as suggested by @kvantour
    cmd | getline result
    close(cmd)
    $5 = result
    print $0
}

Результат :

a1|b1|c1|20190101|20190101|1|11|A|D
a1|b1|c1|20190101|20181201|2|12|B|E
a1|b1|c1|20190101|20181101|3|13|C|F
a2|b2|c2|20190101|20190101|4|14|G|J
a2|b2|c2|20190101|20181201|5|15|H|K
a2|b2|c2|20190101|20181101|6|16|I|L

Больше информация здесь.

Without the call to close(), awk creates child processes to run the commands, until it eventually runs out of file descriptors for more pipelines.

Вам не нужно вызывать для этого внешнюю утилиту date или функции времени, специфичные для gawk, это просто математика:

$ cat tst.awk
BEGIN { FS=OFS="|" }
{
    delta = $5 - 1
    year  = substr($4,1,4)
    month = substr($4,5,2)
    day   = substr($4,7)
    month = month - delta
    if (month <= 0) {
        year--
        month += 12
    }
    $5 = sprintf("%04d%02d%02d",year,month,day)
    print
}
$
$ awk -f tst.awk file
a1|b1|c1|20190101|20190101|1|11|A|D
a1|b1|c1|20190101|20181201|2|12|B|E
a1|b1|c1|20190101|20181101|3|13|C|F
a2|b2|c2|20190101|20190101|4|14|G|J
a2|b2|c2|20190101|20181201|5|15|H|K
a2|b2|c2|20190101|20181101|6|16|I|L