PL/SQL создает функцию проверки палиндрома
Я работаю в sqldeveloper.exe, и я хотел бы
заархивируйте работающую функцию тестера палиндрома.
Однако по какой-то довольно неочевидной причине
слово VARCHAR2(255) или идентификатор функции выровнен
красной краской. Может, кто-нибудь направит меня
на этой дороге отчаяния? Заранее спасибо!
Обновлено: Пока я принимаю только
палиндромы четной мощности в
учетная запись.
Определение, которое я написал:
CREATE OR REPLACE FUNCTION PALINDROME(WORD VARCHAR2(255)) RETURN
INT IS
N := LENGTH(WORD) / 2;
I := 1;
J := LENGTH(WORD);
BEGIN
WHILE I <= N AND SUBSTR(WORD, I, 1) = SUBSTR(WORD, J, 1) LOOP
I := I + 1;
J := J - 1;
END LOOP;
IF I = N + 1 THEN
RETURN 1;
ELSE
RERURN 0;
END IF;
END PALINNDROME;
Ответы 2
Ты:
- не нужен размер в сигнатуре функции;
- есть
RERURNвместоRETURN - Не используйте типы для ваших переменных.
PALINNDROMEнаписан с ошибкой в конце функции.
Вы можете исправить это следующим образом:
CREATE OR REPLACE FUNCTION PALINDROME(
WORD VARCHAR2
) RETURN INT
IS
N PLS_INTEGER := LENGTH(WORD) / 2;
I PLS_INTEGER := 1;
J PLS_INTEGER := LENGTH(WORD);
BEGIN
WHILE I <= N AND SUBSTR(WORD, I, 1) = SUBSTR(WORD, J, 1) LOOP
I := I + 1;
J := J - 1;
END LOOP;
IF I = N + 1 THEN
RETURN 1;
ELSE
RETURN 0;
END IF;
END PALINDROME;
/
Примечание. Вам не нужен особый случай, когда слово имеет нечетную длину, так как средняя буква всегда равна самой себе.
Но вы можете упростить его до:
CREATE OR REPLACE FUNCTION PALINDROME(
WORD VARCHAR2
) RETURN INT
IS
BEGIN
FOR I IN 1 .. LENGTH(word)/2 LOOP
IF SUBSTR(WORD, I, 1) <> SUBSTR(WORD, -I, 1) THEN
RETURN 0;
END IF;
END LOOP;
RETURN 1;
END PALINDROME;
/
дб <> рабочий пример здесь
Альтернатива, которая работает как для четной, так и для нечетной длины, и ее не нужно различать (работает одинаково для обоих случаев):
create or replace function palindrome_check(str varchar2) return number as
begin
return case when length(str) > 1
then case when substr(str, 1, 1) != substr(str, -1, 1) then 0
else palindrome_check(substr(str, 2, length(str) - 2))
end
else 1
end;
end;
/
Это реализует очевидную рекурсию: если строка пуста или имеет длину 1, то это палиндром. Если длина 2 или больше, мы сравниваем первый и последний символ. Если они разные, то строка не является палиндромом. Если они совпадают, удалите их обе из строки и проверьте, является ли оставшаяся подстрока палиндромом.
Рекурсия стоит дорого; при правильном уровне оптимизации оптимизатор PL/SQL переписывает функцию, используя цикл for, поэтому нам не нужно об этом беспокоиться.
with
test_strings (str) as (
select null from dual union all
select 'x' from dual union all
select 'zz' from dual union all
select 'ab' from dual union all
select 'lol' from dual union all
select 'lot' from dual union all
select 'abba' from dual union all
select 'mmmm' from dual union all
select 'mama' from dual union all
select 'radar' from dual union all
select 'poker' from dual union all
select 'pullup' from dual
)
select str, palindrome_check(str) as is_palindrome from test_strings;
STR IS_PALINDROME
------ -------------
1
x 1
zz 1
ab 0
lol 1
lot 0
abba 1
mmmm 1
mama 0
radar 1
poker 0
pullup 1
varchar2в определении функции не должно быть длины