Почему я получаю «Ошибка типа: значение не определено и не может быть преобразовано в объект» в Qt QML?

Я перенес ваше приложение на PySide6. Похоже, он работает с минимальными изменениями кода.

Вот main.py со ссылками PySide2, измененными на PySide6:

import sys
from PySide6.QtCore import Qt, QStringListModel, QObject, Signal, Slot
from PySide6.QtGui import QGuiApplication
from PySide6.QtQml import QQmlApplicationEngine

class Main(QObject):

    clicked = Signal()

    def __init__(self, parent=None):
        super(Main, self).__init__(parent)

    @Slot()
    def justClicking(self):
        self.clicked.emit()

if __name__ == "__main__":
    app = QGuiApplication(sys.argv)
    engine = QQmlApplicationEngine()

    main = Main()
    engine.rootContext().setContextProperty("main", main)

    data = ["London", "New York", "Paris", "Tokyo", "Sydney", "Madrid", "Mumbai", "Istanbul", "Bangkok", "Moscow", "Toronto", "Rome", "Shanghai", "Rio de Janeiro", "Seoul", "Berlin", "Cape Town", "Amsterdam", "Los Angeles", "San Francisco", "Cairo", "Barcelona", "Buenos Aires", "Melbourne", "Athens", "Vancouver", "Dubai", "Prague", "Edinburgh", "Singapore"]

    model = QStringListModel()
    model.setStringList(data)

    context = engine.rootContext()
    context.setContextProperty("myModel", model)

    engine.load("main.qml")
    if not engine.rootObjects():
        sys.exit(-1)
    sys.exit(app.exec_())

Вот main.qml с импортом Qt5, замененным импортом Qt6:

Я переработал ваш main.qml, чтобы сохранить список «зеленых» предметов. Нам нужно сделать это, потому что вы не можете получить доступ к делегатам напрямую, так как Qt будет создавать и уничтожать делегаты по требованию. Нам нужно полагаться на видимых делегатов и на то, что они привязаны к чему-то, что мы можем показать.

import QtQuick
import QtQuick.Controls
import QtQuick.Window

Window {
    visible: true
    color: "#161515"
    width: 640
    height: 480
    title: qsTr("Listview Example")

    property list<string> green

    Rectangle {
        id: rectangle
        x: 51
        y: 63
        width: 539
        height: 143
        color: "#ffffff"

        ListView {
            id: listView
            anchors.fill: parent
            model: myModel
            currentIndex: 0
            delegate: Rectangle {
                id: dlg
                width: listView.width
                height: 25
                color: index === listView.currentIndex ? "lightgrey" : "#00000000"
                radius: 10
                property var modelText: model.display

                property alias colorOfText: titleText.color

                MouseArea {
                    anchors.fill: parent
                    onClicked: {
                        listView.currentIndex = index
                    }
                }
                Text {
                    id: titleText
                    text: modelText
                    font.pixelSize: 18
                    color: green.indexOf(modelText) !== -1 ? "green" : "black"
                    padding: 5
                }
            }
        }
    }
    Button {
        id: printBtn
        x: 286
        y: 241
        width: 69
        height: 35
        text: qsTr("Print")
        onClicked: {
            main.justClicking()
        }
    }
    Connections {
        target: main
        function onClicked() {
            if (green.indexOf(listView.currentItem.modelText) === -1) {
                green.push(listView.currentItem.modelText);
            }
        }
    }
}

Чтобы лучше понять жизненный цикл ваших делегатов, рассмотрите возможность добавления следующего кода к вашему делегату:

                Component.onCompleted: console.info(`Construction for ${model.display} ${index}`);
                Component.onDestruction: console.info(`Destruction for ${model.display} ${index}`);

Затем, когда вы прокручиваете свой ListView вверх и вниз, вы увидите, что делегаты создаются и уничтожаются. По этой причине вы не можете программно получить доступ к своим делегатам, поскольку они могут существовать или не существовать.

Вот скриншот вашего приложения: