Ошибка компиляции ERC4907 в «функции _beforeTokenTransfer»

Я работаю над задачей создания NFT Marketplace с Truffle . Для этого я использую смарт-контракт ERC4907 и пытаюсь его скомпилировать. Ниже приведен мой код ERC4907.

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/extensions/ERC721URIStorage.sol";
import "./IERC4907.sol";

contract ERC4907 is ERC721URIStorage, IERC4907 {
  struct UserInfo {
    address user; // address of user role
    uint64 expires; // unix timestamp, user expires
  }

  mapping(uint256 => UserInfo) internal _users;

  constructor(string memory name_, string memory symbol_) ERC721(name_, symbol_) {}

  /// @notice set the user and expires of a NFT
  /// @dev The zero address indicates there is no user
  /// Throws if `tokenId` is not valid NFT
  /// @param user  The new user of the NFT
  /// @param expires  UNIX timestamp, The new user could use the NFT before expires
  function setUser(
    uint256 tokenId,
    address user,
    uint64 expires
  ) public virtual override {
    require(
      _isApprovedOrOwner(msg.sender, tokenId),
      "ERC721: transfer caller is not owner nor approved"
    );
    UserInfo storage info = _users[tokenId];
    info.user = user;
    info.expires = expires;
    emit UpdateUser(tokenId, user, expires);
  }

  /// @notice Get the user address of an NFT
  /// @dev The zero address indicates that there is no user or the user is expired
  /// @param tokenId The NFT to get the user address for
  /// @return The user address for this NFT
  function userOf(uint256 tokenId)
    public
    view
    virtual
    override
    returns (address)
  {
    if (uint256(_users[tokenId].expires) >= block.timestamp) {
      return _users[tokenId].user;
    } else {
      return address(0);
    }
  }

  /// @notice Get the user expires of an NFT
  /// @dev The zero value indicates that there is no user
  /// @param tokenId The NFT to get the user expires for
  /// @return The user expires for this NFT
  function userExpires(uint256 tokenId)
    public
    view
    virtual
    override
    returns (uint256)
  {
      return _users[tokenId].expires;
  }

  /// @dev See {IERC165-supportsInterface}.
  function supportsInterface(bytes4 interfaceId)
    public
    view
    virtual
    override
    returns (bool)
  {
    return
      interfaceId == type(IERC4907).interfaceId ||
      super.supportsInterface(interfaceId);
  }

  function _beforeTokenTransfer(
    address from,
    address to,
    uint256 tokenId
  ) internal virtual override {
    super._beforeTokenTransfer(from, to, tokenId);

    if (from != to && _users[tokenId].user != address(0)) {
      delete _users[tokenId];
      emit UpdateUser(tokenId, address(0), 0);
    }
  }
}

Я получаю следующую ошибку при попытке скомпилировать его. Ошибка в функции "_beforeTokenTransfer".

CompileError: TypeError: Wrong argument count for function call: 3 arguments given but expected 4.
  --> project:/contracts/ERC4907.sol:87:5:
   |
87 |     super._beforeTokenTransfer(from, to, tokenId);
   |    

Я использую следующие версии

• Трюфель v5.6.8 (ядро: 5.6.8)

• Ганаш v7.5.0

• Solidity v0.5.16 (solc-js)

• Узел v16.17.1

• Web3.js v1.7.4

Я проверил эталонную реализацию на https://eips.ethereum.org/EIPS/eip-4907. Но это все тот же код.

Может кто-нибудь показать мне, что я ошибся здесь? Спасибо

РЕДАКТИРОВАТЬ

Как ответил @Muhammad Hassan, было установлено, что совсем недавно (08.11.2022) в функции _beforeTokenTransfer на ERC721 произошло критическое изменение. Пожалуйста, обратитесь к журналу изменений по следующей ссылке. https://github.com/OpenZeppelin/openzeppelin-contracts/blob/7c5f6bc2c8743d83443fa46395d75f2f3f99054a/CHANGELOG.md#breaking-changes

Добавление дополнительного аргумента «uint256 batchSize» решило проблему компиляции. Спасибо.