Perl добавить строку в текстовый файл

Не совсем понятно, что вы подразумеваете под «интервалом табуляции», но, возможно, вы ищете:

perl -pE 'm/^(\t*)/; say "${1}testing" if $a; $a = /apple/' filename.txt

Я подозреваю, что вы на самом деле хотите \s вместо \t, но YMMV. По сути, в каждой строке ввода вы сопоставляете начальный пробел, а затем печатаете строку с этим пробелом и строкой «тестирование», если предыдущая строка совпала.

Чтобы написать это подробно:

#!/usr/bin/env perl

use 5.12.0;
use strict;
use warnings;
my $n = 'filename.txt';

open my $f, '<', $n, or die "$n: $!\n";
while(<$f>){
        m/^(\t*)/;    # possibly \s is preferred over \t
        say "${1}testing" if $a;
        $a = /apple/;
        print;
}

Мы не можем просто «добавить» текст в середину файла, как пытались. Файл представляет собой последовательность байтов, и их нельзя добавлять или удалять (кроме как в конце), а только изменять. Поэтому, если мы начнем запись в середину файла, мы изменим там байты, поэтому перезапишем то, что следует за этим местом. Вместо этого нам приходится копировать остальной текст и записывать его обратно после «дополнения» или копировать файл, добавляя текст в процессе.

Еще один способ - прочитать весь файл в строку и запустить для него регулярное выражение, чтобы изменить его, а затем записать новую строку. Предполагая, что файл не слишком велик для этого

perl -0777 -pe's{apple\n\K(\t)}{Added text\n$1}g' in.txt

Переключатель -0777 заставляет его читать весь файл в строку («глотать»), доступную в $_, к которой по умолчанию привязано регулярное выражение. Этот \K, который является просмотром назад , отбрасывает предыдущие совпадения, поэтому они не поглощаются из строки, и нам не нужно (захватывать и) возвращать их обратно. С модификатором /g он продолжает перебирать всю строку, чтобы найти и изменить все вхождения шаблона.

Это выводит измененный файл на экран, что можно сохранить в новом файле, перенаправив его

perl -0777 -pe'...' in.txt > out.txt

Или можно изменить входной файл «на месте» с помощью -i

perl -0777 -i.bak -pe'...' in.txt 

.bak позволяет сохранить оригинал с расширением .bak. См. переключатели в perlrun.

Другой способ — использовать предпросмотр для того, что следует далее (вкладка), чтобы нам не приходилось захватывать и возвращать его обратно.

perl -0777 -pe's{apple\n\K(?=\t)}{Added text\n}g' in.txt

Все это приводит к желаемому изменению.

Обратите внимание на эту вкладку ("tab_spacing")

Приведенное выше регулярное выражение предполагает символ табуляции в начале строки, следующей за строкой с apple. Когда мы говорим «табуляция», мы имеем в виду один символ (табуляцию).

Но есть много причин, по которым на самом деле может не быть символа табуляции, даже если он выглядит так, как будто он есть. Пример: все табуляции могут быть автоматически заменены пробелами редактором.

Поэтому может быть безопаснее использовать \s+ (несколько пробелов) вместо \t в регулярном выражении.

s{apple\n\K(\s+)}{Added text\n$1}g

или

s{apple\n\K(?=\s+)}{Added text\n}g

Если это должно быть сделано внутри существующей более крупной программы Perl (а не как программа командной строки, «однострочная», как указано выше), один из способов

use Path::Tiny;  # path(), constructor

my $file_content = path($file)->slurp;  # read the file into a string

# Now use a regex; all discussion above applies
$file_content =~ s{apple\n\K(?=\t)}{Added text\n}g;

# Print out $file_content, to be redirected etc. Or write to a file
path($new_file)->spew($file_content);

Я использую библиотеку Path::Tiny, чтобы "слепить" файл в строку и spew записать $file_content в новый файл. Это необходимо установить, так как оно не находится в «ядре» (обычно не устанавливается вместе с Perl), и если это проблема по какой-то странной причине, вот своего рода идиома для него без каких-либо библиотек

my $file_content = do { 
    local $/;
    open my $fh, '<', $file or die "Can't open $file: $!";
    <$fh>;
};

или даже

my $file_content = do { local (@ARGV, $/) = $file; <> };

(см. этот пост для некоторых объяснений и ссылок)

Честно говоря, некоторые довольно странные вещи в вашем коде:

• Чтение и запись в файл одновременно затруднены. Ваш код, например, просто перепишет все существующие данные в файле.
• Использование простого дескриптора файла (CONFIG) вместо лексической переменной и двух аргументов open() вместо версии с тремя аргументами (open my $config_fh, '+<', $config') заставляет меня думать, что вы используете довольно старые учебники по Perl.
• Использование chop() вместо chomp() заставляет меня думать, что вы используете какие-то древние учебники по Perl
• Кажется, у вас есть лишний $ в вашем регулярном выражении - ^$apple$, вероятно, должно быть ^apple$

Кроме того, Tie::File уже более двадцати лет входит в стандартную библиотеку Perl и значительно облегчит эту задачу.

#!/usr/bin/perl

use strict;
use warnings;

use Tie::File;

tie my @file, 'Tie::File', 'filename.txt' or die $!;

for (0 .. $#file) {
  if ($file[$_] eq 'apple') {
    splice @file, $_ + 1, 0, "\ttesting\n";
  }
}