Правило шаблона XSLT 3.0 не поддерживает потоковую передачу

Я создаю файл csv, используя приведенный ниже xsl. Мне нужно выполнить проверку условия: если XML не содержит элемента элемента, мне нужно добавить строку по умолчанию, в противном случае необходимо добавить элементы из элемента.

Мой XML большой, и я использую потоковую передачу SAXON. Когда я использую элементы if и for-each, он выдает ошибки. Мне нужна твоя помощь, чтобы справиться с этим.

Произошла ошибка: Произошла ошибка при преобразовании: Правило шаблона не поддерживает потоковую передачу.

Существует более одного потребляющего операнда:
Результат правила шаблона может содержать потоковые узлы.

XSLT

<?xml version = "1.0"?>
<xsl:stylesheet xmlns:xsl = "http://www.w3.org/1999/XSL/Transform" version = "3.0">
    <xsl:output method = "text" encoding = "UTF-8" indent = "no" omit-xml-declaration = "yes"/>
    <xsl:mode streamable = "yes"/>
    <xsl:strip-space elements = "*"/>
    <xsl:variable name = "dq" select = "'&quot;'"/>
    <xsl:variable name = "qcq" select = "'&quot;,&quot;'"/>
    <xsl:variable name = "lf" select = "'&#10;'"/>   

    <xsl:variable name = "email" select = "'[email protected]'"/>
    <xsl:variable name = "product_id" select = "'product1'"/>
    <xsl:template match = "items">
        <xsl:text>product_id,email,key</xsl:text>
        <xsl:value-of select = "'&#10;'"/>
        <xsl:choose>
            <xsl:when test = "not(item)">
                <xsl:value-of disable-output-escaping = "yes" select = "concat($dq,$qcq,$email,$qcq,$dq,$lf)"/>
            </xsl:when>
            <xsl:when test = "item">
                <xsl:for-each select = "item ! copy-of(.)">
                    <xsl:variable name = "p_key" select = "id"/>
                    <xsl:value-of disable-output-escaping = "yes" select = "concat($dq,$product_id,$qcq,$email,$qcq,$p_key,$dq,$lf)"/>
                </xsl:for-each>
            </xsl:when>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet> 

Sample XML


<?xml version = "1.0" encoding = "UTF-8"?>
<items><item><id><![CDATA[040411c47702b29acb4e4120040ee6b937fbb8]]></id></item></items>

no item in xml
<?xml version = "1.0" encoding = "UTF-8"?>
<items></items>

Будет ли элемент items полностью пустым, если нет элементов (по умолчанию)? Существует потоковая функция просмотра вперед has-children, которую вы можете использовать w3.org/TR/xpath-functions-31/#func-has-children.

— 04.04.2024 18:16

Спасибо, @MartinHonnen Да, элемент items совершенно пуст.

— 04.04.2024 19:10

xslt saxon

04.04.2024 18:01

Стоит ли изучать PHP в 2023-2024 годах?

Привет всем, сегодня я хочу высказать свои соображения по поводу вопроса, который я уже много раз получал в своем сообществе: "Стоит ли изучать PHP в...

Поведение ключевого слова "this" в стрелочной функции в сравнении с нормальной функцией

В JavaScript одним из самых запутанных понятий является поведение ключевого слова "this" в стрелочной и обычной функциях.

Приемы CSS-макетирования - floats и Flexbox

Здравствуйте, друзья-студенты! Готовы совершенствовать свои навыки веб-дизайна? Сегодня в нашем путешествии мы рассмотрим приемы CSS-верстки - в...

Тестирование функциональных ngrx-эффектов в Angular 16 с помощью Jest

В системе управления состояниями ngrx, совместимой с Angular 16, появились функциональные эффекты. Это здорово и делает код определенно легче для...

Концепция локализации и ее применение в приложениях React ⚡️

Локализация - это процесс адаптации приложения к различным языкам и культурным требованиям. Это позволяет пользователям получить опыт, соответствующий...

Пользовательский скаляр GraphQL

