Пакет - заменить строку в текстовом файле, используя цикл for, включая пустые строки

Вы можете попробовать это так:

@Echo Off
Set "taglinelinks=one two three"
(   For /F "Tokens=1*Delims=:" %%A in ('Findstr /N "^" "overview.md"')Do (
        If %%A NEq 5 (Echo=%%B)Else Echo %taglinelinks%
    )
)>"new.txt"

В этом ответе я придерживаюсь нашего исходного кода и сосредотачиваюсь на недостатках. В основном мне нравится этот подход (конечно, с исправлением ошибок), потому что он может правильно обрабатывать даже строки, начинающиеся с двоеточия :, и у него нет проблем с появлением ! в текстовом файле, поскольку включено отложенное раскрытие.

Так или иначе, сначала я хочу показать адаптированный и работающий код:

@echo off
setlocal DisableDelayedExpansion
set "taglinelinks=one two three"
> "new.txt" (
    for /F "delims = " %%a in ('findstr /N "^" "overview.md"') do (
        set "var=%%a"
        setlocal EnableDelayedExpansion
        if "!var:~,2!" == "5:" (
            echo(!taglinelinks!
        ) else (
            echo(!var:*:=!
        )
        endlocal
    )
)
endlocal

И вот что я исправил:

• предложение if должно быть в блоке с включенным отложенным расширением, поэтому я переместил его на одну строку вниз и заменил % на !;
• Я реализовал предложение else так, чтобы оно содержало оставшуюся часть кода в теле цикла for /F.
• Я добавил отсутствующий endlocal, поэтому вы не можете столкнуться с ограничениями вложенности setlocal, а командная строка set "var=%%a" фактически появляется в разделе кода с отключенным отложенным расширением, что необходимо, чтобы не создавать проблем с появлением ! в файле;

И вот некоторые мелкие и косметические изменения:

• Я добавил @echo off сверху, чтобы избежать записи эха команд в new.txt;
• Я переместил исходную команду setlocal наверх, чтобы сначала отключить отложенное расширение, поэтому ! можно было даже безопасно использовать в перенаправленном имени файла и в первой командной строке set (поскольку мы могли не знать, отключено ли отложенное расширение или включено ранее );
• Я использовал синтаксис set в кавычках также для присвоения переменной taglinelinks, чтобы сделать его безопасным; затем я переместил эту строку за пределы блока перенаправления, чтобы она стала более очевидной;
• хотя это не мешает, опция usebackq не обязательна, поэтому я убрал ее и использовал одинарные кавычки '' (но тут дело вкуса);
• командная строка в кавычках findstr выглядит немного странно, особенно экранированный знак вставки ^^, поэтому я изменил кавычки, чтобы строка поиска, а также путь к файлу были заключены в кавычки, поэтому такое экранирование больше не требуется, и имя файла может даже содержать пробелы или другие специальные символы;
• строка для отображения значения taglinelinks не находится в блоке, где включено отложенное раскрытие; это позволяет переменной содержать даже специальные символы;
• второе присваивание set "var=!var:*:=!" на самом деле не нужно, поэтому я удалил его и сразу повторил усеченную строку;
• Я адаптировал отступ кода, в том числе для блока if/else, чтобы улучшить читабельность;
• Я переместил перенаправление > "new.txt" в начало внешнего блока в скобках, чтобы сделать его более заметным (но это опять же просто вопрос вкуса), и я заключил имя файла в двойные кавычки, так что оно может даже содержать пробелы или что-то другое. специальные символы;
• Я добавил еще одну явную команду endlocal, которая принадлежит начальной setlocal;

Есть еще одна вещь, которая мне не нравится в скрипте, а именно негибкий способ определения номера текущей строки, потому что на данный момент он работает только для чисел меньше 10, немного не адаптируя код.

Вот способ гибко указать номер строки для замены:

@echo off
setlocal DisableDelayedExpansion
set "taglinelinks=one two three"
set "linenumber=5"
> "new.txt" (
    for /F "delims = " %%a in ('findstr /N "^" "overview.md"') do (
        set "var=%%a"
        setlocal EnableDelayedExpansion
        set /A "num=var"
        if !num! equ !linenumber! (
            echo(!taglinelinks!
        ) else (
            echo(!var:*:=!
        )
        endlocal
    )
)
endlocal

Вот что я сделал:

• сначала я определил переменную (константу) linenumber с номером строки 5; учитывать, что linenumber не должно содержать ведущих нулей, чтобы число не интерпретировалось как восьмеричное целое число позже (по if);
• в цикл, который я поместил set /A "num=var", который использует неявное расширение переменной set /A, что означает, что строка строки сканируется слева направо до первого нечислового символа¹, затем эта строка преобразуется в целое число и, наконец, присваивается num; это означает, что файл содержит менее 2³¹ строк;
• предложение if изменено на if !num! equ !linenumber!, которое выполняет числовое сравнение из-за equ, поскольку оба выражения являются целыми числами; так что это больше не зависит от количества цифр номера строки; здесь я мог бы также использовать %linenumber%, так как переменная не изменяется в блоке кода, но я решил использовать !linenumber!, чтобы покрыть случай неправильной инициализации этой переменной (особенно, когда она пуста или содержит специальные символы из-за опечаток);

_{1) Actually leading SPACEs and TABs are ignored. Next a single + or - sign may occur. Then everything up to the next non-numeric figure is used to convert the string into a signed 32-bit integer. If the result cannot be represented as such it becomes coerced.}