Предикаты против рекурсивных шаблонов против других

рассмотрим эту простую задачу:

мы хотим сопоставить этот вход с тем же выходом, за исключением первого появления элемента 'foo' с "@bar = '1'", мы добавляем новый атрибут @wibble, так что это:

<root>
    <foo/>
    <foo/>
    <foo/>
    <foo bar = "1"/>
    <foo bar = "1"/>
    <foo/>
    <foo/>
    <foo/>
    <foo/>
    <foo/>
</root>

идет к этому:

<root>
  <foo />
  <foo />
  <foo />
  <foo wibble = "2" bar = "1" />
  <foo bar = "1" />
  <foo />
  <foo />
  <foo />
  <foo />
  <foo />
</root>

Я мог бы реализовать это сопоставление, используя шаблон идентификации (не знаю, как называется этот шаблон), но это будет выглядеть так:

<xsl:stylesheet version = "1.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl = "urn:schemas-microsoft-com:xslt" exclude-result-prefixes = "msxsl"
>
    <xsl:output method = "xml" indent = "yes"/>

    <xsl:template match = "/">
        <xsl:apply-templates select = "root" mode = "findFirst"/>
    </xsl:template>
    
    <xsl:template match = "@* | node()" mode = "findFirst">
        <xsl:copy>
            <xsl:apply-templates select = "@* | node()" mode = "findFirst"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match = "foo[@bar='1'][1]"  mode = "findFirst">
        <xsl:copy>
            <xsl:attribute name = "wibble">2</xsl:attribute>
            <xsl:apply-templates select = "@* | node()" mode = "findFirst"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

т. е. мы переопределяем шаблон удостоверения некоторым оператором сопоставления, который соответствует конкретному сценарию, который мы хотим сопоставить, реализуем наше переопределяющее сопоставление, а затем продолжаем.

Я часто использую этот стиль.

Иногда, хотя оператор match является сложным (мы недавно видели это в другом вопросе о сопоставлении строк кода). Я нахожу такого рода совпадения проблематичными, в приведенном выше сценарии вариант использования прост, но иногда логика не может быть легко (или вообще) явно выражена внутри оператора сопоставления, и в этом случае у меня возникает соблазн вернуться к рекурсивным функциональным шаблонам, и в этом случае я бы написал такой рекурсивный шаблон.

<xsl:stylesheet version = "1.0" xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl = "urn:schemas-microsoft-com:xslt" exclude-result-prefixes = "msxsl"
>
    <xsl:output method = "xml" indent = "yes"/>

    <xsl:template match = "/">
        <root>
            <xsl:apply-templates select = "root/foo[1]" mode = "findFirst">
                <xsl:with-param name = "isFound" select = "false()"/>
            </xsl:apply-templates>          
        </root>
    </xsl:template>

    <xsl:template match = "foo" mode = "findFirst">
        <xsl:param name = "isFound"/>
        <xsl:copy>
            <xsl:if test = "$isFound = false() and @bar = '1'">
                <xsl:attribute name = "wibble">2</xsl:attribute>
            </xsl:if>
            <xsl:apply-templates select = "@* | node()"  mode = "identity"/>
        </xsl:copy>
        <xsl:choose>
            <xsl:when test = "$isFound = false() and @bar = '1'">
                <xsl:apply-templates select = "following-sibling::foo[1]" mode = "findFirst">
                    <xsl:with-param name = "isFound" select = "true()"/>
                </xsl:apply-templates>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates select = "following-sibling::foo[1]" mode = "findFirst">
                    <xsl:with-param name = "isFound" select = "$isFound"/>
                </xsl:apply-templates>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match = "@* | node()" mode = "identity">
        <xsl:copy>
            <xsl:apply-templates select = "@* | node()"  mode = "identity"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

это в основном рассматривает набор узлов как функциональный «список», принимая голову (и неявно передавая хвост). Теперь мы можем реализовать гораздо более сложную логику и использовать параметры для передачи текущего состояния (фактически свернутого) через рекурсию, но за счет дополнительной сложности.

НО....

• Является ли этот стиль программирования устойчивым в XSLT? - Я всегда беспокоюсь о переполнении стека (по иронии судьбы!), из-за вероятной нехвостовой рекурсии в механизме XSLT рекурсивного шаблона.

• Мои познания в XSLT 3.0 чрезвычайно ограничены (всегда приветствуются любые ссылки на хорошие учебные ресурсы), но в языке FP альтернативой прямой рекурсии было бы использование fold, где fold записывается как хвостовая рекурсивная функция, а fold IS доступен в XSLT 3.0, но разумная ли это альтернатива?

• Существуют ли другие шаблоны использования, которые я могу использовать?