Перебор патчей с общими свойствами в Netlogo

Мое первое замечание: у вас есть патчи, которые снова просят патчи в simulation.

Ваше второе решение было проще для работы. Главное здесь было вырвать его из контекста патча и позволить наблюдателю запустить его. Для вывода на печать я предлагаю использовать такой формат, как print (word current-ID ": " current-sum). Это намного чище, когда вы хотите быстро проверить это после запуска модели.

to simulation-2
  reset-timer
  
  let i 0
  while [i < length AT-data] [
    let current-inner-list item i AT-data
    let current-ID item 0 current-inner-list
    let current-sum sum [AT1] of patches with [ID = current-ID]
    print (word current-ID ": " current-sum)
    
    set i i + 1 
  ]
  
  print timer
end

Для вашего первого решения ваша проблема заключалась в том, что у вас была только одна переменная области, которую вы увеличили. В следующем примере я превратил область в список той же длины, что и AT-данные, содержащий списки. Каждый внутренний список состоит из идентификатора и счетчика, установленного на 0 [["A" 0] ["B" 0] ... ["I" 0]]. Для этого я использую процедуру map. map берет каждый отдельный элемент списка, выполняет с ним определенную операцию и возвращает их все как новый список. В общем, это очень полезная процедура для изучения, когда вы будете работать со списками.

Затем я перебираю все исправления, как вы, и увеличиваю счетчик моего списка областей для правильного идентификатора. У меня есть две разные версии этого увеличения. Первый имеет множество локальных переменных, чтобы наглядно показать, как он работает. Вы выкапываете правильный подсписок, затем выкапываете правильную переменную, увеличиваете эту переменную, заменяете ее в подсписке и заменяете подсписок в основном списке. Второй делает то же самое, но в одной строке кода.

to simulation-1
  reset-timer
  
  set area map [inner-list -> list item 0 inner-list 0] AT-data ;creates a new list of lists of the form [["A" 0] ["B" 0] ... ].
  
  ask patches [
    let i 0
    while [i < length AT-data] [
      let current-inner-list item i AT-data
      ifelse (ID = item 0 current-inner-list)
      [ let inner-area-list item i area    ;grab the correct innerlist
        let increased-count item 1 inner-area-list + AT1    ;increment the second part of this inner list
        set inner-area-list replace-item 1 inner-area-list increased-count    ;put the incremented count back into the inner list
        set area replace-item i area inner-area-list    ;put the inner list back into the complete list
        
        ;; all these can be combined into a single line of code but that is more prone to errors
        ;set area replace-item i area (replace-item 1 item i area (item 1 item i area + AT1))
        
        stop
      ]
      [ set i i + 1 ]
    ]
  ]
  print area
  
  print timer
end

Только после создания всей этой вложенной структуры списка я подумал о том, что вы можете сделать это с обычным списком, в котором у вас есть только разные счетчики, а не идентификаторы, но эта структура делает его очень компактным, понятным и удобным для использования. для последующей обработки.