Листовые узлы системы типов GraphQL называются скалярами. Достигнув скалярного типа, невозможно спуститься дальше по иерархии типов. Скалярный тип...

Перейти к ответу Данный вопрос помечен как решенный

Ответы 2

Ответ принят как подходящий

Если элемент items может быть пустым, вы можете использовать, например.

   <xsl:template match = "items">
        <xsl:text>product_id,email,key</xsl:text>
        <xsl:value-of select = "'&#10;'"/>
        <xsl:choose>
            <xsl:when test = "not(has-children())">
                <xsl:value-of select = "concat($dq,$qcq,$email,$qcq,$dq,$lf)"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:for-each select = "item ! copy-of(.)">
                    <xsl:variable name = "p_key" select = "id"/>
                    <xsl:value-of select = "concat($dq,$product_id,$qcq,$email,$qcq,$p_key,$dq,$lf)"/>
                </xsl:for-each>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

Я удалил экранирование отключение-вывода, поскольку, на мой взгляд, оно не имеет смысла для текста метода вывода.

Другой вариант: on-empty:

<xsl:template match = "items">
    <xsl:text>product_id,email,key</xsl:text>
    <xsl:value-of select = "'&#10;'"/>
    <div>
      <xsl:for-each select = "item ! copy-of(.)">
                <xsl:variable name = "p_key" select = "id"/>
                <xsl:value-of select = "concat($dq,$product_id,$qcq,$email,$qcq,$p_key,$dq,$lf)"/>
      </xsl:for-each>
      <xsl:on-empty>
         <xsl:value-of select = "concat($dq,$qcq,$email,$qcq,$dq,$lf)"/>
      </xsl:on-empty>
    </div>
</xsl:template>

При использовании метода вывода text элемент div, конечно, не производит вывод, возможно, вместо него можно было бы использовать xsl:sequence.

Спасибо @martin, использование функции has-children работает для меня. Ценю ваш ответ.

— 04.04.2024 19:11

Основная проблема с has-children() заключается в том, что он вернет true, если элемент содержит текстовый узел с пробелами или содержимое комментария. Если это подходит для ваших случаев использования, это нормально, но я бы предпочел xsl:on-empty здесь. Вы можете заменить <div>..</div> на <xsl:value-of>....</xsl:value-of>.

— 05.04.2024 00:51

04.04.2024 18:25

Еще одно решение — использовать xsl:fork. Что-то вроде этого:

<xsl:template match = "items">
   <xsl:text>product_id,email,key</xsl:text>
   <xsl:value-of select = "'&#10;'"/>
   <xsl:fork>
      <xsl:sequence>
        <xsl:if test = "not(item)">
           <xsl:value-of select = "concat($dq,$qcq,$email,$qcq,$dq,$lf)"/>
        </xsl:if>
      </xsl:sequence>
      <xsl:sequence>
        <xsl:for-each select = "item ! copy-of(.)">
          <xsl:variable name = "p_key" select = "id"/>
          <xsl:value-of select = "concat($dq,$product_id,$qcq,$email,$qcq,$p_key,$dq,$lf)"/>
        </xsl:for-each>
      </xsl:sequence>
   </xsl:fork>
</xsl:template>

Не испытано.

Еще одно решение — включить элемент «стоппер» в каждую итерацию:

<xsl:variable name = "stopper" as = "element(*)"><stopper/></xsl:variable>
<xsl:for-each select = "item ! copy-of(.), $stopper">
  <xsl:choose>
     <xsl:when test = "self::stopper">
       <xsl:if test = "position()=1">
         <xsl:value-of select = "concat($dq,$product_id,$qcq,$email,$qcq,$p_key,$dq,$lf)"/>
       </xsl:if>
     </xsl:when>
     <xsl:otherwise>
         <xsl:variable name = "p_key" select = "id"/>
         <xsl:value-of select = "concat($dq,$product_id,$qcq,$email,$qcq,$p_key,$dq,$lf)"/>
     </xsl:otherwise>
  </xsl:choose>
</xsl:for-each>

Тоже не тестировался.

05.04.2024 01:12